Daftar Isi
Saat mengerjakan laporan, rencana investasi, atau dataset lainnya dengan tanggal, kamu mungkin sering perlu menjumlahkan angka dalam periode tertentu. Tutorial ini akan mengajarkanmu solusi cepat dan mudah - rumus SUMIFS dengan rentang tanggal sebagai kriteria.
Di blog kami dan forum Excel lainnya, orang sering bertanya bagaimana cara menggunakan SUMIF untuk rentang tanggal. Intinya adalah untuk menjumlahkan antara dua tanggal, Anda perlu menentukan kedua tanggal tersebut sedangkan fungsi SUMIF Excel hanya mengizinkan satu kondisi. Untungnya, kami juga memiliki fungsi SUMIFS yang mendukung banyak kriteria.
Bagaimana cara menjumlahkan jika di antara dua tanggal di Excel
Untuk menjumlahkan nilai dalam rentang tanggal tertentu, gunakan rumus SUMIFS dengan tanggal mulai dan akhir sebagai kriteria. Sintaks fungsi SUMIFS mengharuskan Anda terlebih dahulu menentukan nilai yang akan dijumlahkan (sum_range), lalu memberikan pasangan rentang/kriteria. Dalam kasus kami, rentang (daftar tanggal) akan sama untuk kedua kriteria.
Mempertimbangkan hal di atas, rumus umum untuk menjumlahkan nilai antara dua tanggal mengambil bentuk ini:
Termasuk tanggal ambang batas:
SUMIFS( sum_range , tanggal ,">= start_date ", tanggal , "<= end_date ")Tidak termasuk tanggal ambang batas:
SUMIFS( sum_range , tanggal ,"> start_date ", tanggal , "< end_date ")Seperti yang bisa Anda lihat, perbedaannya hanya pada operator logika. Pada rumus pertama, kita menggunakan lebih besar dari atau sama dengan (>=) dan kurang dari atau sama dengan (<=) untuk menyertakan tanggal ambang batas dalam hasil. Rumus kedua memeriksa apakah tanggal adalah lebih besar dari (>) atau kurang dari (<), dengan tidak mencantumkan tanggal mulai dan akhir.
Pada tabel di bawah ini, misalkan Anda ingin menjumlahkan proyek-proyek yang jatuh tempo dalam rentang tanggal tertentu, inklusif. Untuk menyelesaikannya, gunakan rumus ini:
=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")
Jika Anda lebih suka tidak membuat kode keras rentang tanggal dalam rumus, Anda dapat mengetikkan tanggal mulai di F1, tanggal akhir di G1, menggabungkan operator logika dan referensi sel, dan mengapit seluruh kriteria dalam tanda kutip seperti ini:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)
Untuk menghindari kesalahan yang mungkin terjadi, Anda bisa menyediakan tanggal dengan bantuan fungsi DATE:
=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))
Jumlah dalam rentang dinamis berdasarkan tanggal hari ini
Dalam situasi ketika Anda perlu menjumlahkan data dalam rentang tanggal dinamis (X hari ke belakang dari hari ini atau Y hari ke depan), buat kriteria dengan menggunakan fungsi TODAY, yang akan mendapatkan tanggal saat ini dan memperbaruinya secara otomatis.
Misalnya, untuk menjumlahkan anggaran yang jatuh tempo dalam 7 hari terakhir termasuk tanggal hari ini , rumusnya adalah:
=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)
Jika Anda lebih suka tidak menyertakan tanggal saat ini dalam hasil akhir, gunakan perintah kurang dari operator (<) untuk kriteria pertama untuk mengecualikan tanggal hari ini dan lebih besar dari atau sama dengan (>=) untuk kriteria kedua untuk menyertakan tanggal yang 7 hari sebelum hari ini:
=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)
Dengan cara yang sama, Anda bisa menjumlahkan nilai jika suatu tanggal adalah sejumlah hari ke depan.
Misalnya, untuk mendapatkan total anggaran yang jatuh tempo dalam 3 hari ke depan, gunakan salah satu rumus berikut ini:
Tanggal hari ini disertakan dalam hasil:
=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)
Tanggal hari ini tidak disertakan dalam hasil:
=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)
Jumlah jika di antara dua tanggal dan kriteria lain
Untuk menjumlahkan nilai dalam rentang tanggal yang memenuhi beberapa kondisi lain di kolom yang berbeda, cukup tambahkan satu lagi pasangan rentang/kriteria ke rumus SUMIFS Anda.
Misalnya, untuk menjumlahkan anggaran dalam rentang tanggal tertentu untuk semua proyek yang berisi "tip" dalam namanya, perluas formula dengan kriteria wildcard:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")
Di mana A2:A10 adalah nama proyek, B2:B10 adalah angka yang akan dijumlahkan, C2:C10 adalah tanggal yang akan diperiksa, F1 adalah tanggal mulai dan G1 adalah tanggal akhir.
Tentu saja, tidak ada yang menghalangi Anda untuk memasukkan kriteria ketiga dalam sel terpisah juga, dan mereferensikan sel itu seperti yang ditunjukkan pada tangkapan layar:
Sintaks kriteria tanggal SUMIFS
Ketika menggunakan tanggal sebagai kriteria untuk fungsi SUMIF dan SUMIFS Excel, Anda tidak akan menjadi orang pertama yang bingung :)
Namun, setelah melihat lebih dekat, semua variasi kasus penggunaan bermuara pada beberapa aturan sederhana:
Jika Anda menaruh tanggal secara langsung dalam argumen kriteria , kemudian ketik operator logika (>, <, =, ) tepat sebelum tanggal dan apit seluruh kriteria dalam tanda kutip. Sebagai contoh:
=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")
Apabila tanggal diinput dalam predefined sel , berikan kriteria dalam bentuk string teks: apit operator logika dalam tanda kutip untuk memulai string dan gunakan ampersand (&) untuk menggabungkan dan menyelesaikan string:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)
Apabila tanggal didorong oleh fungsi lain seperti DATE atau TODAY(), menggabungkan operator pembanding dan fungsi. Sebagai contoh:
=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())
Excel SUMIFS antara tanggal tidak berfungsi
Jika rumusmu tidak bekerja atau memberikan hasil yang salah, tips pemecahan masalah berikut ini dapat menjelaskan mengapa rumusmu gagal dan membantumu memperbaiki masalahnya.
Periksa format tanggal dan angka
Jika rumus SUMIFS yang tampaknya benar tidak menghasilkan apa pun kecuali nol, hal pertama yang harus diperiksa adalah bahwa tanggal Anda benar-benar tanggal, dan bukan string teks yang hanya terlihat seperti tanggal. Selanjutnya, pastikan Anda menjumlahkan angka, dan bukan angka yang disimpan sebagai teks. Tutorial berikut akan membantu Anda menemukan dan memperbaiki masalah ini.
- Cara mengubah "tanggal teks" ke tanggal yang sesungguhnya
- Cara mengonversi teks ke angka
Gunakan sintaks yang benar untuk kriteria
Ketika memeriksa tanggal menggunakan SUMIFS, tanggal harus diletakkan di dalam tanda kutip seperti ">=9/10/2020"; referensi sel dan fungsi harus diletakkan di luar tanda kutip seperti "<="&G1 atau "<="&TODAY(). Untuk detil lengkapnya, silahkan lihat sintaks kriteria tanggal.
Verifikasi logika rumus
Kesalahan ketik kecil dalam anggaran bisa menghabiskan jutaan dolar. Kesalahan kecil dalam rumus mungkin menghabiskan waktu berjam-jam untuk debugging. Jadi, ketika menjumlahkan antara 2 tanggal, periksa apakah tanggal mulai didahului oleh lebih besar dari (>) atau lebih besar dari atau sama dengan (>=) operator dan tanggal akhir diawali dengan kurang dari (<) atau kurang dari atau sama dengan (<=).
Pastikan semua rentang memiliki ukuran yang sama
Agar fungsi SUMIFS berfungsi dengan benar, rentang jumlah dan rentang kriteria harus berukuran sama, jika tidak, kesalahan #VALUE! terjadi. Untuk memperbaikinya, pastikan bahwa semua criteria_range argumen memiliki jumlah baris dan kolom yang sama dengan sum_range .
Itulah cara menggunakan fungsi Excel SUMIFS untuk menjumlahkan data dalam rentang tanggal. Jika Anda memiliki beberapa solusi menarik lainnya, saya akan sangat berterima kasih jika Anda berbagi di komentar. Terima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!
Buku kerja latihan untuk diunduh
Contoh rentang tanggal SUMIFS (file .xlsx)
