Duke punuar në një raport, plan investimi ose ndonjë grup tjetër të dhënash me data, shpesh mund t'ju duhet të përmblidhni numra brenda një periudhe të caktuar. Ky tutorial do t'ju mësojë një zgjidhje të shpejtë dhe të lehtë - formulën SUMIFS me diapazonin e datave si kriter.

Në blogun tonë dhe forumet e tjera të Excel, njerëzit shpesh pyesin se si të përdorin SUMIF për intervalin e datave. Çështja është se për të përmbledhur midis dy datave, duhet të përcaktoni të dyja datat ndërsa funksioni Excel SUMIF lejon vetëm një kusht. Fatmirësisht, ne kemi gjithashtu funksionin SUMIFS që mbështet kritere të shumta.

Si të përmbledhim nëse midis dy datave në Excel

Për të mbledhur vlerat brenda një diapazoni të caktuar datash, përdorni një formulë SUMIFS me datat e fillimit dhe mbarimit si kriter. Sintaksa e funksionit SUMIFS kërkon që së pari të specifikoni vlerat që do të mblidhen (suma_range), dhe më pas të jepni çiftet e diapazonit/kritereve. Në rastin tonë, diapazoni (një listë datash) do të jetë i njëjtë për të dy kriteret.

Duke marrë parasysh sa më sipër, formulat e përgjithshme për të mbledhur vlerat ndërmjet dy datave marrin këtë formë:

Përfshirë datat e pragut:

Me përjashtim të datave të pragut:

Siç mund ta shihni, ndryshimi është vetëm në operatorët logjikë. Në formulën e parë, ne përdorim më e madhese ose e barabartë me (>=) dhe më pak se ose e barabartë me (<=) për të përfshirë datat e pragut në rezultat. Formula e dytë kontrollon nëse një datë është më e madhe se (>) ose më e vogël se (<), duke lënë jashtë datat e fillimit dhe të mbarimit.

Në tabela më poshtë, supozoni se dëshironi të përmblidhni projektet që duhet të bëhen në një interval të caktuar datash, përfshirëse. Për ta bërë këtë, përdorni këtë formulë:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Nëse nuk dëshironi të kodoni një interval datash në formulë, atëherë mund të shkruani datën e fillimit në F1, datën e përfundimit në G1, lidhni operatorët logjikë dhe referencat e qelizave dhe mbyllni të gjitha kriteret në thonjëza si kjo:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Për të shmangur gabimet e mundshme, mund të jepni datat me ndihmën e funksionit DATE:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

Suma brenda një diapazoni dinamik bazuar në datën e sotme

Në situatën kur ju duhet të përmbledhni të dhënat brenda një intervali dinamik datash (X ditë mbrapa nga sot ose Y ditë përpara), ndërtoni kriteret duke përdorur funksionin TODAY, i cili do të marrë datën aktuale dhe do ta përditësojë atë automatikisht.

Për shembull, për të përmbledhur buxhetet që duhet të paguhen në të fundit 7 ditë përfshirë datën e sotme , formula është:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

Nëse nuk dëshironi të përfshini datën aktuale në rezultatin përfundimtar, përdorni më pak se operatori (<) për kriteret e para për të përjashtuar datën e sotme dhe më e madhe se ose e barabartë me (>=) për kriterin e dytë përpërfshini datën që është 7 ditë përpara ditës së sotme:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

Në mënyrë të ngjashme, ju mund të mblidhni vlerat nëse një datë është një numër i caktuar ditësh përpara.

Për shembull, për të marrë një total të buxheteve që duhet të paguhen në 3 ditët e ardhshme, përdorni një nga formulat e mëposhtme:

Data e sotme përfshihet në rezultat:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

Data e sotme nuk përfshihet në rezultat:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

Shuma nëse midis dy datave dhe një kriteri tjetër

Për të përmbledhur vlerat brenda një diapazoni datash që plotësojnë disa kushte të tjera në një kolonë tjetër, thjesht shtoni një çift tjetër diapazoni/kriteresh në formulën tuaj SUMIFS.

Për shembull, për të përmbledhur buxhetet brenda një kohe të caktuar diapazoni i datave për të gjitha projektet që përmbajnë "tip" në emrat e tyre, zgjeroni formulën me një kriter të shkronjës:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

Aty ku A2:A10 janë emrat e projekteve, B2:B10 janë numrat për të mbledhur, C2:C10 janë datat për t'u kontrolluar, F1 është data e fillimit dhe G1 është data e përfundimit.

Sigurisht, asgjë nuk ju pengon të futni kriterin e tretë në një sepa vlerësoni gjithashtu qelizën, dhe duke iu referuar asaj qelize siç tregohet në pamjen e ekranit:

Sintaksa e kritereve të datës SUMIFS

Kur bëhet fjalë për përdorimin e datave si kritere për Excel SUMIF dhe funksionet SUMIFS, nuk do të ishit personi i parë që do të hutoheni :)

Me një vështrim më të afërt, megjithatë, e gjithë shumëllojshmëria e rasteve të përdorimit përmblidhet në disa rregulla të thjeshta:

Nëse vendosni data direkt në kriterin argumentet , më pas shkruani një operator logjik (>, <, =, ) menjëherë përpara datës dhe mbyllni të gjitha kriteret në thonjëza. Për shembull:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Kur një datë futet në një qelizë të paracaktuar, jepni kritere në formën e një vargu teksti: mbyllni një operator logjik në thonjëza në filloni një varg dhe përdorni një ampersand (&) për të lidhur dhe përfunduar vargun. Për shembull:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Kur një datë drejtohet nga një funksion tjetër si DATE ose TODAY(), lidhni një operator krahasimi dhe një funksion. Për shembull:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

Excel SUMIFS ndërmjet datave që nuk funksionon

Në rast se formula juaj nuk funksionon ose prodhon rezultate të gabuara, këshillat e mëposhtme për zgjidhjen e problemeve mund të hedhin dritë mbi arsyen pse dështon dhe ju ndihmon ta rregulloni problemin.

Kontrolloni formatin e datave dhe numrave

Nëse një formulë në dukje e saktë SUMIFS nuk kthen asgjë përveç zeros, gjëja e parë që duhet të kontrolloni është që datat tuaja janë vërtet data , dhe jo vargjet e tekstit që duken vetëm si data. Më pas, sigurohuni që jeni duke mbledhur numra dhe jo numra të ruajtur si tekst. Udhëzimet e mëposhtme do t'ju ndihmojnë të zbuloni dhe rregulloni këto probleme.

• Si të ndryshoni "datat e tekstit" në data reale
• Si ta konvertoni tekstin në numër

Përdorni sintaksën e saktë për kriteret

Kur kontrolloni datat duke përdorur SUMIFS, një datë duhet të vendoset brenda thonjëzave si ">=9/10/2020"; referencat e qelizave dhefunksionet duhet të vendosen jashtë thonjëzave si "<="&G1 ose "<="&TODAY(). Për detaje të plota, ju lutemi shikoni sintaksën e kritereve të datës.

Verifikoni logjikën e formulës

Një gabim i vogël shtypi në një buxhet mund të kushtojë miliona. Një gabim i vogël në një formulë mund të kushtojë orë të tëra kohë korrigjimi. Pra, kur përmbledhni midis 2 datave, kontrolloni nëse data e fillimit paraprihet nga operatori më i madh se (>) ose më i madh se ose i barabartë me (>=) dhe fundi data është parashtesuar me më pak se (<) ose më pak se ose e barabartë me (<=).

Sigurohu që të gjitha vargjet janë të së njëjtës madhësi

Që funksioni SUMIFS të funksionojë si duhet, diapazoni i shumës dhe diapazoni i kritereve duhet të jenë të barabarta, përndryshe një #VALUE! ndodh gabimi. Për ta rregulluar atë, sigurohuni që të gjitha argumentet gama_kriterore të kenë të njëjtin numër rreshtash dhe kolonash si vargu_sume .

Kjo është mënyra se si të përdorni funksionin Excel SUMIFS për të përmbledhur të dhënat në një interval datash. Nëse keni në mendje disa zgjidhje të tjera interesante, do të jem shumë mirënjohës nëse i ndani në komente. Faleminderit që lexoni dhe shpresojmë t'ju shohim në blogun tonë javën tjetër!

Praktikoni librin e punës për shkarkim

Sumifs shembuj të diapazonit të datave (skedari .xlsx)