Táboa de contidos
Ao traballar nun informe, plan de investimento ou calquera outro conxunto de datos con datas, é posible que moitas veces necesites sumar números nun período específico. Este tutorial ensinarache unha solución rápida e sinxela: a fórmula SUMIFS co intervalo de datas como criterio.
No noso blog e noutros foros de Excel, a xente adoita preguntar como usar SUMIF para o intervalo de datas. A cuestión é que para sumar dúas datas, cómpre definir ambas as datas mentres que a función SUMIF de Excel só permite unha condición. Por sorte, tamén temos a función SUMIFS que admite varios criterios.
Como sumar se entre dúas datas en Excel
Para sumar valores dentro dun determinado intervalo de datas, use unha fórmula SUMIFS con datas de inicio e finalización como criterios. A sintaxe da función SUMIFS require que primeiro especifique os valores a sumar (suma_rango) e despois proporcione pares intervalo/criterio. No noso caso, o intervalo (unha lista de datas) será o mesmo para ambos os criterios.
Considerando o anterior, as fórmulas xenéricas para sumar valores entre dúas datas adoptan esta forma:
Incluíndo as datas límite:
SUMIFS( intervalo_suma, datas,">= data_inicio", datas, "<= data_final")Excluíndo as datas límite:
SUMIFS( intervalo_suma, datas,"> data_inicio", datas, "< end_date")Como podes ver, a diferenza só está nos operadores lóxicos. Na primeira fórmula, usamos maiorque ou igual a (>=) e menor ou igual a (<=) para incluír as datas límite no resultado. A segunda fórmula verifica se unha data é maior que (>) ou menor que (<), deixando fóra as datas de inicio e fin.
No a seguinte táboa, supoña que quere sumar os proxectos que se vencen nun intervalo de datas determinado, incluído. Para facelo, use esta fórmula:
=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")
Se prefire non codificar un intervalo de datas na fórmula, pode escribir a data de inicio en F1, a data de finalización en G1, concatene os operadores lóxicos e as referencias de cela e engada os criterios completos entre comiñas como esta:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)
Para evitar posibles erros, pode proporcionar datas coa axuda da función DATE:
=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))
Suma dentro dun intervalo dinámico baseado na data de hoxe
Na situación na que necesites sumar datos dentro dun intervalo de datas dinámico (X días atrás a partir de hoxe ou Y días en diante), constrúe os criterios mediante a función HOXE, que obterá a data actual e actualizala automaticamente.
Por exemplo, para sumar os orzamentos que se vencen no último 7 días incluída a data de hoxe , a fórmula é:
=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)
Se prefire non incluír a data actual no resultado final, use o operador inferior a (<) para os primeiros criterios para excluír a data de hoxe e maior ou igual a (>=) para o segundo criterioinclúe a data que é 7 días antes de hoxe:
=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)
De forma similar, podes sumar valores se unha data é un número determinado de días adiante.
Por exemplo, para obter un total de orzamentos que se vencen nos próximos 3 días, use unha das seguintes fórmulas:
A data de hoxe inclúese no resultado:
=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)
A data de hoxe non se inclúe no resultado:
=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)
Suma se entre dúas datas e outro criterio
Para sumar valores dentro dun intervalo de datas que cumpran algunha outra condición nunha columna diferente, simplemente engade un par intervalo/criterio máis á súa fórmula SUMIFS.
Por exemplo, para sumar orzamentos dentro dun determinado intervalo de datas para todos os proxectos que conteñan "suxestión" nos seus nomes, amplía a fórmula cun criterio comodín:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")
Onde A2:A10 son os nomes dos proxectos, B2:B10 son os números para sumar, C2:C10 son as datas a comprobar, F1 é a data de inicio e G1 é a data de finalización.
Por suposto, nada impide que introduza o terceiro criterio nunha sepa taxa de cela tamén e facendo referencia a esa cela como se mostra na captura de pantalla:
Sintaxe de criterios de data SUMIFS
Cando se trata de usar as datas como criterios para SUMIF de Excel e funcións SUMIFS, non sería a primeira persoa en confundirse :)
Con unha ollada máis atenta, con todo, toda a variedade de casos de uso resúmese a algunhas regras simples:
Se pon datas directamente nos criteriosargumentos e, a continuación, escriba un operador lóxico (>, <, =, ) xusto antes da data e engada todos os criterios entre comiñas. Por exemplo:
=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")
Cando se introduce unha data nunha cela predefinida, proporcione criterios en forma de cadea de texto: engada un operador lóxico entre comiñas para inicia unha cadea e usa un ampersand (&) para concatenar e rematar a cadea. Por exemplo:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)
Cando unha data está dirixida por outra función como DATA ou TODAY(), concatene un operador de comparación e unha función. Por exemplo:
=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())
Excel SUMIFS entre datas que non funcionan
No caso de que a túa fórmula non funcione ou produza resultados incorrectos, as seguintes suxestións de solución de problemas poden aclarar por que falla e axúdache a solucionar o problema.
Comproba o formato das datas e dos números
Se unha fórmula SUMIFS aparentemente correcta non devolve máis que cero, o primeiro que hai que comprobar é que as túas datas son realmente datas , e non cadeas de texto que só semellan datas. A continuación, asegúrate de sumar números e non de números almacenados como texto. Os seguintes titoriais axudaranche a detectar e solucionar estes problemas.
- Como cambiar as datas do texto a datas reais
- Como converter texto en número
Utilice a sintaxe correcta para os criterios
Ao comprobar as datas mediante SUMIFS, debe poñerse unha data entre comiñas como ">=9/10/2020"; referencias de cela eAs funcións deben colocarse fóra das comiñas como "<="&G1 ou "<="&TODAY(). Para obter máis información, consulte a sintaxe dos criterios de data.
Verifica a lóxica da fórmula
Unha pequena errata nun orzamento pode custar millóns. Un pequeno erro nunha fórmula pode custar horas de tempo de depuración. Polo tanto, ao sumar entre 2 datas, comprobe se a data de inicio vai precedida polo operador maior que (>) ou maior que ou igual a (>=) e o final a data ten como prefixo menor que (<) ou menor ou igual a (<=).
Asegúrate de que todos os intervalos teñan o mesmo tamaño
Para que a función SUMIFS funcione correctamente, o intervalo de suma e os intervalos de criterios deben ter o mesmo tamaño, senón un #VALOR! prodúcese un erro. Para solucionalo, asegúrese de que todos os argumentos de intervalo_criterios teñan o mesmo número de filas e columnas que intervalo_de_suma .
Así é como usar a función SUMIFS de Excel para sumar datos en un intervalo de datas. Se tes outras solucións interesantes en mente, estarei moi agradecido se compartes nos comentarios. Grazas por ler e esperamos verte no noso blog a próxima semana!
Caderno de prácticas para descargar
Exemplos de intervalos de datas SUMIFS (ficheiro .xlsx)
