Tabloya naverokê
Vê hînker rêgezên cûrbecûr yên karanîna fonksiyona ISNA ya li Excel-ê vedigire da ku xeletiyên #N/A bikar bîne.
Gava Excel nikaribe tiştê ku jê tê xwestin bibîne, #N/ Di şaneyek de xeletiyek xuya dike. Ji bo rêgirtin û birêvebirina van xeletiyan, hûn dikarin fonksiyona ISNA bikar bînin. Bikaranîna wê ya pratîkî çi ye? Di bingeh de, ew dibe alîkar ku hûn formulan xwe ji bikarhêner re xweştir bikin û pelên xebata we çêtir xuya bikin.
Fonksiyon ISNA di Excel de
Fonksiyon Excel ISNA ji bo kontrolkirina hucreyan tê bikar anîn. an jî formulên çewtiyên #N/A. Encam nirxek mentiqî ye: TRUE heke xeletiyek #N/A were tespît kirin, nerast FALSE.
Fonksiyon di hemî guhertoyên Excel 2000 heta 2021 û Excel 365 de heye.
The hevoksaziya fonksiyona ISNA bi qasî ku dibe hêsan e:
ISNA(nirx)Li ku derê nirx nirxa şaneyê an formula ku hûn dixwazin xeletiyên #N/A kontrol bikin e.
Ji bo afirandina formulek ISNA di forma wê ya bingehîn de, referansek şaneyê wekî argumana wê ya yekane peyda bike:
=ISNA(A2)
Heke di şaneya referanskirî de xeletiyek #N/A hebe, hûn ê RAST bibin. Ger xeletiyek din, nirx an şaneyek vala hebe, hûn ê FALSE bistînin:
Çawa di Excel de ISNA bikar bînin
Bikaranîna fonksiyona ISNA di forma xwe ya paqij de wateya pratîkî ya hindik heye. Pir caran, ew bi fonksiyonên din re bi hev re tê bikar anîn da ku encama formek diyarkirî binirxîne. Ji bo vê yekê, tenê wê formula din têxe argumana nirx ya ISNA:
ISNA( your_formula())Di daneheva jêrîn de, bihesibînin ku hûn dixwazin du lîsteyan (stûnên A û D) bidin ber hev û navên ku di her du lîsteyan de hene û yên ku tenê di navnîşê de xuya dibin destnîşan bikin. 1.
Ji bo berawirdkirina navê di A3 de li hember her navekî di stûna D de, formula ev e:
=MATCH(A3, $D$2:$D$9, 0)
Heke nirxek lêgerînê were dîtin, fonksiyona MATCH wê vedigerîne. pozîsyona têkildar di rêza lêgerînê de, wekî din xeletiyek #N/A çêdibe. Ji bo ceribandina encama MATCH-ê, em wê di ISNA-yê de hêlîn dikin:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Ev formula diçe B3, û paşê bi B14 tê kopî kirin.
Niha, hûn dikarin bi zelalî Binêrin ka kîjan xwendekar hemû îmtîhanan derbas kirine (navek di stûna D de peyda nabe > MATCH #N/A vedigerîne > ISNA RAST vedigerîne) û yên herî kêm testek têkçûyî heye (navek di stûna D de xuya dike & gt; xeletî tune > ISNA FALSE vedigerîne).
Şîret. Di Excel 365 û Excel 2021 de, hûn dikarin fonksiyonek nûjen a XMATCH bikar bînin. li şûna MATCH.
Eger formula ISNA di Excel de
Ji hêla sêwiranê ve, fonksiyona ISNA tenê dikare du nirxên Boolean vegerîne. Ji bo nîşandana peyamên xweyên xwerû, wê bi fonksiyona IF re bi hev re bikar bînin:
IF(ISNA(…), " text_if_error", " text_if_no_error")Parastkirina me mînakek hinekî pêşdetir, ka em fêr bibin ka kîjan xwendekarên ji koma A di ti îmtîhanê de bi ser neketin û ji wan re "Tê îmtîhanên têkçûyî tune" vegerînin. Ji bo xwendekarên mayî, em ê vegerin "Fail". Ji bo vê yekê, formula ISNA MATCH têxe navîmtîhana mentiqî ya IF, da ku IF bibe fonksiyona herî derve:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
Encam niha gelek çêtir û biaqiltir xuya dikin, li hev dikin?
Meriv çawa ISNA di Excel de bi VLOOKUP-ê re bikar tîne
Têkheviya IF ISNA çareseriyek gerdûnî ye ku dikare bi her fonksiyonek ku di komek daneyan de li tiştek digere û xeletiyek #N/A vedigerîne were bikar anîn. dema ku nirxek lêgerînê neyê dîtin.
Sîntaksa fonksiyona ISNA ya bi VLOOKUP re wiha ye:
IF(ISNA(VLOOKUP(…), " text_custom", VLOOKUP( ...))Bi zimanekî mirovî hatiye wergerandin, dibêje: heke VLOOKUP bibe sedema xeletiyek #N/A, nivîsa xwerû vegerîne, wekî din encama VLOOKUP vegerîne.
Di tabloya nimûneya me de, bifikirin ku hûn dixwazin dersên ku xwendekar di îmtîhanê de bi ser neketin vegerînin. Ji bo kesên ku hemî îmtîhan bi serketî derbas kirine, dê "Tê testên têkçûyî tune" were xuyang kirin.
Ji bo lêgerîna mijaran, em vê formula VLOOKUP-a klasîk ava dikin:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Û paşê wê di formula giştî ya IF ISNA ya ku li jor hatî nîqaş kirin de bihêlin:
80 39
Di Excel 2013 û guhertoya paşîn de, hûn dikarin fonksiyona IFNA bikar bînin da ku xeletiyên #N/A bigirin û bigirin. Ev formula we kurttir dike û xwendinê hêsantir dike.
Wek nimûne, em xeletiyên #N/A bi daçekan ("-") diguhezînin û vê çareseriya xweş distînin:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Bikarhênerên Excel 365 û 2021 wekî serketiya nûjen a VLOOKUP-ê bi tevahî hewceyê fonksiyonek pêçandî tuneFonksiyona XLOOKUP, dikare bi xwemalî xeletiyên #N/A bi rê ve bibe:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Encam dê tam heman be wekî ku di dîmena jorîn de tê xuyang kirin.
Formula ISNAyê bihejmêre. Çewtiyên #N/Na
Ji bo hejmartina #N/A çewtiyên di navbereke diyarkirî de, fonksiyona ISNA bi SUMPRODUCT re bi vî awayî bikar bînin:
SUMPRODUCT(--ISNA( range))Li vir, ISNA rêzek nirxên TRUE û FALSE vedigerîne, negasyona ducarî (--) nirxên mantiqî di nav 1'an û 0'yan de dihêle, û SUMPRODUCT encamê zêde dike.
Mînakî, ji bo Fêr bibe ka çend xwendekar di hemî îmtîhanan de biser ketine, formula MATCH-ê ji bo rêzek nirxên lêgerînê (A3:A14) biguhezînin û wê di ISNA de bihêlin:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))
Formul diyar dike ku 9 xwendekar testên têkçûyî tune ne, ango fonksiyona MATCH 9 xeletiyên #N/A vedigerîne:
Bi vî rengî meriv di Excel de formûlên ISNA-yê çê dike û bikar tîne. Ez ji bo xwendina te spas dikim û li hêviya dîtina te li ser bloga me hefteya pêş me!
Daxistinên berdest
Mînakên formula ISNA (pelê xlsx)
