ანგარიშზე, საინვესტიციო გეგმაზე ან ნებისმიერ სხვა მონაცემთა ბაზაზე მუშაობისას, თარიღებით, შეიძლება ხშირად დაგჭირდეთ რიცხვების შეჯამება კონკრეტულ პერიოდში. ეს სახელმძღვანელო გასწავლით სწრაფ და მარტივ გადაწყვეტას - SUMIFS ფორმულა თარიღის დიაპაზონით, როგორც კრიტერიუმები.

ჩვენს ბლოგზე და Excel-ის სხვა ფორუმებზე, ადამიანები ხშირად კითხულობენ, როგორ გამოვიყენოთ SUMIF თარიღის დიაპაზონისთვის. საქმე იმაშია, რომ ორ თარიღს შორის შეჯამებისთვის, თქვენ უნდა განსაზღვროთ ორივე თარიღი, ხოლო Excel SUMIF ფუნქცია მხოლოდ ერთ პირობას იძლევა. საბედნიეროდ, ჩვენ ასევე გვაქვს SUMIFS ფუნქცია, რომელიც მხარს უჭერს მრავალ კრიტერიუმს.

როგორ შევაჯამოთ თუ ორ თარიღს შორის Excel-ში

მნიშვნელობების შესაჯამებლად თარიღის გარკვეულ დიაპაზონში, გამოიყენეთ SUMIFS ფორმულა დაწყების და დასრულების თარიღებით კრიტერიუმად. SUMIFS ფუნქციის სინტაქსი მოითხოვს, რომ ჯერ მიუთითოთ დასამატებელი მნიშვნელობები (ჯამ_დიაპაზონი) და შემდეგ მიაწოდოთ დიაპაზონი/კრიტერიუმების წყვილები. ჩვენს შემთხვევაში, დიაპაზონი (თარიღების სია) იგივე იქნება ორივე კრიტერიუმისთვის.

ზემოაღნიშნულის გათვალისწინებით, ორ თარიღს შორის მნიშვნელობების ჯამის ზოგადი ფორმულები ამ ფორმას იღებს:

მათ შორის ბარიერის თარიღები:

ზღვრული თარიღების გამოკლებით:

როგორც ხედავთ, განსხვავება მხოლოდ ლოგიკურ ოპერატორებშია. პირველ ფორმულაში ვიყენებთ უმეტესვიდრე ან უდრის (>=) და ამცირებს ან უდრის -ს (<=), რათა შედეგში შეიტანოს ბარიერის თარიღები. მეორე ფორმულა ამოწმებს, არის თუ არა თარიღი აღმატებული (>) ან (<ზე ნაკლები), დაწყების და დასრულების თარიღების გამოტოვება.

ქვემოთ მოყვანილი ცხრილი, დავუშვათ, რომ გსურთ შეაჯამოთ პროექტები, რომლებიც გათვალისწინებულია თარიღის კონკრეტულ დიაპაზონში, მათ შორის. ამის შესასრულებლად გამოიყენეთ ეს ფორმულა:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

თუ არ გირჩევნიათ ფორმულაში თარიღის დიაპაზონის მყარი კოდირება, მაშინ შეგიძლიათ აკრიფოთ დაწყების თარიღი F1-ში, დასრულების თარიღი G1, შეაერთეთ ლოგიკური ოპერატორები და უჯრედების მითითებები და ჩასვით მთელი კრიტერიუმი ბრჭყალებში:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

შესაძლო შეცდომების თავიდან ასაცილებლად, შეგიძლიათ მიაწოდოთ თარიღები DATE ფუნქციის დახმარებით:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

ჯამი დინამიურ დიაპაზონში დღევანდელ თარიღზე დაყრდნობით

სიტუაციაში, როდესაც გჭირდებათ მონაცემების ჯამი დინამიური თარიღის დიაპაზონში (X დღე უკან დღეიდან ან Y დღე წინ), შექმენით კრიტერიუმები TODAY ფუნქციის გამოყენებით, რომელიც მიიღებს მიმდინარე თარიღს და ავტომატურად განაახლებს მას.

მაგალითად, ბოლო ვადაგადაცილებული ბიუჯეტის შეჯამება 7 დღე დღევანდელი თარიღის ჩათვლით , ფორმულა არის:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

თუ გსურთ არ შეიტანოთ მიმდინარე თარიღი საბოლოო შედეგში, გამოიყენეთ ოპერატორზე ნაკლები (<) პირველი კრიტერიუმისთვის დღევანდელი თარიღის გამორიცხვისთვის და უფრო მეტი ან ტოლი (>=) მეორე კრიტერიუმისთვისჩართეთ თარიღი, რომელიც დღეს არის 7 დღით ადრე:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

მსგავსი წესით, შეგიძლიათ შეაჯამოთ მნიშვნელობები, თუ თარიღი არის დღეების მოცემული რაოდენობა გადადით.

მაგალითად, იმისათვის, რომ მიიღოთ ჯამური ბიუჯეტი, რომელიც გადასახდელია მომდევნო 3 დღის განმავლობაში, გამოიყენეთ შემდეგი ფორმულებიდან ერთ-ერთი:

დღევანდელი თარიღი შედის შედეგში:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

დღევანდელი თარიღი არ შედის შედეგში:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

ჯამი თუ ორ თარიღსა და სხვა კრიტერიუმს შორის

თარიღის დიაპაზონში მნიშვნელობების შესაჯამებლად, რომლებიც აკმაყოფილებენ სხვა პირობას სხვა სვეტში, უბრალოდ დაამატეთ კიდევ ერთი დიაპაზონი/კრიტერიუმების წყვილი თქვენს SUMIFS ფორმულაში.

მაგალითად, ბიუჯეტის შესაჯამებლად გარკვეული პერიოდის განმავლობაში. თარიღის დიაპაზონი ყველა პროექტისთვის, რომელიც შეიცავს "რჩევას" მათ სახელებში, გააფართოვეთ ფორმულა კრიტერიუმებით:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

სადაც A2:A10 არის პროექტის სახელები, B2:B10 არის რიცხვები შესაჯამებლად, C2:C10 არის შესამოწმებელი თარიღები, F1 არის დაწყების თარიღი და G1 არის დასრულების თარიღი.

რა თქმა უნდა, არაფერი გიშლით ხელს მესამე კრიტერიუმების სეპაში შეყვანაში. ასევე შეაფასეთ უჯრედი და მიუთითეთ ის უჯრედი, როგორც ეს ნაჩვენებია ეკრანის სურათზე:

SUMIFS თარიღის კრიტერიუმების სინტაქსი

როცა საქმე ეხება თარიღების გამოყენებას Excel SUMIF-ის კრიტერიუმად და SUMIFS-ის ფუნქციები, თქვენ არ იქნებით პირველი ადამიანი, ვინც დაიბნევა :)

თუმცა, უფრო დეტალურად რომ დაათვალიეროთ, გამოყენების შემთხვევების მრავალფეროვნება რამდენიმე მარტივ წესზე მოდის:

თუ თარიღებს პირდაპირ კრიტერიუმში ჩასვამთარგუმენტები , შემდეგ აკრიფეთ ლოგიკური ოპერატორი (>, <, =, ) თარიღამდე და ჩასვით მთელი კრიტერიუმი ბრჭყალებში. მაგალითად:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

როდესაც თარიღი შეიყვანება წინასწარ განსაზღვრულ უჯრედში , მიუთითეთ კრიტერიუმები ტექსტის სტრიქონის სახით: ჩასვით ლოგიკური ოპერატორი ბრჭყალებში. დაიწყეთ სტრიქონი და გამოიყენეთ ამპერსანდი (&) სტრიქონის შესაერთებლად და დასასრულებლად. მაგალითად:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

როდესაც თარიღი განპირობებულია სხვა ფუნქციით როგორიცაა DATE ან TODAY(), შეაერთეთ შედარების ოპერატორი და ფუნქცია. მაგალითად:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

Excel SUMIFS თარიღებს შორის არ მუშაობს

იმ შემთხვევაში, თუ თქვენი ფორმულა არ მუშაობს ან არასწორ შედეგს იძლევა, პრობლემების აღმოფხვრის შემდეგმა რჩევებმა შეიძლება ნათელი მოჰფინოს ამის მიზეზს ვერ ხერხდება და დაგეხმარებათ პრობლემის მოგვარებაში.

შეამოწმეთ თარიღებისა და რიცხვების ფორმატი

თუ ერთი შეხედვით სწორი SUMIFS ფორმულა არაფერს აბრუნებს გარდა ნულისა, პირველი რაც უნდა შეამოწმოთ არის, რომ თქვენი თარიღები ნამდვილად თარიღებია. და არა ტექსტის სტრიქონები, რომლებიც მხოლოდ თარიღს ჰგავს. შემდეგი, დარწმუნდით, რომ აჯამებთ რიცხვებს და არა ტექსტად შენახულ რიცხვებს. შემდეგი გაკვეთილები დაგეხმარებათ ამ პრობლემების ამოცნობაში და გამოსწორებაში.

• როგორ შევცვალოთ „ტექსტის თარიღები“ რეალურ თარიღებზე
• როგორ გადავიტანოთ ტექსტი რიცხვად

გამოიყენეთ სწორი სინტაქსი კრიტერიუმებისთვის

თარიღების შემოწმებისას SUMIFS-ის გამოყენებით, ბრჭყალებში უნდა ჩაიწეროს თარიღი, როგორიცაა ">=9/10/2020"; უჯრედის მითითებები დაფუნქციები უნდა განთავსდეს ბრჭყალების მიღმა, როგორიცაა "<="&G1 ან "<="&TODAY(). სრული დეტალებისთვის, გთხოვთ, იხილოთ თარიღის კრიტერიუმების სინტაქსი.

დაამოწმეთ ფორმულის ლოგიკა

ბიუჯეტში მცირე შეცდომა შეიძლება დაჯდეს მილიონობით. ფორმულაში მცირე შეცდომა შეიძლება დაუჯდეს საათის გამართვის დროს. ასე რომ, 2 თარიღს შორის შეჯამებისას შეამოწმეთ დაწყების თარიღს წინ უძღვის -ზე მეტი (>) ან უმეტეს ან ტოლია (>=) ოპერატორი და დასასრული თარიღის პრეფიქსია (<)-ზე ნაკლები ან მცირე ან ტოლი (<=).

დარწმუნდით, რომ ყველა დიაპაზონი ერთი და იგივე ზომისაა

SUMIFS ფუნქციის სწორად მუშაობისთვის, ჯამის დიაპაზონი და კრიტერიუმების დიაპაზონი უნდა იყოს თანაბარი ზომის, წინააღმდეგ შემთხვევაში #VALUE! ხდება შეცდომა. მის გამოსასწორებლად, დარწმუნდით, რომ ყველა კრიტერიუმის_დიაპაზონის არგუმენტს აქვს მწკრივების და სვეტების იგივე რაოდენობა, როგორც ჯამის_დიაპაზონი .

ასე გამოვიყენოთ Excel SUMIFS ფუნქცია მონაცემების შესაჯამებლად. თარიღის დიაპაზონი. თუ თქვენ გაქვთ მხედველობაში სხვა საინტერესო გადაწყვეტილებები, მადლობელი ვიქნები, თუ კომენტარებში გამიზიარებთ. გმადლობთ, რომ კითხულობთ და ვიმედოვნებთ, რომ მომავალ კვირას შეგხვდებით ჩვენს ბლოგზე!

ივარჯიშეთ სამუშაო წიგნი ჩამოსატვირთად

SUMIFS თარიღის დიაპაზონის მაგალითები (ფაილი .xlsx)