Hesabat, investisiya planı və ya tarixləri olan hər hansı digər verilənlər toplusu üzərində işləyərkən, tez-tez müəyyən bir müddət ərzində nömrələri toplamağa ehtiyacınız ola bilər. Bu dərslik sizə tez və asan həll yolunu öyrədəcək - meyar kimi tarix diapazonu olan SUMIFS düstur.

Bizim bloqumuzda və digər Excel forumlarımızda insanlar tez-tez tarix diapazonu üçün SUMIF-dən necə istifadə etməyi soruşurlar. Məsələ burasındadır ki, iki tarix arasında cəmləmək üçün hər iki tarixi təyin etməlisiniz, halbuki Excel SUMIF funksiyası yalnız bir şərtə icazə verir. Xoşbəxtlikdən, bizdə çoxlu kriteriyaları dəstəkləyən SUMIFS funksiyası da var.

Excel-də iki tarix arasında olması necə cəmlənəcək

Müəyyən tarix diapazonu daxilində dəyərləri toplamaq üçün istifadə edin meyar kimi başlanğıc və bitmə tarixləri olan SUMIFS düsturu. SUMIFS funksiyasının sintaksisi sizdən əvvəlcə əlavə ediləcək dəyərləri (cəm_aralığı) təyin etməyi, sonra isə diapazon/meyar cütlərini təqdim etməyi tələb edir. Bizim vəziyyətimizdə diapazon (tarixlərin siyahısı) hər iki meyar üçün eyni olacaq.

Yuxarıda göstərilənləri nəzərə alaraq, iki tarix arasındakı dəyərləri toplamaq üçün ümumi düsturlar bu formanı alır:

O cümlədən həddi tarixlər:

Sərhəd tarixlər istisna olmaqla:

Gördüyünüz kimi fərq yalnız məntiqi operatorlardadır. Birinci düsturda biz daha böyük istifadə ediriknəticəyə həddi tarixləri daxil etmək üçün və ya bərabər (>=) və dən az və ya bərabər (<=). İkinci düstur tarixin böyük (>) və ya -dən (<) kiçik olduğunu yoxlayır, başlanğıc və bitmə tarixlərini buraxır.

Burada aşağıdakı cədvəldə, müəyyən bir tarix diapazonunda olan layihələri, o cümlədən, toplamaq istədiyinizi düşünək. Bunu etmək üçün bu düsturdan istifadə edin:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Düsturda tarix diapazonunu sərt kodlaşdırmamaq istəyirsinizsə, onda başlanğıc tarixini F1-də, bitmə tarixini isə daxil edə bilərsiniz. G1, məntiqi operatorları və xana istinadlarını birləşdirin və bütün kriteriyaları aşağıdakı kimi dırnaq işarəsinə daxil edin:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Mümkün səhvlərin qarşısını almaq üçün TARİX funksiyasının köməyi ilə tarixlər:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

Bugünkü tarixə əsaslanan dinamik diapazonda cəmi

Dinamik tarix diapazonunda verilənləri cəmləmək lazım olan vəziyyətdə (bu gündən X gün əvvəl və ya Y gün əvvəl), cari tarixi əldə edəcək və onu avtomatik yeniləyəcək BUGÜN funksiyasından istifadə edərək kriteriyaları qurun.

Məsələn, son vaxtda ödənilməli olan büdcələri cəmləmək üçün 7 gün bugünkü tarix də daxil olmaqla , düstur belədir:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

Cari tarixi yekun nəticəyə daxil etmək istəmirsinizsə, istifadə edin. bugünkü tarixi istisna edən ilk meyarlar üçün operatordan (<) az və böyük və ya bərabər (>=) ikinci meyar üçünbu gündən 7 gün əvvəl olan tarixi daxil edin:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

Oxşar şəkildə, əgər tarix verilmiş gün sayıdırsa, siz dəyərləri cəmləyə bilərsiniz irəli.

Məsələn, növbəti 3 gün ərzində ödənilməli olan büdcələrin cəmini əldə etmək üçün aşağıdakı düsturlardan birini istifadə edin:

Bugünkü tarix nəticəyə daxil edilib:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

Bugünkü tarix nəticəyə daxil edilmir:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

İki tarix və digər meyarlar arasındadırsa, cəmi

Fərqli sütunda hər hansı digər şərtə cavab verən tarix diapazonundaki dəyərləri toplamaq üçün sadəcə olaraq SUMIFS düsturunuza daha bir sıra/kriteriya cütü əlavə edin.

Məsələn, müəyyən müddət ərzində büdcələri cəmləmək üçün adlarında "tip" olan bütün layihələr üçün tarix diapazonu, düsturu wildcard meyarları ilə genişləndirin:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

A2:A10 layihə adları olduğu halda, B2:B10 cəmlənəcək nömrələr, C2:C10 yoxlamaq üçün tarixlər, F1 başlanğıc tarixi və G1 bitmə tarixidir.

Əlbəttə, heç bir şey sizə sepada üçüncü meyarları daxil etməyə mane olmur. qiymət xanası da və ekran görüntüsündə göstərildiyi kimi həmin xanaya istinad:

SUMIFS tarix meyarının sintaksisi

Tarixlərin Excel üçün meyar kimi istifadə edilməsinə gəldikdə SUMIF və SUMIFS funksiyaları ilə siz çaşqınlıq yaşayan ilk şəxs olmayacaqsınız :)

Diqqətlə baxdıqda, bütün müxtəlif istifadə halları bir neçə sadə qaydaya düşür:

Tarixləri birbaşa kriteriyaya daxil etsənizarqumentlər , sonra tarixdən düz əvvəl məntiqi operatoru (>, <, =, ) yazın və bütün meyarları dırnaq işarələri içərisinə daxil edin. Məsələn:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Tarix əvvəlcədən təyin edilmiş xana a daxil edildikdə, mətn sətri şəklində meyarları təmin edin: məntiqi operatoru dırnaq işarəsinə daxil edin. simli başladın və simli birləşdirmək və bitirmək üçün işarədən (&) istifadə edin. Məsələn:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Tarix başqa funksiya tərəfindən idarə edildikdə, məsələn, DATE və ya TODAY(), müqayisə operatorunu və funksiyanı birləşdirin. Məsələn:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

Tarixlər arasında Excel SUMIFS işləmir

Düsturunuz işləmirsə və ya səhv nəticələr verirsə, aşağıdakı problemlərin aradan qaldırılması məsləhətləri bunun səbəbini aydınlaşdıra bilər. uğursuz olur və problemi həll etməyə kömək edir.

Tarixlərin və rəqəmlərin formatını yoxlayın

Əgər düzgün görünən SUMIFS düsturu sıfırdan başqa heç nə qaytarmırsa, yoxlamaq üçün ilk şey tarixlərin həqiqətən tarixlər olmasıdır. , və yalnız tarixlərə bənzəyən mətn sətirləri deyil. Sonra, mətn kimi saxlanan nömrələri deyil, nömrələri cəmlədiyinizə əmin olun. Aşağıdakı dərsliklər bu problemləri aşkar edib həll etməyə kömək edəcək.

• "Mətn tarixlərini" real tarixlərə necə dəyişmək olar
• Mətni rəqəmə necə çevirmək olar

Meyarlar üçün düzgün sintaksisdən istifadə edin

SUMIFS-dən istifadə edərək tarixləri yoxlayarkən, ">=9/10/2020" kimi dırnaq işarələrinin içərisinə tarix qoyulmalıdır; hüceyrə istinadları vəfunksiyalar "<="&G1 və ya "<="&TODAY() kimi dırnaq işarələrindən kənarda yerləşdirilməlidir. Tam təfərrüatlar üçün tarix meyarının sintaksisinə baxın.

Düsturun məntiqini yoxlayın

Büdcədə kiçik bir hərf səhvi milyonlara başa gələ bilər. Düsturdakı kiçik bir səhv sazlama vaxtının saatlarına başa gələ bilər. Beləliklə, 2 tarix arasında cəmlənərkən, başlanğıc tarixinin əvvəlində böyük (>) və ya böyük və ya ona bərabər (>=) operatorunun və sonun olub olmadığını yoxlayın. tarixə -dən az (<) və ya -dən az və ya bərabərdir (<=).

Bütün diapazonların eyni ölçüdə olduğundan əmin olun

SUMIFS funksiyasının düzgün işləməsi üçün cəmi diapazon və kriteriya diapazonları bərabər ölçüdə olmalıdır, əks halda #VALUE! xəta baş verir. Bunu düzəltmək üçün bütün kriteriya_aralığı arqumentlərinin cəm_aralığı ilə eyni sayda sətir və sütuna malik olduğundan əmin olun.

Məlumatları toplamaq üçün Excel SUMIFS funksiyasından belə istifadə etmək olar. tarix diapazonu. Fikrinizdə başqa maraqlı həllər varsa, şərhlərdə paylaşsanız çox minnətdar olaram. Oxuduğunuz üçün təşəkkür edirik və sizi gələn həftə bloqumuzda görməyə ümid edirik!

Endirmək üçün məşq iş dəftəri

SUMIFS tarix diapazonu nümunələri (.xlsx faylı)