Tabla de contenido
Este tutorial se sumerge en varias formas de utilizar la función ISNA en Excel para manejar errores #N/A.
Cuando Excel no puede encontrar lo que se le pide, aparece un error #N/A en una celda. Para interceptar y gestionar estos errores, puede utilizar la función ISNA. ¿Cuál es su utilidad práctica? Básicamente, ayuda a que sus fórmulas sean más fáciles de usar y sus hojas de cálculo tengan mejor aspecto.
Función ISNA en Excel
La función ISNA de Excel se utiliza para comprobar celdas o fórmulas en busca de errores #N/A. El resultado es un valor lógico: TRUE si se detecta un error #N/A, FALSE en caso contrario.
La función está disponible en todas las versiones de Excel 2000 a 2021 y Excel 365.
La sintaxis de la función ISNA es de lo más sencilla:
ISNA(valor)Dónde valor es el valor de la celda o fórmula que desea comprobar si hay errores #N/A.
Para crear una fórmula ISNA en su forma básica, proporcione una referencia de celda como único argumento:
=ISNA(A2)
En caso de que la celda referenciada contenga un error #N/A, obtendrá TRUE. En caso de cualquier otro error, valor o celda en blanco, obtendrá FALSE:
Cómo utilizar ISNA en Excel
Utilizar la función ISNA en su forma pura tiene poco sentido práctico. Más a menudo, se utiliza junto con otras funciones para evaluar el resultado de una determinada fórmula. Para ello, basta con poner esa otra fórmula en la función valor argumento de ISNA:
ISNA( tu_fórmula ())En el siguiente conjunto de datos, supongamos que desea comparar dos listas (columnas A y D) e identificar los nombres que están presentes en ambas listas y los que sólo aparecen en la lista 1.
Para comparar el nombre en A3 contra cada nombre en la columna D, la fórmula es:
=MATCH(A3, $D$2:$D$9, 0)
Si se encuentra un valor de búsqueda, la función MATCH devuelve su posición relativa en la matriz de búsqueda, de lo contrario se produce un error #N/A. Para comprobar el resultado de MATCH, lo anidamos en ISNA:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Esta fórmula va a B3, y luego se copia a través de B14.
Ahora puede ver claramente qué alumnos han superado todas las pruebas (no aparece un nombre en la columna D> MATCH devuelve #N/A> ISNA devuelve TRUE) y cuáles tienen al menos una prueba fallida (aparece un nombre en la columna D> no hay error> ISNA devuelve FALSE).
Sugerencia. En Excel 365 y Excel 2021, puede utilizar una función más moderna XMATCH. en lugar de MATCH.
Fórmula IF ISNA en Excel
Por diseño, la función ISNA sólo puede devolver dos valores booleanos. Para mostrar sus mensajes personalizados, utilícela en combinación con la función IF:
IF(ISNA(...), " text_if_error ", " text_if_no_error ")Afinando un poco más nuestro ejemplo, vamos a averiguar qué alumnos del grupo A no han suspendido ningún examen y devolveremos para ellos "Ningún examen suspendido". Para el resto de alumnos, devolveremos "Suspendido". Para ello, incrustaremos la fórmula ISNA MATCH en la prueba lógica de IF, de forma que IF se convierta en la función más externa:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "Ninguna prueba fallida", "Fallida")
Los resultados parecen ahora mucho mejores y más intuitivos, ¿estás de acuerdo?
Cómo utilizar ISNA en Excel con VLOOKUP
La combinación IF ISNA es una solución universal que puede utilizarse con cualquier función que busque algo en un conjunto de datos y devuelva un error #N/A cuando no se encuentre un valor de búsqueda.
La sintaxis de la función ISNA con VLOOKUP es la siguiente:
IF(ISNA(VLOOKUP(...), " texto_personalizado ", VLOOKUP(...))Traducido a un lenguaje humano, dice: si VLOOKUP resulta en un error #N/A, devuelve texto personalizado, de lo contrario devuelve el resultado de VLOOKUP.
En nuestra tabla de ejemplo, supongamos que desea devolver las asignaturas en las que los alumnos han suspendido exámenes. Para los que han superado todos los exámenes con éxito, se mostrará "Ningún examen suspendido".
Para buscar los temas, construimos esta clásica fórmula VLOOKUP:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Y luego anidarlo en la fórmula genérica IF ISNA comentada anteriormente:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Ninguna prueba fallida", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
En Excel 2013 y versiones posteriores, puede utilizar la función IFNA para capturar y manejar errores #N/A. Esto hace que su fórmula sea más corta y más fácil de leer.
Como ejemplo, sustituimos los errores #N/A por guiones ("-") y obtenemos esta elegante solución:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Los usuarios de Excel 365 y 2021 no necesitan ninguna función de envoltura en absoluto, ya que el sucesor moderno de VLOOKUP, la función XLOOKUP, puede manejar errores #N/A de forma nativa:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
El resultado será exactamente el mismo que se muestra en la captura de pantalla anterior.
Fórmula SUMPRODUCT ISNA para contar los errores #N/A
Para contar los errores #N/A en un rango determinado, utilice la función ISNA junto con SUMPRODUCT de esta forma:
SUMPRODUCTO(--ISNA( gama ))Aquí, ISNA devuelve una matriz de valores TRUE y FALSE, la doble negación (--) coacciona los valores lógicos en 1's y 0's, y SUMPRODUCT suma el resultado.
Por ejemplo, para saber cuántos alumnos han aprobado todos los exámenes, modifique la fórmula MATCH para un rango de valores de búsqueda (A3:A14) y anídela en ISNA:
=SUMPRODUCTO(--ISNA(MATCH(A3:A14, D2:D9, 0)))
La fórmula determina que 9 alumnos no han suspendido ningún examen, es decir, la función MATCH devuelve 9 errores #N/A:
Así es como se crean y utilizan las fórmulas ISNA en Excel. Te doy las gracias por leer y ¡espero verte en nuestro blog la semana que viene!
Descargas disponibles
Ejemplos de fórmulas ISNA (archivo .xlsx)
