Strādājot ar pārskatu, ieguldījumu plānu vai jebkuru citu datu kopu ar datumiem, bieži var rasties nepieciešamība summēt skaitļus konkrētā laika periodā. Šajā pamācībā jūs uzzināsiet ātru un vienkāršu risinājumu - SUMIFS formulu, kurā kā kritērijs ir datumu diapazons.

Mūsu emuārā un citos Excel forumos cilvēki bieži jautā, kā izmantot SUMIF datumu diapazonam. Runa ir par to, ka, lai summētu starp diviem datumiem, ir jādefinē abi datumi, savukārt Excel SUMIF funkcija ļauj izmantot tikai vienu nosacījumu. Par laimi, mums ir arī funkcija SUMIFS, kas atbalsta vairākus kritērijus.

Kā summēt, ja starp diviem datumiem programmā Excel

Lai saskaitītu vērtības noteiktā datumu diapazonā, izmantojiet SUMIFS formulu, kā kritērijus norādot sākuma un beigu datumu. SUMIFS funkcijas sintakse nosaka, ka vispirms jānorāda saskaitāmās vērtības (sum_range) un pēc tam jānorāda diapazona/kritēriju pāri. Mūsu gadījumā diapazons (datumu saraksts) būs vienāds abiem kritērijiem.

Ņemot vērā iepriekš minēto, vispārīgās formulas, lai summētu vērtības starp diviem datumiem, ir šādā formā:

Tostarp robežvērtību datumi:

Izņemot robeždatumus:

Kā redzat, atšķirība ir tikai loģiskajos operatoros. Pirmajā formulā mēs izmantojam lielāks par vai vienāds ar (>=) un mazāks vai vienāds ar (<=), lai iekļautu robeždatus rezultātos. Otrajā formulā tiek pārbaudīts, vai datums ir lielāks par (>) vai mazāk nekā (<), izlaižot sākuma un beigu datumu.

Pieņemsim, ka turpmāk dotajā tabulā vēlaties summēt projektus, kuru izpildes termiņš ir konkrētā datumu intervālā, ieskaitot. Lai to izdarītu, izmantojiet šo formulu:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020").

Ja nevēlaties formulā kodēt datumu diapazonu, varat ievadīt sākuma datumu F1, beigu datumu G1, savienot loģiskos operatorus un šūnu atsauces un visu kritēriju ietvert pēdiņās, piemēram, šādā veidā:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Lai izvairītos no iespējamām kļūdām, datumus var ievadīt, izmantojot funkciju DATE:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

Summa dinamiskā diapazonā, pamatojoties uz šodienas datumu.

Ja nepieciešams apkopot datus dinamiskā datumu diapazonā (X dienas atpakaļ no šodienas vai Y dienas uz priekšu), izveidojiet kritērijus, izmantojot funkciju TODAY, kas iegūs pašreizējo datumu un automātiski to atjauninās.

Piemēram, lai summētu budžetus, kuru izpildes termiņš ir pēdējās 7 dienās. ieskaitot šodienas datumu , formula ir šāda:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

Ja galarezultātā nevēlaties iekļaut pašreizējo datumu, izmantojiet vienumu mazāk nekā operators (<) pirmajam kritērijam, lai izslēgtu šodienas datumu un lielāks vai vienāds ar (>=) otrajam kritērijam, lai iekļautu datumu, kas ir 7 dienas pirms šodienas:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

Līdzīgā veidā varat summēt vērtības, ja datums ir noteikts dienu skaits uz priekšu.

Piemēram, lai iegūtu kopsummu par budžetiem, kuru izpildes termiņš ir nākamās 3 dienas, izmantojiet vienu no šādām formulām:

Rezultātā ir iekļauts šodienas datums:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

Šodienas datums nav iekļauts rezultātos:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

Summa, ja starp diviem datumiem un citu kritēriju

Lai summētu vērtības datuma diapazonā, kas atbilst kādam citam nosacījumam citā slejā, vienkārši pievienojiet SUMIFS formulai vēl vienu diapazonu/kritēriju pāri.

Piemēram, lai summētu visu projektu, kuru nosaukumā ir "tip", budžetus noteiktā datumu diapazonā, paplašiniet formulu ar aizstājējzīmju kritēriju:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

Kur A2:A10 ir projektu nosaukumi, B2:B10 ir summējamie skaitļi, C2:C10 ir pārbaudāmie datumi, F1 ir sākuma datums un G1 ir beigu datums.

Protams, nekas netraucē ievadīt trešo kritēriju arī atsevišķā šūnā un atsaukties uz šo šūnu, kā parādīts ekrāna attēlā:

SUMIFS datuma kritēriju sintakse

Kad runa ir par datumu kā kritēriju izmantošanu Excel SUMIF un SUMIFS funkcijām, jūs nebūsiet pirmais, kas apjuks :)

Tomēr, rūpīgāk aplūkojot visus daudzveidīgos izmantošanas gadījumus, var secināt, ka to pamatā ir tikai daži vienkārši noteikumi:

Ja datumus ievadāt tieši kritēriju argumenti , pēc tam ievadiet loģisko operatoru (>, <, =, ) tieši pirms datuma un ietveriet visu kritēriju pēdiņās, piemēram:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020").

Ja datums tiek ievadīts iepriekš noteiktā šūna , sniedziet kritērijus teksta virknes veidā: lai sāktu virkni, ielieciet loģisko operatoru pēdiņās un izmantojiet ampersandu (&), lai virkni apvienotu un pabeigtu, piemēram:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Ja datumu nosaka cita funkcija piemēram, DATE vai TODAY(), apvienojiet salīdzināšanas operatoru un funkciju. Piemēram:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

Excel SUMIFS starp datumiem nedarbojas

Ja jūsu formula nedarbojas vai sniedz nepareizus rezultātus, turpmāk minētie problēmu novēršanas padomi var palīdzēt noskaidrot, kāpēc tā nedarbojas, un novērst problēmu.

Pārbaudiet datumu un skaitļu formātu

Ja šķietami pareiza SUMIFS formula atgriež tikai nulli, vispirms pārbaudiet, vai datumi patiešām ir datumi, nevis teksta virknes, kas tikai izskatās kā datumi. Pēc tam pārliecinieties, vai summējat skaitļus, nevis skaitļus, kas saglabāti kā teksts. Turpmākās pamācības palīdzēs jums atklāt un novērst šīs problēmas.

• Kā mainīt "teksta datumus" uz reāliem datumiem
• Kā konvertēt tekstu uz numuru

Kritēriju pareizas sintakses lietošana

Pārbaudot datumus, izmantojot SUMIFS, datums jāieliek pēdiņās, piemēram, ">=9/10/2020"; šūnu atsauces un funkcijas jāieliek ārpus pēdiņām, piemēram, "<="&G1 vai "<="&TODAY(). Sīkāku informāciju skatiet sadaļā datuma kritēriju sintakse.

Formulas loģikas pārbaude

Neliela pārrakstīšanās kļūda budžetā var izmaksāt miljoniem. Neliela kļūda formulā var izmaksāt vairākas stundas atkļūdošanas laika. Tāpēc, saskaitot divus datumus, pārbaudiet, vai pirms sākuma datuma ir rakstīts sākuma datums. lielāks par (>) vai lielāks vai vienāds ar (>=) operators un beigu datums ir ar prefiksu mazāk nekā (<) vai mazāks par vai vienāds ar (<=).

Pārliecinieties, ka visi diapazoni ir vienāda izmēra

Lai SUMIFS funkcija darbotos pareizi, summas diapazonam un kritēriju diapazoniem jābūt vienāda lieluma, pretējā gadījumā rodas #VALUE! kļūda. Lai to novērstu, pārliecinieties, ka visi SUMIFS diapazoni ir vienāda lieluma. criteria_range argumentiem ir tāds pats rindu un kolonnu skaits kā sum_range .

Lūk, kā izmantot Excel SUMIFS funkciju, lai summētu datus datumu diapazonā. Ja jums ir kādi citi interesanti risinājumi, es būšu ļoti pateicīgs, ja dalīsieties komentāros. Paldies, ka izlasījāt, un ceru, ka nākamnedēļ tiksimies mūsu blogā!

Prakses darba burtnīca lejupielādei

SUMIFS datumu diapazona piemēri (.xlsx fails)