Inhoudsopgave
Deze handleiding gaat in op verschillende manieren om de ISNA-functie in Excel te gebruiken om #N/A-fouten af te handelen.
Wanneer Excel niet kan vinden wat wordt gevraagd, verschijnt er een #N/A-fout in een cel. Om dergelijke fouten te onderscheppen en af te handelen, kunt u de ISNA-functie gebruiken. Wat is het praktische nut daarvan? In wezen helpt het om uw formules gebruiksvriendelijker te maken en uw werkbladen er beter uit te laten zien.
ISNA-functie in Excel
De Excel ISNA functie wordt gebruikt om cellen of formules te controleren op #N/A fouten. Het resultaat is een logische waarde: TRUE indien een #N/A fout is gedetecteerd, FALSE anders.
De functie is beschikbaar in alle versies van Excel 2000 tot en met 2021 en Excel 365.
De syntaxis van de ISNA-functie is zo eenvoudig mogelijk:
ISNA (waarde)Waar waarde is de celwaarde of formule die u wilt controleren op #N/A fouten.
Om een ISNA-formule in zijn basisvorm te maken, geeft u een celverwijzing als enig argument:
=ISNA(A2)
Indien de cel waarnaar verwezen wordt een #N/A fout bevat, krijgt u TRUE. In geval van een andere fout, waarde of een lege cel, krijgt u FALSE:
Hoe ISNA gebruiken in Excel
Het gebruik van de ISNA-functie in zijn pure vorm heeft weinig praktische zin. Vaker wordt hij samen met andere functies gebruikt om het resultaat van een bepaalde formule te evalueren. Hiervoor zet u gewoon die andere formule in de waarde argument van ISNA:
ISNA( uw_formule ())Stel dat u in de onderstaande dataset twee lijsten (kolommen A en D) wilt vergelijken en de namen wilt identificeren die in beide lijsten voorkomen en die welke alleen in lijst 1 voorkomen.
Om de naam in A3 te vergelijken met elke naam in kolom D is de formule:
=MATCH(A3, $D$2:$D$9, 0)
Indien een lookup-waarde wordt gevonden, geeft de MATCH-functie de relatieve positie ervan in de lookup-array terug, anders treedt een #N/A-fout op. Om het resultaat van MATCH te testen, nesten we het in ISNA:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Deze formule gaat naar B3, en wordt dan gekopieerd via B14.
Nu kunt u duidelijk zien welke studenten alle tests hebben doorstaan (een naam komt niet voor in kolom D> MATCH geeft #N/A> ISNA geeft TRUE) en welke studenten minstens één gezakte test hebben (een naam komt voor in kolom D> geen fout> ISNA geeft FALSE).
Tip. In Excel 365 en Excel 2021 kunt u de modernere functie XMATCH gebruiken in plaats van MATCH.
IF ISNA-formule in Excel
De ISNA-functie kan per ontwerp slechts twee Booleaanse waarden teruggeven. Om uw aangepaste berichten weer te geven, gebruikt u de functie in combinatie met de IF-functie:
IF(ISNA(...), " tekst_als_fout ", " tekst_als_geen_fout ")Laten we ons voorbeeld wat verder verfijnen en uitzoeken welke leerlingen uit groep A voor geen enkele toets gezakt zijn en voor hen "Geen gezakte toetsen" teruggeven. Voor de overige leerlingen geven we "Gezakt" terug. Om dit te doen sluiten we de ISNA MATCH-formule in in de logische toets van IF, zodat IF de buitenste functie wordt:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
De resultaten zien er nu veel beter en intuïtiever uit, akkoord?
ISNA gebruiken in Excel met VLOOKUP
De combinatie IF ISNA is een universele oplossing die kan worden gebruikt met elke functie die iets zoekt in een verzameling gegevens en een #N/A-fout teruggeeft wanneer een opzoekwaarde niet wordt gevonden.
De syntaxis van de ISNA-functie met VLOOKUP is als volgt:
ALS(ISNA(VLOOKUP(...), " aangepaste_tekst ", VLOOKUP(...))Vertaald in een menselijke taal zegt het: indien VLOOKUP resulteert in een #N/A fout, retourneer aangepaste tekst, anders retourneer het resultaat van VLOOKUP.
Stel dat u in onze voorbeeldtabel de vakken wilt retourneren waarin leerlingen gezakt zijn voor toetsen. Voor degenen die alle toetsen met goed gevolg hebben afgelegd, wordt "Geen gezakte toetsen" weergegeven.
Om de onderwerpen op te zoeken, maken we deze klassieke VLOOKUP-formule:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
En dan nestelen in de hierboven besproken algemene IF ISNA-formule:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No failed tests", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
In Excel 2013 en latere versies kunt u de IFNA-functie gebruiken om #N/A-fouten op te vangen en af te handelen. Dit maakt uw formule korter en gemakkelijker leesbaar.
Als voorbeeld vervangen we #N/A fouten door streepjes ("-") en krijgen we deze elegante oplossing:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
De gebruikers van Excel 365 en 2021 hebben helemaal geen wrapper-functie nodig, omdat de moderne opvolger van VLOOKUP, de XLOOKUP-functie, van nature #N/A-fouten kan verwerken:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Het resultaat zal precies hetzelfde zijn als in de bovenstaande schermafbeelding.
SUMPRODUCT ISNA-formule om #N/A-fouten te tellen
Om #N/A-fouten in een bepaald bereik te tellen, gebruikt u de functie ISNA samen met SUMPRODUCT op deze manier:
SUMPRODUCT(--ISNA( reeks ))Hier geeft ISNA een matrix van TRUE en FALSE waarden, de dubbele negatie (--) zet de logische waarden om in 1's en 0's, en SUMPRODUCT telt het resultaat op.
Om bijvoorbeeld na te gaan hoeveel leerlingen voor alle toetsen zijn geslaagd, wijzigt u de MATCH-formule voor een bereik van opzoekwaarden (A3:A14) en nestelt u deze in ISNA:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0))
De formule bepaalt dat 9 leerlingen geen gezakte toetsen hebben, d.w.z. de MATCH-functie geeft 9 #N/A fouten:
Dat is hoe u ISNA-formules maakt en gebruikt in Excel. Ik dank u voor het lezen en zie u graag volgende week op onze blog!
Beschikbare downloads
ISNA formulevoorbeelden (.xlsx bestand)
