Denne vejledning dykker ned i forskellige måder at bruge ISNA-funktionen i Excel til at håndtere #N/A-fejl på.

Når Excel ikke kan finde det, som den bliver bedt om, vises en #N/A-fejl i en celle. For at opfange og håndtere sådanne fejl kan du bruge ISNA-funktionen. Hvad er den praktiske anvendelse af det? Den hjælper grundlæggende med at gøre dine formler mere brugervenlige og dine regneark flottere.

ISNA-funktion i Excel

Excel-funktionen ISNA bruges til at kontrollere celler eller formler for #N/A-fejl. Resultatet er en logisk værdi: TRUE, hvis der er fundet en #N/A-fejl, ellers FALSE.

Funktionen er tilgængelig i alle versioner af Excel 2000 til og med 2021 og Excel 365.

Syntaksen for ISNA-funktionen er så enkel, som den overhovedet kan være:

Hvor værdi er den celleværdi eller formel, som du vil kontrollere for #N/A-fejl.

Hvis du vil oprette en ISNA-formel i sin grundform, skal du angive en cellehenvisning som det eneste argument:

=ISNA(A2)

Hvis den celle, der henvises til, indeholder en #N/A-fejl, får du TRUE. Hvis der er en anden fejl, værdi eller en tom celle, får du FALSE:

Sådan bruger du ISNA i Excel

Det giver ikke meget praktisk mening at bruge ISNA-funktionen i sin rene form. Oftest bruges den sammen med andre funktioner til at evaluere resultatet af en bestemt formel. Til dette formål skal du blot sætte den anden formel ind i værdi argument fra ISNA:

Antag, at du i nedenstående datasæt vil sammenligne to lister (kolonne A og D) og identificere de navne, der findes i begge lister, og de navne, der kun findes i liste 1.

For at sammenligne navnet i A3 med hvert navn i kolonne D er formlen:

=MATCH(A3, $D$2:$D$9, 0)

Hvis der findes en opslagsværdi, returnerer MATCH-funktionen dens relative position i opslagsarrayet, ellers opstår der en #N/A-fejl. For at teste resultatet af MATCH indlejrer vi den i ISNA:

=ISNA(MATCH(A3, $D$2:$D$9, 0))

Denne formel går til B3 og kopieres derefter gennem B14.

Nu kan du tydeligt se, hvilke elever der har bestået alle prøverne (der findes ikke et navn i kolonne D> MATCH returnerer #N/A> ISNA returnerer TRUE), og hvilke elever der har mindst én fejlslagen prøve (der findes et navn i kolonne D> ingen fejl> ISNA returnerer FALSE).

Tip. I Excel 365 og Excel 2021 kan du bruge en mere moderne XMATCH-funktion i stedet for MATCH.

IF ISNA-formel i Excel

ISNA-funktionen kan kun returnere to boolske værdier. Hvis du vil vise dine brugerdefinerede meddelelser, skal du bruge den sammen med IF-funktionen:

Hvis vi finpudser vores eksempel lidt yderligere, kan vi finde ud af, hvilke elever fra gruppe A der ikke dumpede nogen test, og returnere "Ingen dumpede test" for dem. For de resterende elever returnerer vi "Ikke bestået". For at gøre dette skal du indlejre ISNA MATCH-formlen i den logiske test af IF, så IF bliver den yderste funktion:

=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "Ingen fejlslagne prøver", "Fejlslagen")

Resultaterne ser meget bedre og mere intuitive ud nu, er du enig?

Sådan bruger du ISNA i Excel med VLOOKUP

IF ISNA-kombinationen er en universel løsning, der kan bruges med enhver funktion, der søger efter noget i et datasæt og returnerer en #N/A-fejl, når en opslagsværdi ikke findes.

Syntaksen for ISNA-funktionen med VLOOKUP er som følger:

Oversat til et menneskeligt sprog står der: Hvis VLOOKUP resulterer i en #N/A-fejl, returneres brugerdefineret tekst, ellers returneres VLOOKUP-resultatet.

I vores eksempeltabel antager vi, at du ønsker at returnere de fag, hvor eleverne ikke bestod prøverne. For dem, der har bestået alle prøverne med succes, vises "Ingen dumpede prøver".

For at slå emnerne op, konstruerer vi denne klassiske VLOOKUP-formel:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

Og derefter indlejres den i den generiske IF ISNA-formel, der er beskrevet ovenfor:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Ingen fejlslagne prøver", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

I Excel 2013 og nyere versioner kan du bruge IFNA-funktionen til at fange og håndtere #N/A-fejl. Dette gør din formel kortere og lettere at læse.

Som et eksempel erstatter vi #N/A-fejl med streger ("-") og får denne elegante løsning:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")

Brugere af Excel 365 og 2021 har slet ikke brug for nogen wrapper-funktion, da den moderne efterfølger til VLOOKUP, XLOOKUP-funktionen, kan håndtere #N/A-fejl i den oprindelige form:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")

Resultatet bliver nøjagtig det samme som vist i skærmbilledet ovenfor.

SUMPRODUCT ISNA-formel til at tælle #N/A-fejl

Hvis du vil tælle #N/A-fejl i et bestemt område, skal du bruge ISNA-funktionen sammen med SUMPRODUCT på denne måde:

Her returnerer ISNA et array af værdierne TRUE og FALSE, den dobbelte negation (--) tvinger de logiske værdier til at blive til 1'er og 0'er, og SUMPRODUCT lægger resultatet sammen.

Hvis du f.eks. vil finde ud af, hvor mange studerende der bestod alle prøverne, skal du ændre MATCH-formlen for et område af opslagsværdier (A3:A14) og indlejre den i ISNA:

=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))

Formlen fastslår, at 9 elever ikke har dumpet nogen prøver, dvs. MATCH-funktionen returnerer 9 #N/A-fejl:

Det er sådan, du kan oprette og bruge ISNA-formler i Excel. Tak for din læsning, og jeg glæder mig til at se dig på vores blog i næste uge!

Tilgængelige downloads

ISNA-formeleksempler (.xlsx-fil)