Obsah
Při práci s reportem, investičním plánem nebo jakoukoli jinou datovou sadou s daty můžete často potřebovat sečíst čísla v rámci určitého období. Tento tutoriál vás naučí rychlé a snadné řešení - vzorec SUMIFS s rozsahem dat jako kritériem.
Na našem blogu a dalších fórech Excelu se lidé často ptají, jak použít funkci SUMIF pro rozsah dat. Jde o to, že pro součet mezi dvěma daty je třeba definovat obě data, zatímco funkce SUMIF Excelu umožňuje pouze jednu podmínku. Naštěstí máme k dispozici také funkci SUMIFS, která podporuje více kritérií.
Jak sečíst if mezi dvěma daty v aplikaci Excel
Chcete-li sečíst hodnoty v určitém rozsahu dat, použijte vzorec SUMIFS s počátečním a koncovým datem jako kritérii. Syntaxe funkce SUMIFS vyžaduje, abyste nejprve zadali hodnoty, které se mají sečíst (sum_range), a poté dvojice rozsah/kritéria. V našem případě bude rozsah (seznam dat) pro obě kritéria stejný.
Vzhledem k výše uvedenému mají obecné vzorce pro součet hodnot mezi dvěma daty tento tvar:
Včetně prahových dat:
SUMIFS( sum_range , data ,">= start_date ", data , "<= end_date ")S výjimkou prahových dat:
SUMIFS( sum_range , data ,"> start_date ", data , "< end_date ")Jak vidíte, rozdíl je pouze v logických operátorech. V prvním vzorci používáme větší než nebo se rovná (>=) a menší nebo rovno (<=) pro zahrnutí prahových dat do výsledku. Druhý vzorec kontroluje, zda je datum větší než (>) nebo méně než (<) s vynecháním počátečního a koncového data.
Předpokládejme, že v níže uvedené tabulce chcete sečíst projekty, které jsou splatné v určitém rozmezí dat včetně. Chcete-li to provést, použijte tento vzorec:
=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")
Pokud nechcete ve vzorci zadávat rozsah dat natvrdo, můžete zadat počáteční datum do F1, koncové datum do G1, spojit logické operátory a odkazy na buňky a uzavřít celé kritérium do uvozovek takto:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)
Abyste se vyhnuli případným chybám, můžete zadávat data pomocí funkce DATE:
=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))
Součet v dynamickém rozsahu na základě dnešního data
V případě, že potřebujete sečíst data v rámci dynamického rozsahu dat (X dní zpět od dneška nebo Y dní dopředu), sestavte kritéria pomocí funkce TODAY, která získá aktuální datum a automaticky jej aktualizuje.
Chcete-li například sečíst rozpočty splatné za posledních 7 dní. včetně dnešního data , vzorec je:
=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)
Pokud nechcete do konečného výsledku zahrnout aktuální datum, použijte příkaz méně než operátor (<) pro první kritérium, aby se vyloučilo dnešní datum a větší nebo rovno (>=) pro druhé kritérium, aby zahrnovalo datum, které je 7 dní před dnešním dnem:
=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)
Podobným způsobem můžete sčítat hodnoty, pokud je datum o určitý počet dní dopředu.
Chcete-li například získat celkový počet rozpočtů, které jsou splatné v následujících 3 dnech, použijte jeden z následujících vzorců:
Do výsledku je zahrnuto dnešní datum:
=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)
Dnešní datum není ve výsledku zahrnuto:
=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)
Součet, pokud je mezi dvěma daty a dalším kritériem
Chcete-li sečíst hodnoty v rámci rozsahu dat, které splňují jinou podmínku v jiném sloupci, jednoduše přidejte do vzorce SUMIFS další dvojici rozsah/kritérium.
Chcete-li například sečíst rozpočty v určitém rozmezí dat pro všechny projekty, které obsahují ve svém názvu slovo "tip", rozšiřte vzorec o kritérium se zástupným znakem:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")
Kde A2:A10 jsou názvy projektů, B2:B10 jsou čísla k sečtení, C2:C10 jsou data ke kontrole, F1 je datum zahájení a G1 je datum ukončení.
Nic vám samozřejmě nebrání zadat třetí kritérium také do samostatné buňky a odkázat na ni, jak je znázorněno na obrázku:
Syntaxe datových kritérií SUMIFS
Pokud jde o použití dat jako kritérií pro funkce Excel SUMIF a SUMIFS, nebyli byste první, kdo by se zmýlil :)
Při bližším pohledu se však všechny rozmanité případy použití omezují na několik jednoduchých pravidel:
Pokud zadáte data přímo do argumenty kritérií , pak zadejte logický operátor (>, <, =, ) těsně před datum a celé kritérium uzavřete do uvozovek. Například:
=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")
Když je datum zadáno v předdefinovaném buňka , zadejte kritéria ve formě textového řetězce: logický operátor uzavřete do uvozovek pro začátek řetězce a použijte ampersand (&) pro spojení a ukončení řetězce. Například:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)
Když je datum řízeno další funkce jako je DATE nebo TODAY(), spojte operátor porovnání a funkci. Například:
=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())
Nefunguje funkce Excel SUMIFS mezi daty
Pokud váš vzorec nefunguje nebo poskytuje nesprávné výsledky, následující tipy pro řešení problémů mohou objasnit příčiny selhání a pomoci vám problém vyřešit.
Zkontrolujte formát dat a čísel
Pokud zdánlivě správný vzorec SUMIFS vrátí pouze nulu, je třeba nejprve zkontrolovat, zda jsou data skutečně data, a ne textové řetězce, které jako data pouze vypadají. Dále se ujistěte, že sčítáte čísla, a ne čísla uložená jako text. Následující návody vám pomohou tyto problémy odhalit a odstranit.
- Jak změnit "textová data" na skutečná data
- Jak převést text na číslo
Použijte správnou syntaxi pro kritéria
Při kontrole dat pomocí SUMIFS by se datum mělo umístit do uvozovek, například ">=9/10/2020"; odkazy na buňky a funkce by se měly umístit mimo uvozovky, například "<="&G1 nebo "<="&TODAY(). Podrobné informace naleznete v části Syntaxe kritérií data.
Ověření logiky vzorce
Malý překlep v rozpočtu může stát miliony. Malá chyba ve vzorci může stát hodiny času na ladění. Proto při sčítání mezi dvěma daty zkontrolujte, zda počátečnímu datu předchází znak. větší než (>) nebo větší nebo rovno (>=) a před koncovým datem je předpona méně než (<) nebo menší nebo rovno (<=).
Ujistěte se, že všechny rozsahy mají stejnou velikost
Aby funkce SUMIFS fungovala správně, měly by být rozsahy součtů a kritérií stejně velké, jinak dojde k chybě #VALUE!. Chcete-li ji opravit, zajistěte, aby všechny rozsahy součtů a kritérií byly stejně velké. criteria_range mají stejný počet řádků a sloupců jako argumenty sum_range .
To je návod, jak použít funkci SUMIFS v Excelu pro sčítání dat v rozsahu dat. Pokud vás napadá nějaké další zajímavé řešení, budu vám opravdu vděčný, když se o něj podělíte v komentářích. Děkuji za přečtení a doufám, že se uvidíme na našem blogu příští týden!
Cvičebnice ke stažení
Příklady rozsahu dat SUMIFS (.xlsx soubor)
