Mục lục
Khi làm việc trên một báo cáo, kế hoạch đầu tư hoặc bất kỳ tập dữ liệu nào khác có ngày tháng, bạn có thể thường phải tính tổng các số trong một khoảng thời gian cụ thể. Hướng dẫn này sẽ hướng dẫn bạn một giải pháp nhanh chóng và dễ dàng - công thức SUMIFS với phạm vi ngày làm tiêu chí.
Trên blog của chúng tôi và các diễn đàn Excel khác, mọi người thường hỏi cách sử dụng SUMIF cho phạm vi ngày. Vấn đề là để tính tổng giữa hai ngày, bạn cần xác định cả hai ngày trong khi hàm SUMIF của Excel chỉ cho phép một điều kiện. May mắn thay, chúng ta cũng có hàm SUMIFS hỗ trợ nhiều tiêu chí.
Cách tính tổng nếu giữa hai ngày trong Excel
Để tính tổng các giá trị trong một phạm vi ngày nhất định, hãy sử dụng công thức SUMIFS với ngày bắt đầu và ngày kết thúc làm tiêu chí. Cú pháp của hàm SUMIFS yêu cầu trước tiên bạn chỉ định các giá trị cần cộng (sum_range), sau đó cung cấp các cặp phạm vi/tiêu chí. Trong trường hợp của chúng tôi, phạm vi (danh sách ngày) sẽ giống nhau cho cả hai tiêu chí.
Xem xét điều trên, các công thức chung để tính tổng các giá trị giữa hai ngày có dạng sau:
Bao gồm ngưỡng ngày:
SUMIFS( sum_range, dates,">= start_date", dates, "<= end_date")Không bao gồm ngưỡng ngày:
SUMIFS( sum_range, dates,"> start_date", dates, "< end_date")Như bạn có thể thấy, sự khác biệt chỉ nằm ở các toán tử logic. Trong công thức đầu tiên, chúng tôi sử dụng lớn hơnhơn hoặc bằng (>=) và nhỏ hơn hoặc bằng (<=) để bao gồm ngày ngưỡng trong kết quả. Công thức thứ hai kiểm tra xem một ngày có lớn hơn (>) hay nhỏ hơn (<), bỏ qua ngày bắt đầu và ngày kết thúc.
Trong bảng bên dưới, giả sử bạn muốn tính tổng các dự án đến hạn trong một phạm vi ngày cụ thể, bao gồm cả. Để hoàn thành, hãy sử dụng công thức sau:
=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")
Nếu bạn không muốn mã hóa cứng phạm vi ngày trong công thức thì bạn có thể nhập ngày bắt đầu vào F1, ngày kết thúc vào G1, nối các toán tử logic và tham chiếu ô và đặt toàn bộ tiêu chí trong dấu ngoặc kép như sau:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)
Để tránh các lỗi có thể xảy ra, bạn có thể cung cấp ngày với sự trợ giúp của hàm DATE:
=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))
Tính tổng trong phạm vi động dựa trên ngày hôm nay
Trong trường hợp bạn cần tính tổng dữ liệu trong phạm vi ngày động (X ngày trở lại kể từ hôm nay hoặc Y ngày trở đi), hãy xây dựng tiêu chí bằng cách sử dụng hàm TODAY, hàm này sẽ lấy ngày hiện tại và tự động cập nhật.
Ví dụ: để tính tổng các khoản ngân sách đến hạn cuối cùng 7 ngày kể cả ngày hôm nay , công thức là:
=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)
Nếu bạn không muốn đưa ngày hiện tại vào kết quả cuối cùng, hãy sử dụng toán tử nhỏ hơn (<) cho tiêu chí đầu tiên để loại trừ ngày hôm nay và lớn hơn hoặc bằng (>=) cho tiêu chí thứ hai đểbao gồm ngày cách ngày hôm nay 7 ngày:
=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)
Theo cách tương tự, bạn có thể tính tổng các giá trị nếu ngày là một số ngày nhất định chuyển tiếp.
Ví dụ: để có được tổng số ngân sách đến hạn trong 3 ngày tới, hãy sử dụng một trong các công thức sau:
Kết quả bao gồm ngày hôm nay:
=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)
Kết quả không bao gồm ngày hôm nay:
=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)
Tính tổng nếu giữa hai ngày và một tiêu chí khác
Để tính tổng các giá trị trong phạm vi ngày đáp ứng một số điều kiện khác trong một cột khác, chỉ cần thêm một cặp phạm vi/tiêu chí khác vào công thức SUMIFS của bạn.
Ví dụ: để tính tổng ngân sách trong một phạm vi nhất định phạm vi ngày cho tất cả các dự án có chứa "mẹo" trong tên của chúng, hãy mở rộng công thức bằng tiêu chí ký tự đại diện:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")
Trong đó A2:A10 là tên dự án, B2:B10 là tên dự án các số để tính tổng, C2:C10 là ngày cần kiểm tra, F1 là ngày bắt đầu và G1 là ngày kết thúc.
Tất nhiên, không có gì ngăn cản bạn nhập liền một lúc tiêu chí thứ ba cả ô xếp hạng và tham chiếu ô đó như minh họa trong ảnh chụp màn hình:
Cú pháp tiêu chí ngày SUMIFS
Khi sử dụng ngày làm tiêu chí cho hàm SUMIF trong Excel và hàm SUMIFS, bạn sẽ không phải là người đầu tiên bị nhầm lẫn đâu :)
Tuy nhiên, khi xem xét kỹ hơn, tất cả các trường hợp sử dụng khác nhau đều quy về một vài quy tắc đơn giản:
Nếu bạn đặt ngày trực tiếp trong tiêu chíđối số , sau đó nhập toán tử logic (>, <, =, ) ngay trước ngày và đặt toàn bộ tiêu chí trong dấu ngoặc kép. Ví dụ:
=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")
Khi nhập ngày vào ô được xác định trước, hãy cung cấp tiêu chí ở dạng chuỗi văn bản: đặt toán tử logic trong dấu ngoặc kép để bắt đầu một chuỗi và sử dụng dấu và (&) để nối và kết thúc chuỗi. Ví dụ:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)
Khi một ngày được điều khiển bởi một hàm khác chẳng hạn như DATE hoặc TODAY(), hãy nối một toán tử so sánh và một hàm. Ví dụ:
=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())
SUMIF Excel giữa các ngày không hoạt động
Trong trường hợp công thức của bạn không hoạt động hoặc tạo ra kết quả sai, các mẹo khắc phục sự cố sau đây có thể làm sáng tỏ lý do tại sao không thành công và giúp bạn khắc phục sự cố.
Kiểm tra định dạng của ngày và số
Nếu công thức SUMIFS có vẻ đúng không trả về gì ngoài 0, điều đầu tiên cần kiểm tra là ngày của bạn có thực sự là ngày không và không phải chuỗi văn bản chỉ trông giống như ngày tháng. Tiếp theo, hãy chắc chắn rằng bạn đang tính tổng các số chứ không phải các số được lưu dưới dạng văn bản. Các hướng dẫn sau đây sẽ giúp bạn phát hiện và khắc phục những sự cố này.
- Cách thay đổi "ngày văn bản" thành ngày thực
- Cách chuyển đổi văn bản thành số
Sử dụng đúng cú pháp cho tiêu chí
Khi kiểm tra ngày tháng bằng SUMIFS, ngày tháng phải được đặt trong dấu ngoặc kép như ">=9/10/2020"; tham chiếu ô vàcác chức năng nên được đặt bên ngoài dấu ngoặc kép như "<="&G1 hoặc "<="&TODAY(). Để biết chi tiết đầy đủ, vui lòng xem cú pháp tiêu chí ngày.
Xác minh logic của công thức
Một lỗi đánh máy nhỏ trong ngân sách có thể tiêu tốn hàng triệu đô la. Một lỗi nhỏ trong công thức có thể tốn hàng giờ sửa lỗi. Vì vậy, khi tính tổng giữa 2 ngày, hãy kiểm tra xem ngày bắt đầu có trước toán tử lớn hơn (>) hoặc lớn hơn hoặc bằng (>=) và kết thúc không ngày có tiền tố là nhỏ hơn (<) hoặc nhỏ hơn hoặc bằng (<=).
Đảm bảo tất cả các phạm vi đều có cùng kích thước
Để hàm SUMIFS hoạt động chính xác, phạm vi tổng và phạm vi tiêu chí phải có kích thước bằng nhau, nếu không thì lỗi #VALUE! lỗi xảy ra. Để khắc phục, hãy đảm bảo rằng tất cả các đối số criteria_range có cùng số lượng hàng và cột như sum_range .
Đó là cách sử dụng hàm SUMIFS của Excel để tính tổng dữ liệu trong một phạm vi ngày. Nếu bạn có một số giải pháp thú vị khác trong tâm trí, tôi sẽ thực sự biết ơn nếu bạn chia sẻ nhận xét. Cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!
Sách bài tập thực hành để tải xuống
Ví dụ về phạm vi ngày SUMIFS (tệp .xlsx)
