Daftar Isi
Tutorial ini membahas berbagai cara menggunakan fungsi ISNA di Excel untuk menangani kesalahan # N / A.
Ketika Excel tidak dapat menemukan apa yang diminta, kesalahan # N / A muncul di sel. Untuk mencegat dan menangani kesalahan seperti itu, Anda dapat menggunakan fungsi ISNA. Apa kegunaan praktisnya? Pada dasarnya, ini membantu membuat rumus Anda lebih ramah pengguna dan lembar kerja Anda terlihat lebih baik.
Fungsi ISNA di Excel
Fungsi Excel ISNA digunakan untuk memeriksa sel atau rumus untuk kesalahan # N / A. Hasilnya adalah nilai logis: TRUE jika kesalahan # N / A terdeteksi, FALSE sebaliknya.
Fungsi ini tersedia di semua versi Excel 2000 hingga 2021 dan Excel 365.
Sintaks fungsi ISNA sesederhana mungkin:
ISNA (nilai)Di mana nilai adalah nilai sel atau rumus yang ingin Anda periksa untuk kesalahan # N / A.
Untuk membuat rumus ISNA dalam bentuk dasarnya, berikan referensi sel sebagai satu-satunya argumen:
=ISNA(A2)
Jika sel yang direferensikan berisi kesalahan # N / A, Anda akan mendapatkan TRUE. Jika ada kesalahan, nilai, atau sel kosong lainnya, Anda akan mendapatkan FALSE:
Cara menggunakan ISNA di Excel
Menggunakan fungsi ISNA dalam bentuk murninya memiliki sedikit arti praktis. Lebih sering, fungsi ini digunakan bersama dengan fungsi-fungsi lain untuk mengevaluasi hasil dari formula tertentu. Untuk ini, cukup masukkan formula lain itu ke dalam nilai argumen ISNA:
ISNA( rumus_Anda ())Dalam dataset di bawah ini, misalkan anda ingin membandingkan dua daftar (kolom A dan D) dan mengidentifikasi nama-nama yang ada di kedua daftar dan yang hanya muncul di daftar 1.
Untuk membandingkan nama di A3 dengan setiap nama di kolom D, rumusnya adalah:
=MATCH(A3, $D$2:$D$9, 0)
Jika nilai pencarian ditemukan, fungsi MATCH mengembalikan posisi relatifnya dalam larik pencarian, jika tidak, kesalahan #N/A akan terjadi. Untuk menguji hasil MATCH, kita menyarangkannya di ISNA:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Rumus ini masuk ke B3, dan kemudian disalin melalui B14.
Sekarang, anda bisa melihat dengan jelas siswa mana yang telah lulus semua tes (sebuah nama tidak tersedia dalam kolom D> MATCH mengembalikan #N/A> ISNA mengembalikan TRUE) dan mana yang memiliki setidaknya satu tes yang gagal (sebuah nama muncul dalam kolom D> tidak ada kesalahan> ISNA mengembalikan FALSE).
Tip. Di Excel 365 dan Excel 2021, Anda dapat menggunakan fungsi XMATCH yang lebih modern. bukan MATCH.
JIKA rumus ISNA di Excel
Secara desain, fungsi ISNA hanya dapat mengembalikan dua nilai Boolean. Untuk menampilkan pesan kustom Anda, gunakan dalam kombinasi dengan fungsi IF:
IF(ISNA(...), " text_if_error ", " text_if_no_error ")Menyempurnakan contoh kita sedikit lebih jauh, mari kita cari tahu siswa mana dari kelompok A yang tidak gagal dalam tes apapun dan mengembalikan "Tidak ada tes yang gagal" untuk mereka. Untuk siswa yang tersisa, kita akan mengembalikan "Gagal". Untuk melakukan ini, sematkan rumus ISNA MATCH dalam tes logika IF, sehingga IF menjadi fungsi terluar:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "Tidak ada tes yang gagal", "Gagal")
Hasilnya terlihat jauh lebih baik dan lebih intuitif sekarang, setuju?
Cara menggunakan ISNA di Excel dengan VLOOKUP
Kombinasi IF ISNA adalah solusi universal yang bisa digunakan dengan fungsi apapun yang mencari sesuatu dalam sekumpulan data dan mengembalikan error #N/A ketika nilai pencarian tidak ditemukan.
Sintaks fungsi ISNA dengan VLOOKUP adalah sebagai berikut:
IF(ISNA(VLOOKUP(...), " custom_text ", VLOOKUP(...))Diterjemahkan ke dalam bahasa manusia, dikatakan: jika VLOOKUP menghasilkan kesalahan #N/A, kembalikan teks khusus, jika tidak, kembalikan hasil VLOOKUP.
Dalam tabel contoh kita, asumsikan Anda ingin mengembalikan mata pelajaran di mana para siswa gagal dalam tes. Bagi mereka yang telah lulus semua tes dengan sukses, "Tidak ada tes yang gagal" akan ditampilkan.
Untuk mencari subyek, kita membuat rumus VLOOKUP klasik ini:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Dan kemudian menyarangkannya dalam rumus IF ISNA umum yang dibahas di atas:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Tidak ada tes yang gagal", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Di Excel 2013 dan versi yang lebih baru, Anda dapat menggunakan fungsi IFNA untuk menangkap dan menangani kesalahan # N / A. Ini membuat rumus Anda lebih pendek dan lebih mudah dibaca.
Sebagai contoh, kita mengganti galat #N/A dengan tanda hubung ("-") dan mendapatkan solusi elegan ini:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Pengguna Excel 365 dan 2021 tidak memerlukan fungsi wrapper sama sekali karena penerus modern VLOOKUP, fungsi XLOOKUP, dapat menangani kesalahan # N / A secara native:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Hasilnya akan persis sama seperti yang ditunjukkan pada screenshot di atas.
Rumus SUMPRODUCT ISNA untuk menghitung kesalahan #N/A
Untuk menghitung kesalahan #N/A dalam kisaran tertentu, gunakan fungsi ISNA bersama dengan SUMPRODUCT dengan cara ini:
SUMPRODUCT(--ISNA( rentang ))Di sini, ISNA mengembalikan larik nilai TRUE dan FALSE, negasi ganda (--) memaksa nilai logika menjadi 1 dan 0, dan SUMPRODUCT menjumlahkan hasilnya.
Misalnya, untuk mengetahui berapa banyak siswa yang berhasil dalam semua tes, modifikasi rumus MATCH untuk rentang nilai pencarian (A3:A14) dan sarangkan di ISNA:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0))))
Rumus menentukan bahwa 9 siswa tidak memiliki tes yang gagal, yaitu fungsi MATCH mengembalikan 9 kesalahan # N / A:
Itulah cara membuat dan menggunakan rumus ISNA di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!
Unduhan yang tersedia
Contoh rumus ISNA (file .xlsx)
