Enhavtabelo
Ĉi tiu lernilo plonĝas en diversajn manierojn uzi la ISNA-funkcion en Excel por trakti #N/A-erarojn.
Kiam Excel ne povas trovi tion, kion ĝi estas petita, #N/ Eraro aperas en ĉelo. Por kapti kaj trakti tiajn erarojn, vi povas uzi la ISNA-funkcion. Kio estas la praktika uzo de tio? Esence, ĝi helpas igi viajn formulojn pli afablajn kaj viajn laborfoliojn pli bone aspekti.
ISNA-funkcio en Excel
La Excel ISNA-funkcio estas uzata por kontroli ĉelojn. aŭ formuloj por #N/A eraroj. La rezulto estas logika valoro: VERA se #N/A eraro estas detektita, MALSA alie.
La funkcio disponeblas en ĉiuj versioj de Excel 2000 ĝis 2021 kaj Excel 365.
La sintakso de la ISNA-funkcio estas tiel simpla kiel ĝi eble povus esti:
ISNA(valoro)Kie valoro estas la ĉela valoro aŭ formulo, kiun vi volas kontroli por #N/A eraroj.
Por krei ISNA-formulon en ĝia baza formo, liveru ĉelreferencon kiel ĝia nura argumento:
=ISNA(A2)
Se la referencita ĉelo enhavas #N/A eraron, vi ricevos VERA. En kazo de iu alia eraro, valoro aŭ malplena ĉelo, vi ricevos FALSE:
Kiel uzi ISNA en Excel
Uzante la ISNA-funkcion en sia pura formo havas malmulte da praktika senco. Pli ofte, ĝi estas uzata kune kun aliaj funkcioj por taksi la rezulton de certa formulo. Por tio, simple metu tiun alian formulon en la argumenton valoro de ISNA:
ISNA( via_formulo())En la suba datumaro, supozu, ke vi volas kompari du listojn (kolumnoj A kaj D) kaj identigi la nomojn, kiuj ĉeestas en ambaŭ listoj kaj tiujn, kiuj aperas nur en listo. 1.
Por kompari la nomon en A3 kun ĉiu nomo en kolumno D, la formulo estas:
=MATCH(A3, $D$2:$D$9, 0)
Se serĉvaloro estas trovita, la MATCH funkcio liveras sian relativa pozicio en la serĉa tabelo, alie okazas eraro #N/A. Por testi la rezulton de MATCH, ni nestas ĝin en ISNA:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Ĉi tiu formulo iras al B3, kaj poste estas kopiita tra B14.
Nun, vi povas klare. vidu kiuj studentoj trapasis ĉiujn testojn (nomo ne haveblas en kolumno D > MATCH donas #N/A > ISNA donas VERA) kaj kiuj havas almenaŭ unu malsukcesan teston (nomo aperas en kolumno D > neniu eraro). > ISNA donas FALSE).
Konsileto. En Excel 365 kaj Excel 2021, vi povas uzi pli modernan XMATCH-funkcion. anstataŭ MATCH.
IF ISNA-formulo en Excel
Laŭ dezajno, la ISNA-funkcio povas nur redoni du buleajn valorojn. Por montri viajn kutimajn mesaĝojn, uzu ĝin kombine kun la funkcio IF:
IF(ISNA(…), " text_if_error", " text_if_no_error")Rafinante nian ekzemplo iom plu, ni eksciu, kiuj lernantoj de la grupo A ne malsukcesis iun teston kaj resendu "Neniu malsukcesintaj testoj" por ili. Por la ceteraj studentoj, ni resendos "Malsukcesis". Por fari tion, enmetu la formulon ISNA MATCH enla logika testo de IF, tiel ke IF fariĝas la plej ekstera funkcio:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
La rezultoj aspektas multe pli bone kaj pli intuiciaj nun, ĉu konsentas?
Kiel uzi ISNA en Excel kun VLOOKUP
La kombinaĵo IF ISNA estas universala solvo, kiu povas esti uzata kun iu ajn funkcio, kiu serĉas ion en aro da datumoj kaj redonas #N/A-eraro. kiam serĉvaloro ne estas trovita.
La sintakso de la ISNA-funkcio kun VLOOKUP estas jena:
IF(ISNA(VLOOKUP (...)), " persona_teksto", VLOOKUP( …))Tradukita en homan lingvon, ĝi diras: se VLOOKUP rezultigas #N/A-eraron, redonu kutiman tekston, alie redonu la rezulton de VLOOKUP.
En nia specimena tabelo, supozu, ke vi volas redonu la fakojn en kiuj studentoj malsukcesis testojn. Por tiuj, kiuj sukcese trapasis ĉiujn testojn, "Neniu malsukcesaj testoj" aperos.
Por serĉi la temojn, ni konstruas ĉi tiun klasikan VLOOKUP formulon:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Kaj poste nestu ĝin en la ĝenerala IF ISNA-formulo diskutita supre:
97 72
En Excel 2013 kaj posta versio, vi povas uzi la IFNA-funkcion por kapti kaj trakti #N/A-eraroj. Ĉi tio faras vian formulon pli mallonga kaj pli facile legebla.
Ekzemple, ni anstataŭigas #N/A-erarojn per streketoj ("-") kaj ricevas ĉi tiun elegantan solvon:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
La uzantoj de Excel 365 kaj 2021 tute ne bezonas ajnan envolvaĵfunkcion kiel la moderna posteulo de VLOOKUP, laXLOOKUP-funkcio, povas trakti #N/A-erarojn denaske:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
La rezulto estos ĝuste la sama kiel montrita en la supra ekrankopio.
SUMPRODUCT ISNA formulo por kalkuli #N/A eraroj
Por kalkuli #N/A-eraroj en certa intervalo, uzu la ISNA-funkcion kune kun SUMPRODUCT tiamaniere:
SUMPRODUCT(--ISNA( gamo))Ĉi tie, ISNA resendas tabelon de VERA kaj FALSA valoroj, la duobla neado (--) devigas la logikan valorojn en 1 kaj 0, kaj SUMPRODUKTO aldonas la rezulton.
Ekzemple, al eksciu kiom da studentoj sukcesis en ĉiuj testoj, modifi la MATCH-formulon por gamo da serĉvaloroj (A3:A14) kaj nestu ĝin en ISNA:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))
La formulo determinas, ke 9 studentoj ne havas malsukcesajn testojn, t.e. la MATCH-funkcio liveras 9 #N/A-eraroj:
Tiel krei kaj uzi ISNA-formulojn en Excel. Mi dankas vin pro legado kaj antaŭĝojas vidi vin en nia blogo venontsemajne!
Haveblaj elŝutoj
ISNA-formulekzemploj (.xlsx-dosiero)
