При работа с отчет, инвестиционен план или друг набор от данни с дати често се налага да сумирате числа в рамките на определен период. В този урок ще научите едно бързо и лесно решение - формулата SUMIFS с диапазон от дати като критерий.

В нашия блог и в други форуми на Excel хората често питат как да използват SUMIF за диапазон от дати. Въпросът е, че за да съберете сума между две дати, трябва да определите и двете дати, докато функцията SUMIF на Excel позволява само едно условие. За щастие имаме и функцията SUMIFS, която поддържа множество критерии.

Как да съберете ако между две дати в Excel

За да съберете стойности в рамките на определен диапазон от дати, използвайте формулата SUMIFS с начална и крайна дата като критерии. Синтаксисът на функцията SUMIFS изисква първо да посочите стойностите, които да се сумират (sum_range), и след това да предоставите двойки диапазон/критерии. В нашия случай диапазонът (списък от дати) ще бъде един и същ и за двата критерия.

Като се има предвид горното, общите формули за сумиране на стойности между две дати имат следния вид:

Включително праговите дати:

С изключение на праговите дати:

Както виждате, разликата е само в логическите оператори. В първата формула използваме по-голям от или равен на (>=) и по-малък или равен на (<=), за да включите праговите дати в резултата. Втората формула проверява дали дадена дата е по-голям от (>) или по-малко от (<), като се пропускат началната и крайната дата.

В таблицата по-долу, да предположим, че искате да съберете проектите, които трябва да бъдат изпълнени в определен диапазон от дати, включително. За да го направите, използвайте тази формула:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Ако предпочитате да не въвеждате твърд код за диапазон от дати във формулата, можете да въведете началната дата в F1, крайната дата в G1, да свържете логическите оператори и препратките към клетките и да оградите целия критерий в кавички по следния начин:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

За да избегнете евентуални грешки, можете да въвеждате дати с помощта на функцията DATE:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

Сума в динамичен диапазон въз основа на днешната дата

Когато трябва да обобщите данни в рамките на динамичен диапазон от дати (X дни назад от днес или Y дни напред), конструирайте критериите, като използвате функцията TODAY, която ще получи текущата дата и ще я актуализира автоматично.

Например, за да обобщите бюджетите, които са дължими през последните 7 дни. включително днешната дата , формулата е:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

Ако предпочитате да не включвате текущата дата в крайния резултат, използвайте по-малко от оператор (<) за първия критерий, за да изключите днешната дата и по-голям или равен на (>=) за втория критерий, за да включите датата, която е 7 дни преди днешния ден:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

По подобен начин можете да сумирате стойности, ако дадена дата е с определен брой дни напред.

Например, за да получите общата сума на бюджетите, които трябва да бъдат изпълнени през следващите 3 дни, използвайте една от следните формули:

Днешната дата е включена в резултата:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

Днешната дата не е включена в резултата:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

Сума, ако между две дати и друг критерий

За да съберете стойности в рамките на диапазон от дати, които отговарят на друго условие в друга колона, просто добавете още една двойка диапазон/критерии към формулата SUMIFS.

Например, за да обобщите бюджетите в рамките на определен диапазон от дати за всички проекти, които съдържат "tip" в имената си, разширете формулата с критерий със заместващ знак:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

Където A2:A10 са имената на проектите, B2:B10 са числата за сумиране, C2:C10 са датите за проверка, F1 е началната дата, а G1 е крайната дата.

Разбира се, нищо не ви пречи да въведете и третия критерий в отделна клетка и да направите препратка към тази клетка, както е показано на снимката:

Синтаксис на критериите за дата SUMIFS

Когато става въпрос за използване на дати като критерии за функциите SUMIF и SUMIFS на Excel, не сте първият човек, който се обърква :)

При по-внимателно вглеждане обаче цялото разнообразие от случаи на употреба се свежда до няколко прости правила:

Ако въведете датите директно в аргументи за критериите , след което въведете логически оператор (>, <, =, ) точно преди датата и оградете целия критерий в кавички:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

При въвеждане на дата в предварително дефиниран клетка , предоставете критерии под формата на текстов низ: затворете логически оператор в кавички, за да започнете низ, и използвайте амперсанд (&), за да свържете и завършите низ:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Когато датата се определя от друга функция като DATE или TODAY(), конкатенирайте оператор за сравнение и функция. Например:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

Excel SUMIFS между дати не работи

Ако формулата ви не работи или дава грешни резултати, следните съвети за отстраняване на неизправности могат да хвърлят светлина върху причините за неуспеха и да ви помогнат да отстраните проблема.

Проверка на формата на датите и числата

Ако привидно правилната формула SUMIFS връща само нула, първо трябва да проверите дали датите са наистина дати, а не текстови низове, които само приличат на дати. След това се уверете, че сумирате числа, а не числа, записани като текст. Следващите уроци ще ви помогнат да откриете и отстраните тези проблеми.

• Как да промените "текстовите дати" в реални дати
• Как да конвертирате текст в число

Използвайте правилния синтаксис за критериите

Когато проверявате дати с помощта на SUMIFS, датата трябва да бъде поставена в кавичките, например ">=9/10/2020"; препратките към клетки и функциите трябва да бъдат поставени извън кавичките, например "<="&G1 или "<="&TODAY(). За пълна информация вижте синтаксиса на критериите за дата.

Проверка на логиката на формулата

Малка печатна грешка в бюджет може да струва милиони. Малка грешка във формула може да струва часове време за отстраняване на грешки. Така че, когато сумирате между 2 дати, проверявайте дали началната дата е предшествана от по-голям от (>) или по-голям или равен на (>=), а крайната дата е предшествана от по-малко от (<) или по-малък или равен на (<=).

Уверете се, че всички диапазони са с еднакъв размер

За да работи правилно функцията SUMIFS, диапазоните на сумата и критериите трябва да са с еднакъв размер, в противен случай се получава грешка #VALUE! За да я отстраните, уверете се, че всички criteria_range аргументите имат същия брой редове и колони като sum_range .

Ето как да използвате функцията SUMIFS на Excel за сумиране на данни в диапазон от дати. Ако имате предвид други интересни решения, ще ви бъда много благодарен, ако ги споделите в коментарите. Благодаря, че прочетохте, и се надявам да се видим в нашия блог следващата седмица!

Практическа работна тетрадка за изтегляне

Примери за диапазона на датите SUMIFS (.xlsx файл)