Агуулгын хүснэгт
Энэ заавар нь #N/A алдааг зохицуулахын тулд Excel-ийн ISNA функцийг ашиглах янз бүрийн арга замыг харуулсан.
Хэрэв Excel асуусан зүйлээ олж чадахгүй бол #N/ Нүдэнд алдаа гарч ирнэ. Ийм алдааг таслан зогсоох, зохицуулахын тулд та ISNA функцийг ашиглаж болно. Үүний практик хэрэглээ юу вэ? Үндсэндээ энэ нь таны томьёог хэрэглэгчдэд ээлтэй, ажлын хуудсыг илүү сайн харагдуулахад тусалдаг.
Excel дээрх ISNA функц
Excel ISNA функц нь нүднүүдийг шалгахад ашиглагддаг. эсвэл #N/A алдааны томъёо. Үр дүн нь логик утга юм: Хэрэв #Үгүй алдаа илэрсэн бол ҮНЭН, үгүй бол ХУДАЛ болно.
Функц нь Excel 2000-2021 болон Excel 365-ын бүх хувилбарт боломжтой.
ISNA функцийн синтакс нь байж болохуйц энгийн:
ISNA(утга)Энд утга нь таны #N/A алдааг шалгахыг хүсэж буй нүдний утга эсвэл томьёо юм.
ISNA томъёог үндсэн хэлбэрээр нь үүсгэхийн тулд нүдний лавлагааг түүний цорын ганц аргумент болгон оруулна уу:
=ISNA(A2)
Хэрэв лавлагаа өгсөн нүдэнд #N/A алдаа байгаа бол, чи ҮНЭН болно. Бусад алдаа, утга эсвэл хоосон нүд гарсан тохиолдолд та ХУДАЛ авах болно:
Excel дээр ISNA-г хэрхэн ашиглах талаар
ISNA функцийг ашиглах нь цэвэр хэлбэрээр нь практик утга багатай. Ихэнхдээ энэ нь тодорхой томъёоны үр дүнг үнэлэхийн тулд бусад функцуудтай хамт хэрэглэгддэг. Үүний тулд өөр томьёог ISNA-н утга аргументад оруулна уу:
ISNA( таны_томьёо())Доорх өгөгдлийн багцад та хоёр жагсаалтыг (A ба D багана) харьцуулж, жагсаалтад байгаа болон зөвхөн жагсаалтад байгаа нэрсийг тодорхойлохыг хүсч байна гэж бодъё. 1.
A3 дээрх нэрийг D баганын нэр тус бүртэй харьцуулахын тулд дараах томьёо:
=MATCH(A3, $D$2:$D$9, 0)
Хэрэв хайлтын утга олдвол MATCH функц нь түүний утгыг буцаана. хайх массив дахь харьцангуй байрлал, эс бөгөөс #N/A алдаа гарна. MATCH-ын үр дүнг шалгахын тулд бид үүнийг ISNA-д оруулдаг:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Энэ томьёог B3 руу оруулаад дараа нь B14-ээр хуулж авна.
Одоо та ойлгомжтой болгох боломжтой. Аль оюутнууд бүх шалгалтад тэнцсэнийг харна уу (D > баганад нэр байхгүй; MATCH нь #Үгүй >-ийг буцаана; ISNA нь ҮНЭН-ийг буцаана) болон хамгийн багадаа нэг шалгалтанд тэнцээгүй (D баганад нэр гарч ирнэ > алдаа байхгүй) > ISNA нь ХУДАЛ буцаана).
Зөвлөгөө. Excel 365 болон Excel 2021 дээр та илүү орчин үеийн XMATCH функцийг ашиглаж болно. MATCH-ын оронд.
IF ISNA томъёо Excel-д
Зохиомлоор ISNA функц нь зөвхөн хоёр Булийн утгыг буцаана. Захиалгат мессежээ харуулахын тулд үүнийг IF функцтэй хослуулан ашиглана уу:
IF(ISNA(…), " алдаа_текст", " алдаа_болоогүй_текст")Бидний Жишээ нь, А бүлгийн аль сурагч ямар ч шалгалтанд тэнцээгүйг олж мэдээд "Амжилтгүй шалгалт байхгүй" гэж хариулъя. Үлдсэн оюутнуудын хувьд бид "Бүтэлгүйтсэн" гэж буцаана. Үүнийг хийхийн тулд ISNA MATCH томъёог оруулаарайIF-ийн логик тест, ингэснээр IF нь хамгийн гадна талын функц болох болно:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
Үр дүн нь одоо илүү сайн, илүү ойлгомжтой харагдаж байна, зөвшөөрч байна уу?
Excel-д ISNA-г VLOOKUP-тай хэрхэн ашиглах талаар
IF ISNA хослол нь өгөгдлийн багцаас ямар нэг зүйлийг хайж, #N/A алдаа гаргадаг бүх функцэд ашиглах боломжтой бүх нийтийн шийдэл юм. хайлтын утга олдохгүй үед.
VLOOKUP-тай ISNA функцын синтакс дараах байдалтай байна:
IF(ISNA(VLOOKUP(…), " custom_text", VLOOKUP( …))Хүний хэл рүү орчуулбал, хэрэв VLOOKUP үр дүнд #N/A алдаа гарвал захиалгат текстийг буцаана, үгүй бол VLOOKUP-ын үр дүнг буцаана.
Манай жишээ хүснэгтэд та үүнийг хийхийг хүсэж байна гэж бодъё. Сурагчдын шалгалтанд тэнцээгүй сэдвүүдийг буцаана. Бүх шалгалтыг амжилттай өгсөн хүмүүсийн хувьд "Амжилтгүй шалгалт байхгүй" гэсэн бичиг гарч ирнэ.
Сэдвүүдийг хайхын тулд бид энэхүү сонгодог VLOOKUP томьёог бүтээнэ:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Дараа нь дээр дурдсан ерөнхий IF ISNA томъёонд үүнийг оруулаарай:
84 51
Excel 2013 болон түүнээс хойшхи хувилбаруудад та #N/A алдааг барьж, зохицуулахын тулд IFNA функцийг ашиглаж болно. Энэ нь таны томъёог богиносгож, уншихад хялбар болгоно.
Жишээ нь бид #N/A алдааг зураасаар ("-") сольж, дараах гоёмсог шийдлийг олж авдаг:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Excel 365 болон 2021-ийн хэрэглэгчид VLOOKUP-ийн орчин үеийн залгамжлагчийн хувьд ямар ч боодлын функц хэрэггүй.XLOOKUP функц нь #N/A алдааг өөрөө зохицуулах боломжтой:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Үр дүн нь дээрх дэлгэцийн агшинд үзүүлсэнтэй яг ижил байх болно.
Тоолох SUMPRODUCT ISNA томьёо. #Үгүй алдаа
Тодорхой муж дахь #N/A алдааг тоолохын тулд ISNA функцийг SUMPRODUCT-тай хамт дараах байдлаар ашиглана уу:
SUMPRODUCT(--ISNA( муж). ))Энд ISNA нь ҮНЭН ба ХУДАЛ утгуудын массивыг буцаадаг бөгөөд давхар үгүйсгэх (--) нь логик утгуудыг 1 ба 0-д шахаж, SUMPRODUCT үр дүнг нэгтгэдэг.
Жишээ нь: Хэдэн сурагч бүх шалгалтыг амжилттай давсан болохыг олж мэдээд, хайлтын утгуудын мужид (A3:A14) MATCH томьёог өөрчилж, ISNA-д оруулах:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))
Томъёо нь 9 сурагч болохыг тодорхойлдог. бүтэлгүйтсэн тест байхгүй, өөрөөр хэлбэл, MATCH функц нь 9 #N/A алдааг буцаана:
Ингэж Excel-д ISNA томьёо үүсгэж ашиглах боломжтой. Уншиж байгаад баярлалаа, ирэх долоо хоногт манай блог дээр уулзахыг тэсэн ядан хүлээж байна!
Татаж авах боломжтой зүйлс
ISNA томъёоны жишээнүүд (.xlsx файл)
