Mục lục
Hướng dẫn này đi sâu vào nhiều cách sử dụng hàm ISNA trong Excel để xử lý lỗi #N/A.
Khi Excel không thể tìm thấy nội dung được yêu cầu, lỗi #N/ Một lỗi xuất hiện trong một ô. Để chặn và xử lý các lỗi như vậy, bạn có thể sử dụng hàm ISNA. Việc sử dụng thực tế của điều đó là gì? Về cơ bản, nó giúp làm cho công thức của bạn thân thiện hơn với người dùng và trang tính của bạn trông đẹp hơn.
Hàm ISNA trong Excel
Hàm ISNA của Excel được sử dụng để kiểm tra các ô hoặc công thức cho lỗi #N/A. Kết quả là một giá trị logic: TRUE nếu phát hiện thấy lỗi #N/A, FALSE nếu không.
Hàm này có sẵn trong tất cả các phiên bản Excel 2000 đến 2021 và Excel 365.
Hàm cú pháp của hàm ISNA đơn giản nhất có thể:
ISNA(giá trị)Trong đó giá trị là giá trị ô hoặc công thức bạn muốn kiểm tra lỗi #N/A.
Để tạo công thức ISNA ở dạng cơ bản, hãy cung cấp tham chiếu ô làm đối số duy nhất:
=ISNA(A2)
Trong trường hợp ô được tham chiếu chứa lỗi #N/A, bạn sẽ nhận được SỰ THẬT. Trong trường hợp có bất kỳ lỗi, giá trị hoặc ô trống nào khác, bạn sẽ nhận được FALSE:
Cách sử dụng ISNA trong Excel
Sử dụng hàm ISNA ở dạng tinh khiết của nó có rất ít ý nghĩa thực tế. Thường xuyên hơn, nó được sử dụng cùng với các chức năng khác để đánh giá kết quả của một công thức nhất định. Đối với điều này, chỉ cần đặt công thức khác đó vào đối số giá trị của ISNA:
ISNA( your_formula())Trong tập dữ liệu bên dưới, giả sử bạn muốn so sánh hai danh sách (cột A và D) và xác định những tên có trong cả hai danh sách và những tên chỉ xuất hiện trong danh sách 1.
Để so sánh tên trong ô A3 với từng tên trong cột D, công thức là:
=MATCH(A3, $D$2:$D$9, 0)
Nếu tìm thấy giá trị tra cứu, hàm MATCH sẽ trả về giá trị tra cứu vị trí tương đối trong mảng tra cứu, nếu không sẽ xảy ra lỗi #N/A. Để kiểm tra kết quả của MATCH, chúng tôi lồng nó vào ISNA:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Công thức này chuyển đến B3, sau đó được sao chép qua B14.
Bây giờ, bạn có thể rõ ràng xem học sinh nào đã vượt qua tất cả các bài kiểm tra (không có tên trong cột D > MATCH trả về #N/A > ISNA trả về TRUE) và học sinh nào có ít nhất một bài kiểm tra không đạt (tên xuất hiện trong cột D > không có lỗi > ISNA trả về FALSE).
Mẹo. Trong Excel 365 và Excel 2021, bạn có thể sử dụng hàm XMATCH hiện đại hơn. thay vì MATCH.
Công thức IF ISNA trong Excel
Theo thiết kế, hàm ISNA chỉ có thể trả về hai giá trị Boolean. Để hiển thị các thông báo tùy chỉnh của bạn, hãy sử dụng nó kết hợp với hàm IF:
IF(ISNA(…), " text_if_error", " text_if_no_error")Tinh chỉnh của chúng tôi ví dụ xa hơn một chút, hãy tìm xem sinh viên nào từ nhóm A đã không trượt bất kỳ bài kiểm tra nào và trả về "Không có bài kiểm tra nào thất bại" cho họ. Đối với những sinh viên còn lại, chúng tôi sẽ trả về "Không đạt". Để thực hiện việc này, hãy nhúng công thức ISNA MATCH vàokiểm tra logic của IF, để IF trở thành hàm ngoài cùng:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
Kết quả bây giờ trông đẹp hơn và trực quan hơn nhiều, bạn đồng ý không?
Cách sử dụng ISNA trong Excel với VLOOKUP
Tổ hợp IF ISNA là một giải pháp phổ biến có thể được sử dụng với bất kỳ hàm nào tìm kiếm thứ gì đó trong một tập hợp dữ liệu và trả về lỗi #N/A khi không tìm thấy giá trị tra cứu.
Cú pháp của hàm ISNA với VLOOKUP như sau:
IF(ISNA(VLOOKUP(…), " custom_text", VLOOKUP( …))Được dịch sang ngôn ngữ của con người, nội dung này cho biết: nếu VLOOKUP dẫn đến lỗi #N/A, hãy trả về văn bản tùy chỉnh, nếu không thì hãy trả về kết quả của VLOOKUP.
Trong bảng mẫu của chúng tôi, giả sử bạn muốn trả về các môn học mà sinh viên đã trượt bài kiểm tra. Đối với những người đã vượt qua tất cả các bài kiểm tra thành công, "Không có bài kiểm tra nào bị trượt" sẽ được hiển thị.
Để tra cứu các môn học, chúng tôi xây dựng công thức VLOOKUP cổ điển này:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Và sau đó lồng nó vào công thức chung IF ISNA đã thảo luận ở trên:
30 80
Trong Excel 2013 trở lên, bạn có thể sử dụng hàm IFNA để nắm bắt và xử lý lỗi #N/A. Điều này làm cho công thức của bạn ngắn hơn và dễ đọc hơn.
Ví dụ: chúng tôi thay thế lỗi #N/A bằng dấu gạch ngang ("-") và nhận được giải pháp tinh tế này:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Người dùng Excel 365 và 2021 hoàn toàn không cần bất kỳ hàm bao bọc nào vì là phiên bản kế nhiệm hiện đại của VLOOKUP,Hàm XLOOKUP, có thể xử lý lỗi #N/A một cách tự nhiên:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Kết quả sẽ giống hệt như trong ảnh chụp màn hình ở trên.
Công thức TỔNG HỢP ISNA để đếm Lỗi #N/A
Để đếm lỗi #N/A trong một phạm vi nhất định, hãy sử dụng hàm ISNA cùng với TÓM TẮT theo cách này:
SUMPRODUCT(--ISNA( range))Ở đây, ISNA trả về một mảng các giá trị TRUE và FALSE, phủ định kép (--) buộc các giá trị logic thành 1 và 0, và SUMPRODUCT cộng kết quả.
Ví dụ: để tìm hiểu xem có bao nhiêu học sinh thành công trong tất cả các bài kiểm tra, sửa đổi công thức MATCH cho một dải giá trị tra cứu (A3:A14) và lồng nó vào ISNA:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))
Công thức xác định rằng 9 học sinh không có phép thử nào bị lỗi, tức là hàm MATCH trả về 9 lỗi #N/A:
Đó là cách tạo và sử dụng công thức ISNA trong Excel. Tôi cảm ơn bạn đã đọc và mong được gặp bạn trên blog của chúng tôi vào tuần tới!
Các bản tải xuống có sẵn
Ví dụ về công thức ISNA (tệp .xlsx)
