Pri práci so správou, investičným plánom alebo iným súborom údajov s dátumami môžete často potrebovať sčítať čísla v rámci určitého obdobia. Tento návod vás naučí rýchle a jednoduché riešenie - vzorec SUMIFS s rozsahom dátumov ako kritériom.

Na našom blogu a iných fórach Excelu sa ľudia často pýtajú, ako použiť SUMIF pre rozsah dátumov. Ide o to, že na sčítanie medzi dvoma dátumami musíte definovať oba dátumy, zatiaľ čo funkcia Excel SUMIF umožňuje len jednu podmienku. Našťastie máme aj funkciu SUMIFS, ktorá podporuje viacero kritérií.

Ako sčítať ak medzi dvoma dátumami v programe Excel

Ak chcete sčítať hodnoty v rámci určitého rozsahu dátumov, použite vzorec SUMIFS s počiatočným a koncovým dátumom ako kritériom. Syntax funkcie SUMIFS vyžaduje, aby ste najprv zadali hodnoty, ktoré sa majú sčítať (sum_range), a potom poskytli dvojice rozsah/kritérium. V našom prípade bude rozsah (zoznam dátumov) rovnaký pre obe kritériá.

Vzhľadom na vyššie uvedené majú všeobecné vzorce na sčítanie hodnôt medzi dvoma dátumami tento tvar:

Vrátane hraničných dátumov:

S výnimkou hraničných dátumov:

Ako vidíte, rozdiel je len v logických operátoroch. V prvom vzorci používame väčšia ako alebo sa rovná (>=) a menšia alebo rovná (<=), aby sa do výsledku zahrnuli hraničné dátumy. Druhý vzorec kontroluje, či je dátum väčšia ako (>) alebo menej ako (<) s vynechaním dátumu začiatku a konca.

Predpokladajme, že v nasledujúcej tabuľke chcete zhrnúť projekty, ktoré sú splatné v určitom rozsahu dátumov vrátane. Ak to chcete urobiť, použite tento vzorec:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Ak nechcete do vzorca natvrdo zapisovať rozsah dátumov, môžete do F1 zadať počiatočný dátum, do G1 koncový dátum, spojiť logické operátory a odkazy na bunky a celé kritérium uzavrieť do úvodzoviek takto:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Aby ste sa vyhli prípadným chybám, môžete zadávať dátumy pomocou funkcie DATE:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

Súčet v rámci dynamického rozsahu na základe dnešného dátumu

Ak potrebujete sčítať údaje v rámci dynamického rozsahu dátumov (X dní dozadu od dnešného dňa alebo Y dní dopredu), vytvorte kritériá pomocou funkcie TODAY, ktorá získa aktuálny dátum a automaticky ho aktualizuje.

Napríklad na sčítanie rozpočtov splatných za posledných 7 dní vrátane dnešného dátumu , vzorec je:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

Ak nechcete do konečného výsledku zahrnúť aktuálny dátum, použite príkaz menej ako operátor (<) pre prvé kritérium na vylúčenie dnešného dátumu a väčšia alebo rovná (>=) pre druhé kritérium, aby zahŕňalo dátum, ktorý je 7 dní pred dnešným dňom:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

Podobným spôsobom môžete sčítať hodnoty, ak je dátum o určitý počet dní dopredu.

Ak chcete napríklad získať súčet rozpočtov, ktoré sú splatné v nasledujúcich 3 dňoch, použite jeden z nasledujúcich vzorcov:

Vo výsledku je zahrnutý dnešný dátum:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

Dnešný dátum nie je zahrnutý do výsledku:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

Suma, ak je medzi dvoma dátumami a iným kritériom

Ak chcete sčítať hodnoty v rámci rozsahu dátumov, ktoré spĺňajú inú podmienku v inom stĺpci, jednoducho pridajte do vzorca SUMIFS ešte jednu dvojicu rozsah/kritérium.

Ak chcete napríklad zhrnúť rozpočty v rámci určitého rozsahu dátumov pre všetky projekty, ktoré obsahujú v názve slovo "tip", rozšírte vzorec o kritérium so zástupným znakom:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

Kde A2:A10 sú názvy projektov, B2:B10 sú čísla na sčítanie, C2:C10 sú dátumy na kontrolu, F1 je dátum začiatku a G1 je dátum konca.

Samozrejme, nič vám nebráni zadať aj tretie kritérium do samostatnej bunky a odkazovať na túto bunku, ako je to znázornené na obrázku:

Syntax kritérií dátumu SUMIFS

Pokiaľ ide o používanie dátumov ako kritérií pre funkcie Excel SUMIF a SUMIFS, neboli by ste prvý, kto by bol zmätený :)

Pri podrobnejšom pohľade sa však všetky rozmanité prípady použitia zužujú na niekoľko jednoduchých pravidiel:

Ak zadáte dátumy priamo do argumenty kritérií , potom zadajte logický operátor (>, <, =, ) priamo pred dátum a celé kritérium uzavrite do úvodzoviek. Napríklad:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Keď sa dátum zadá do preddefinovaného bunka , zadajte kritériá vo forme textového reťazca: logický operátor uzavrite do úvodzoviek, aby ste začali reťazec, a použite ampersand (&) na spojenie a ukončenie reťazca. Napríklad:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Ak je dátum riadený ďalšia funkcia ako DATE alebo TODAY(), spojte operátor porovnávania a funkciu. Napríklad:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

Excel SUMIFS medzi dátumami nefunguje

V prípade, že váš vzorec nefunguje alebo poskytuje nesprávne výsledky, nasledujúce tipy na riešenie problémov môžu objasniť, prečo zlyháva, a pomôcť vám problém vyriešiť.

Skontrolujte formát dátumov a čísel

Ak zdanlivo správny vzorec SUMIFS vráti iba nulu, v prvom rade skontrolujte, či sú vaše dátumy naozaj dátumy, a nie textové reťazce, ktoré ako dátumy iba vyzerajú. Ďalej sa uistite, že sčítavate čísla, a nie čísla uložené ako text. Nasledujúce návody vám pomôžu odhaliť a odstrániť tieto problémy.

• Ako zmeniť "textové dátumy" na skutočné dátumy
• Ako previesť text na číslo

Používajte správnu syntax pre kritériá

Pri kontrole dátumov pomocou SUMIFS by sa mal dátum umiestniť do úvodzoviek, napríklad ">=9/10/2020"; odkazy na bunky a funkcie by sa mali umiestniť mimo úvodzoviek, napríklad "<="&G1 alebo "<="&TODAY(). Všetky podrobnosti nájdete v syntaxi dátumových kritérií.

Overenie logiky vzorca

Malý preklep v rozpočte môže stáť milióny. Malá chyba vo vzorci môže stáť hodiny ladenia. Pri sčítavaní medzi 2 dátumami preto skontrolujte, či sa pred dátumom začatia väčšia ako (>) alebo väčšia alebo rovná (>=) a pred koncovým dátumom je predponou menej ako (<) alebo menšia alebo rovná (<=).

Uistite sa, že všetky rozsahy majú rovnakú veľkosť

Aby funkcia SUMIFS fungovala správne, rozsah súčtu a rozsah kritérií by mali byť rovnako veľké, inak sa vyskytne chyba #VALUE!. Ak to chcete opraviť, zabezpečte, aby všetky criteria_range argumenty majú rovnaký počet riadkov a stĺpcov ako sum_range .

Takto sa dá použiť funkcia Excel SUMIFS na sčítanie údajov v rozsahu dátumov. Ak vás napadajú nejaké ďalšie zaujímavé riešenia, budem vám veľmi vďačný, ak sa o ne podelíte v komentároch. Ďakujem za prečítanie a dúfam, že sa uvidíme na našom blogu budúci týždeň!

Cvičebnica na stiahnutie

Príklady rozsahu dátumov SUMIFS (.xlsx súbor)