Edukien taula
Tutorial honek Excel-en ISNA funtzioa erabiltzeko hainbat modutan murgiltzen da #N/A akatsak kudeatzeko.
Excel-ek eskatutakoa aurkitu ezin duenean, #N/ bat Errore bat agertzen da gelaxka batean. Akats horiek atzemateko eta kudeatzeko, ISNA funtzioa erabil dezakezu. Zein da horren erabilera praktikoa? Funtsean, zure formulak erabilerrazagoak eta zure lan-orriak itxura hobea izaten laguntzen du.
ISNA funtzioa Excel-en
Excel ISNA funtzioa gelaxkak egiaztatzeko erabiltzen da. edo #N/A akatsetarako formulak. Emaitza balio logiko bat da: EGIA #N/A errore bat hautematen bada, GEZURRA bestela.
Funtzioa Excel 2000tik 2021era eta Excel 365 bertsio guztietan dago eskuragarri.
The ISNA funtzioaren sintaxia izan daitekeen bezain sinplea da:
ISNA(balioa)Non balioa #N/A akatsak dauden egiaztatu nahi duzun gelaxka-balioa edo formula den.
ISNA formula bat oinarrizko forman sortzeko, eman gelaxka-erreferentzia bat argumentu bakar gisa:
=ISNA(A2)
Erreferentziatutako gelaxkak #N/A errorea badu, EGIA lortuko duzu. Beste edozein errore, balio edo gelaxka hutsik izanez gero, GEZURRA lortuko duzu:
Nola erabili ISNA Excel-en
ISNA funtzioa erabiliz bere forma hutsean zentzu praktiko gutxi du. Gehiagotan, beste funtzio batzuekin batera erabiltzen da formula jakin baten emaitza ebaluatzeko. Horretarako, jarri beste formula hori ISNAren balioa argumentuan:
ISNA( zure_formula())Beheko datu-multzoan, demagun bi zerrenda alderatu nahi dituzula (A eta D zutabeak) eta identifikatu bi zerrendetan dauden izenak eta zerrendan bakarrik agertzen direnak. 1.
A3-ko izena D zutabeko izen bakoitzarekin alderatzeko, hau da formula:
=MATCH(A3, $D$2:$D$9, 0)
Bilaketa-balio bat aurkitzen bada, MATCH funtzioak bere itzultzen du. posizio erlatiboa bilaketa-matrizean, bestela #N/A errorea gertatzen da. MATCH-en emaitza probatzeko, ISNAn habiatzen dugu:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Formula hau B3ra doa, eta gero B14 bidez kopiatzen da.
Orain, argi eta garbi dezakezu ikusi zein ikaslek gainditu dituzten proba guztiak (izen bat ez dago eskuragarri D zutabean > MATCH-ek #N/A ematen du > ISNAk EGIA ematen du) eta zeintzuk izan diren gutxienez proba huts bat (izen bat D zutabean agertzen da > errorerik ez > ISNAk GEZURRA ematen du).
Aholkua. Excel 365 eta Excel 2021-en, XMATCH funtzio modernoagoa erabil dezakezu. MATCH-en ordez.
IF ISNA formula Excel-en
Diseinuaren arabera, ISNA funtzioak bi balio boolear bakarrik itzul ditzake. Zure mezu pertsonalizatuak bistaratzeko, erabili IF funtzioarekin batera:
IF(ISNA(…), " text_if_error", " text_if_no_error")Gure finketa Adibide pixka bat aurrerago, jakin dezagun A taldeko zein ikasleek ez zuten probarik gainditu eta itzul diezaiegun "Proba hutsik ez". Gainerako ikasleentzat, "Huts eginda" itzuliko dugu. Horretarako, txertatu ISNA MATCH formulaIF-ren proba logikoa, IF kanpoaldeko funtzioa bihur dadin:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
Emaitzak askoz hobeto eta intuitiboagoak dirudite orain, ados?
Nola erabili ISNA Excel-en VLOOKUP-ekin
IF ISNA konbinazioa datu multzo batean zerbait bilatzen duen eta #N/A errorea itzultzen duen edozein funtziorekin erabil daitekeen soluzio unibertsala da. Bilaketa-balio bat aurkitzen ez denean.
VLOOKUP duen ISNA funtzioaren sintaxia honako hau da:
IF(ISNA(VLOOKUP(…), " custom_text), VLOOKUP( …))Giza hizkuntza batera itzulita, zera dio: VLOOKUP-ek #N/A errorea eragiten badu, itzuli testu pertsonalizatua, bestela itzuli VLOOKUP-en emaitza.
Gure lagin-taulan, suposatu nahi duzula. itzuli ikasleek probak huts egin dituzten irakasgaiak. Proba guztiak arrakastaz gainditu dituztenentzat, "Proba hutsik ez" bistaratuko da.
Gaiak bilatzeko, VLOOKUP formula klasiko hau eraikiko dugu:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Eta habia ezazu goian aipatu dugun IF ISNA formula generikoan:
87 93
Excel 2013 eta ondorengo bertsioan, IFNA funtzioa erabil dezakezu #N/A akatsak harrapatzeko eta kudeatzeko. Honek zure formula laburragoa eta irakurterraza egiten du.
Adibide gisa, #N/A erroreak marratxoekin ordezkatzen ditugu ("-") eta irtenbide dotore hau lortzen dugu:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Excel 365 eta 2021-en erabiltzaileek ez dute inolako bilgarri-funtziorik behar VLOOKUP-en ondorengo moderno gisa,XLOOKUP funtzioa, #N/A akatsak berez kudea ditzake:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Emaitza goiko pantaila-argazkian erakusten den berdina izango da.
SUMPRODUCT ISNA zenbatzeko formula #N/A errors
Barruti jakin bateko #N/A erroreak zenbatzeko, erabili ISNA funtzioa SUMPRODUCT-ekin batera modu honetan:
SUMPRODUCT(--ISNA( barrutia))Hemen, ISNAk TRUE eta FALSE balioen matrize bat itzultzen du, ezeztapen bikoitzak (--) balio logikoak 1 eta 0etara behartzen ditu eta SUMPRODUCT emaitza batu du.
Adibidez, jakin zenbat ikaslek lortu duten proba guztietan, aldatu MATCH formula bilaketa-balio sorta baterako (A3:A14) eta habiatu ISNA-n:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))
Formulak 9 ikaslek zehazten du. ez izan proba hutsik, hau da, MATCH funtzioak 9 #N/A akats itzultzen ditu:
Horrela sortu eta erabili ISNA formulak Excel-en. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut!
Deskargak erabilgarri
ISNA formula adibideak (.xlsx fitxategia)
