Ha egy jelentésen, befektetési terven vagy bármilyen más dátumokat tartalmazó adathalmazon dolgozol, gyakran előfordulhat, hogy egy adott időszakon belüli számokat kell összegezned. Ez a bemutató egy gyors és egyszerű megoldást tanít meg - a SUMIFS képletet dátumtartományt kritériumként használva.

A blogunkon és más Excel-fórumokon gyakran kérdezik, hogyan lehet a SUMIF-et dátumtartományra használni. A lényeg az, hogy két dátum közötti összegzéshez mindkét dátumot meg kell határoznunk, míg az Excel SUMIF függvénye csak egy feltételt enged meg. Szerencsére van a SUMIFS függvény is, amely több feltételt támogat.

Hogyan lehet összegezni, ha két dátum között az Excelben

Egy bizonyos dátumtartományon belüli értékek összegzéséhez használjon SUMIFS képletet, amelynek kritériumai a kezdő- és a végdátum. A SUMIFS függvény szintaxisa szerint először meg kell adnia az összeadandó értékeket (sum_range), majd meg kell adnia a tartomány/kritérium párokat. Esetünkben a tartomány (a dátumok listája) mindkét kritérium esetében ugyanaz lesz.

A fentieket figyelembe véve a két dátum közötti értékek összegzésére szolgáló általános képletek a következő formát ölthetik:

Beleértve a küszöbdátumokat is:

A küszöbdátumok kivételével:

Amint láthatjuk, a különbség csak a logikai operátorokban van. Az első képletben az alábbiakat használjuk nagyobb, mint vagy egyenlő (>=) és kisebb vagy egyenlő, mint (<=), hogy a küszöbdátumok is szerepeljenek az eredményben. A második képlet azt ellenőrzi, hogy egy dátum a következő-e nagyobb, mint (>) vagy kevesebb, mint (<), kihagyva a kezdő- és záró dátumot.

Az alábbi táblázatban tegyük fel, hogy egy adott dátumtartományban esedékes projekteket szeretnénk összegezni, beleértve a dátumokat is. Ehhez használjuk ezt a képletet:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Ha nem szeretné a képletben a dátumtartományt keményen kódolni, akkor a kezdő dátumot beírhatja az F1-be, a végdátumot a G1-be, a logikai operátorokat és a cellahivatkozásokat összekapcsolhatja, és az egész kritériumot idézőjelek közé zárhatja, így:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Az esetleges hibák elkerülése érdekében a dátumokat a DATE függvény segítségével adhatja meg:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

A mai dátumon alapuló dinamikus tartományon belüli összegzés

Abban az esetben, ha dinamikus dátumtartományon belüli adatokat kell összegeznie (X nappal a mai naptól visszafelé vagy Y nappal előre), a kritériumokat a TODAY függvény használatával alakíthatja ki, amely az aktuális dátumot kapja meg és automatikusan frissíti.

Például, az elmúlt 7 napban esedékes költségvetések összegzéséhez beleértve a mai dátumot is a képlet a következő:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

Ha nem szeretné, hogy az aktuális dátum szerepeljen a végeredményben, használja a kevesebb, mint operátor (<) az első kritériumhoz, hogy kizárja a mai dátumot és a nagyobb vagy egyenlő, mint (>=) a második feltételhez, hogy tartalmazza a dátumot, amely 7 nappal a mai nap előtt van:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

Hasonló módon összegezheti az értékeket, ha egy dátum adott számú nappal előrébb van.

Ha például a következő 3 napban esedékes költségvetések összegét szeretné megkapni, használja a következő képletek egyikét:

A mai dátum szerepel az eredményben:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

A mai dátum nem szerepel az eredményben:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

Sum ha két dátum és egy másik kritérium között

Ha olyan értékeket szeretne összegezni egy dátumtartományon belül, amelyek egy másik oszlopban egy másik feltételnek is megfelelnek, egyszerűen adjon hozzá még egy tartomány/feltétel párt a SUMIFS képlethez.

Például, ha egy bizonyos dátumtartományon belüli költségvetéseket szeretne összegezni az összes olyan projektre vonatkozóan, amelyek nevében szerepel a "tip" szó, akkor bővítse a képletet egy jokerfeltétellel:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

Ahol A2:A10 a projekt neve, B2:B10 az összegzendő számok, C2:C10 az ellenőrizendő dátumok, F1 a kezdeti dátum és G1 a végdátum.

Természetesen semmi sem akadályozza meg abban, hogy a harmadik kritériumot egy külön cellába is beírja, és a képernyőképen látható módon hivatkozzon erre a cellára:

SUMIFS dátumkritériumok szintaxis

Amikor a dátumokat az Excel SUMIF és SUMIFS függvények kritériumaként használjuk, nem ön lenne az első, aki összezavarodik :)

Közelebbről megnézve azonban a különböző felhasználási esetek sokfélesége néhány egyszerű szabályban merül ki:

Ha a dátumokat közvetlenül a kritériumok érvek , majd írjon be egy logikai operátort (>, <, =, ) közvetlenül a dátum előtt, és az egész kritériumot zárja idézőjelbe. Például:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Amikor egy dátumot adunk meg egy előre definiált sejt , a kritériumokat szöveges karakterlánc formájában adja meg: egy logikai operátort idézőjelek közé zárva kezdje a karakterláncot, és egy erősítőjelet (&) használjon a karakterlánc összekapcsolásához és befejezéséhez. Például:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Amikor egy dátumot a egy másik funkció mint például a DATE vagy a TODAY(), kapcsoljon össze egy összehasonlító operátort és egy függvényt. Például:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

Excel SUMIFS a dátumok között nem működik

Ha a képlet nem működik vagy rossz eredményeket produkál, a következő hibaelhárítási tippek rávilágíthatnak a hiba okára, és segíthetnek a probléma megoldásában.

Ellenőrizze a dátumok és számok formátumát

Ha egy látszólag helyes SUMIFS-képlet csak nullát ad vissza, először is ellenőrizze, hogy a dátumok valóban dátumok-e, és nem csak dátumnak látszó szöveges karakterláncok. Ezután győződjön meg róla, hogy számokat összegez, és nem szövegként tárolt számokat. A következő útmutatók segítenek felismerni és kijavítani ezeket a problémákat.

• Hogyan változtassuk a "szöveges dátumokat" valódi dátumokra?
• Hogyan lehet a szöveget számmá alakítani

A kritériumok helyes szintaxisának használata

Dátumok ellenőrzésénél a SUMIFS használatával a dátumot idézőjelek közé kell tenni, mint például ">=9/10/2020"; a cellahivatkozásokat és függvényeket az idézőjeleken kívül kell elhelyezni, mint például "<="&G1 vagy "<="&TODAY(). A teljes részleteket lásd a dátumkritériumok szintaxisában.

Ellenőrizze a képlet logikáját

Egy kis elírás a költségvetésben milliókba kerülhet. Egy kis hiba egy képletben órákba kerülhet a hibakeresés során. Tehát, amikor 2 dátum között összegezünk, ellenőrizzük, hogy a kezdő dátum előtt van-e a nagyobb, mint (>) vagy nagyobb vagy egyenlő, mint (>=) operátorral, és a végdátumot a következő előtaggal jelölik meg kevesebb, mint (<) vagy kisebb vagy egyenlő, mint (<=).

Győződjön meg róla, hogy minden tartomány azonos méretű

Ahhoz, hogy a SUMIFS függvény helyesen működjön, az összegtartománynak és a kritériumtartományoknak egyforma méretűeknek kell lenniük, különben #VALUE! hiba lép fel. A hiba kijavításához győződjön meg arról, hogy az összes criteria_range argumentumoknak ugyanannyi sora és oszlopa van, mint a sum_range .

Így használhatjuk az Excel SUMIFS függvényét egy dátumtartományban lévő adatok összegzésére. Ha van más érdekes megoldás is a fejedben, nagyon hálás lennék, ha megosztanád velünk kommentben. Köszönöm, hogy elolvastad, és remélem, jövő héten találkozunk a blogon!

Gyakorlati munkafüzet letölthető

SUMIFS dátumtartomány példák (.xlsx fájl)