V tem priročniku so predstavljeni različni načini uporabe funkcije ISNA v Excelu za obravnavo napak #N/A.

Kadar Excel ne more najti zahtevanega, se v celici pojavi napaka #N/A. Za prestrezanje in odpravljanje takih napak lahko uporabite funkcijo ISNA. Kakšna je praktična uporaba te funkcije? V bistvu vam pomaga, da so vaše formule prijaznejše do uporabnika in delovni listi lepšega videza.

Funkcija ISNA v programu Excel

Excelova funkcija ISNA se uporablja za preverjanje celic ali formul za napake #N/A. Rezultat je logična vrednost: TRUE, če je odkrita napaka #N/A, in FALSE v nasprotnem primeru.

Funkcija je na voljo v vseh različicah programov Excel od 2000 do 2021 in Excel 365.

Sintaksa funkcije ISNA je tako preprosta, kot je le mogoče:

Kje: vrednost je vrednost celice ali formule, ki jo želite preveriti za napake #N/A.

Če želite ustvariti formulo ISNA v njeni osnovni obliki, kot edini argument navedite sklic na celico:

=ISNA(A2)

Če referenčna celica vsebuje napako #N/A, se izpiše TRUE. V primeru katere koli druge napake, vrednosti ali prazne celice se izpiše FALSE:

Kako uporabljati ISNA v Excelu

Uporaba funkcije ISNA v njeni čisti obliki je praktično nesmiselna. Pogosteje jo uporabljamo skupaj z drugimi funkcijami za vrednotenje rezultata določene formule. Za to preprosto vstavite to drugo formulo v vrednost argument ISNA:

Predpostavimo, da želite primerjati dva seznama (stolpca A in D) in ugotoviti, katera imena so prisotna na obeh seznamih in katera samo na seznamu 1.

Za primerjavo imena v A3 z vsakim imenom v stolpcu D je formula naslednja:

=MATCH(A3, $D$2:$D$9, 0)

Če najdemo vrednost iskanja, funkcija MATCH vrne njen relativni položaj v polju iskanja, sicer se pojavi napaka #N/A. Če želimo preveriti rezultat funkcije MATCH, jo ugnezdimo v ISNA:

=ISNA(MATCH(A3, $D$2:$D$9, 0))

Ta formula se prenese v B3, nato pa se kopira v B14.

Zdaj lahko jasno vidite, kateri učenci so uspešno opravili vse teste (v stolpcu D ni imena> MATCH vrne #N/A> ISNA vrne TRUE) in kateri imajo vsaj en neuspešen test (v stolpcu D je ime> ni napake> ISNA vrne FALSE).

Nasvet: V Excelu 365 in Excelu 2021 lahko namesto funkcije MATCH uporabite sodobnejšo funkcijo XMATCH.

Formula IF ISNA v Excelu

Po zasnovi lahko funkcija ISNA vrne le dve logični vrednosti. Če želite prikazati sporočila po meri, jo uporabite v kombinaciji s funkcijo IF:

Če naš primer še nekoliko izpopolnimo, ugotovimo, kateri učenci iz skupine A niso opravili nobenega testa, in zanje vrnemo "Ni neuspešnih testov". Za preostale učence vrnemo "Neuspešno". To storimo tako, da formulo ISNA MATCH vgradimo v logični test IF, tako da IF postane najbolj zunanja funkcija:

=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "Ni neuspešnih testov", "Neuspešno")

Rezultati so zdaj videti veliko boljši in bolj intuitivni, se strinjate?

Kako uporabljati ISNA v Excelu z VLOOKUP

Kombinacija IF ISNA je univerzalna rešitev, ki se lahko uporablja s katero koli funkcijo, ki išče nekaj v nizu podatkov in vrne napako #N/A, če iskane vrednosti ne najde.

Sintaksa funkcije ISNA z VLOOKUP je naslednja:

Če ga prevedemo v človeški jezik, pravi: če VLOOKUP povzroči napako #N/A, vrnite besedilo po meri, sicer vrnite rezultat VLOOKUP.

Predpostavimo, da želite v naši vzorčni tabeli vrniti predmete, pri katerih učenci niso uspešno opravili testov. Za tiste, ki so uspešno opravili vse teste, bo prikazano "Ni neuspešnih testov".

Za iskanje predmetov sestavimo to klasično formulo VLOOKUP:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

Nato ga vnesite v splošno formulo IF ISNA, o kateri smo govorili zgoraj:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Ni neuspešnih testov", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

V Excelu 2013 in novejših različicah lahko uporabite funkcijo IFNA, da zajamete in obravnavate napake #N/A. Tako je vaša formula krajša in lažje berljiva.

Kot primer lahko napake #N/A nadomestimo s črticami ("-") in dobimo to elegantno rešitev:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")

Uporabniki programov Excel 365 in 2021 ne potrebujejo nobene ovojne funkcije, saj sodobna naslednica funkcije VLOOKUP, funkcija XLOOKUP, samodejno obravnava napake #N/A:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")

Rezultat bo popolnoma enak, kot je prikazano na zgornji sliki zaslona.

Formula SUMPRODUCT ISNA za štetje napak #N/A

Če želite šteti napake #N/A v določenem območju, uporabite funkcijo ISNA skupaj s SUMPRODUCT na ta način:

V tem primeru ISNA vrne polje vrednosti TRUE in FALSE, dvojna negacija (--) spremeni logične vrednosti v 1 in 0, SUMPRODUCT pa sešteje rezultat.

Če želite na primer ugotoviti, koliko študentov je uspešno opravilo vse teste, spremenite formulo MATCH za območje vrednosti iskanja (A3:A14) in jo vnesite v formulo ISNA:

=SUMPRODUKT(--ISNA(MATCH(A3:A14, D2:D9, 0)))

Formula določa, da 9 učencev nima neuspešno rešenih testov, tj. funkcija MATCH vrne 9 napak #N/A:

To je način ustvarjanja in uporabe formul ISNA v Excelu. Zahvaljujem se vam za branje in se veselim, da se naslednji teden vidimo na našem blogu!

Razpoložljivi prenosi

Primeri formul ISNA (.xlsx datoteka)