Wrth weithio ar adroddiad, cynllun buddsoddi neu unrhyw set ddata arall gyda dyddiadau, efallai y bydd angen i chi grynhoi rhifau o fewn cyfnod penodol. Bydd y tiwtorial hwn yn dysgu datrysiad cyflym a hawdd i chi - fformiwla SUMIFS gydag ystod dyddiad fel meini prawf.

Ar ein blog a fforymau Excel eraill, mae pobl yn aml yn gofyn sut i ddefnyddio SUMIF ar gyfer ystod dyddiadau. Y pwynt yw, i grynhoi rhwng dau ddyddiad, mae angen i chi ddiffinio'r ddau ddyddiad tra bod swyddogaeth Excel SUMIF yn caniatáu un amod yn unig. Yn ffodus, mae gennym hefyd y swyddogaeth SUMIFS sy'n cefnogi meini prawf lluosog.

I grynhoi gwerthoedd o fewn ystod dyddiad penodol, defnyddiwch fformiwla SUMIFS gyda dyddiadau dechrau a gorffen fel meini prawf. Mae cystrawen y ffwythiant SUMIFS yn mynnu eich bod yn gyntaf yn nodi'r gwerthoedd i'w hadio (sum_range), ac yna'n darparu parau amrediad/meini prawf. Yn ein hachos ni, bydd yr ystod (rhestr o ddyddiadau) yr un fath ar gyfer y ddau faen prawf.

O ystyried yr uchod, mae'r fformiwlâu generig i grynhoi gwerthoedd rhwng dau ddyddiad ar y ffurf hon:

Gan gynnwys y dyddiadau trothwy:

Heb gynnwys y dyddiadau trothwy:

Fel y gwelwch, dim ond yn y gweithredwyr rhesymegol y mae'r gwahaniaeth. Yn y fformiwla gyntaf, rydym yn defnyddio mwyna neu hafal i (>=) a yn llai na neu'n hafal i (<=) i gynnwys y dyddiadau trothwy yn y canlyniad. Mae'r ail fformiwla yn gwirio a yw dyddiad yn fwy na (>) neu yn llai na (<), gan adael allan y dyddiadau dechrau a gorffen.

Yn y tabl isod, mae'n debyg eich bod am grynhoi prosiectau sy'n ddyledus o fewn ystod dyddiad penodol, yn gynwysedig. I'w wneud, defnyddiwch y fformiwla hon:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Os byddai'n well gennych beidio â chodio ystod dyddiad yn y fformiwla, gallwch deipio'r dyddiad cychwyn yn F1, y dyddiad gorffen yn G1, cydgadwynwch y gweithredwyr rhesymegol a'r cyfeirnodau cell ac amgaewch y meini prawf cyfan mewn dyfynodau fel hyn:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Er mwyn osgoi camgymeriadau posibl, gallwch gyflenwi dyddiadau gyda chymorth y ffwythiant DYDDIAD:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

Swm o fewn ystod ddeinamig yn seiliedig ar ddyddiad heddiw

Mewn sefyllfa pan fydd angen crynhoi data o fewn ystod dyddiad deinamig (X diwrnod yn ôl o heddiw neu Y diwrnod ymlaen), lluniwch y meini prawf trwy ddefnyddio'r ffwythiant HEDDIW, a fydd yn cael y dyddiad cyfredol ac yn ei ddiweddaru'n awtomatig.

Er enghraifft, i grynhoi cyllidebau sy'n ddyledus yn yr olaf 7 diwrnod gan gynnwys dyddiad heddiw , y fformiwla yw:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

Os byddai'n well gennych beidio â chynnwys y dyddiad presennol yn y canlyniad terfynol, defnyddiwch y llai na gweithredwr (<) ar gyfer y meini prawf cyntaf i eithrio dyddiad heddiw a yn fwy na neu'n hafal i (>=) ar gyfer yr ail faen prawf icynnwys y dyddiad sydd 7 diwrnod cyn heddiw:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

Yn yr un modd, gallwch adio gwerthoedd os yw dyddiad yn nifer penodol o ddyddiau ymlaen.

Er enghraifft, i gael cyfanswm o gyllidebau sy'n ddyledus o fewn y 3 diwrnod nesaf, defnyddiwch un o'r fformiwlâu canlynol:

Mae dyddiad heddiw wedi'i gynnwys yn y canlyniad:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

Nid yw dyddiad heddiw wedi'i gynnwys yn y canlyniad:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

Swm os rhwng dau ddyddiad a maen prawf arall

I adio gwerthoedd o fewn ystod dyddiad sy'n cwrdd â rhyw amod arall mewn colofn wahanol, ychwanegwch un ystod/pâr o feini prawf arall i'ch fformiwla SUMIFS.

Er enghraifft, i grynhoi cyllidebau o fewn rhyw un amrediad dyddiadau ar gyfer yr holl brosiectau sy'n cynnwys "tip" yn eu henwau, ymestyn y fformiwla gyda maen prawf cerdyn gwyllt:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

Ble mae A2:A10 yn enwau'r prosiectau, B2:B10 yw'r rhifau i grynhoi, C2:C10 yw'r dyddiadau i'w gwirio, F1 yw'r dyddiad cychwyn a G1 yw'r dyddiad gorffen.

Wrth gwrs, nid oes dim yn eich atal rhag nodi'r trydydd maen prawf mewn sepa cyfraddwch y gell hefyd, a chyfeirnodi'r gell honno fel y dangosir yn y sgrinlun:

Cstrawen meini prawf dyddiad SUMIFS

Pan ddaw i ddefnyddio dyddiadau fel meini prawf ar gyfer Excel SUMIF a swyddogaethau SUMIFS, nid chi fyddai'r person cyntaf i ddrysu :)

O edrych yn agosach, fodd bynnag, mae'r holl amrywiaeth o achosion defnydd yn dibynnu ar ychydig o reolau syml:

Os rhowch ddyddiadau yn uniongyrchol yn y meini prawf dadleuon , yna teipiwch weithredwr rhesymegol (>, <, =, ) yn union cyn y dyddiad ac amgaewch y meini prawf cyfan mewn dyfyniadau. Er enghraifft:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Pan fydd dyddiad yn cael ei fewnbynnu mewn cell ragddiffiniedig , rhowch feini prawf ar ffurf llinyn testun: amgaewch weithredwr rhesymegol mewn dyfynodau i cychwyn llinyn a defnyddio ampersand (&) i gydgadwynu a gorffen y llinyn i ffwrdd. Er enghraifft:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Pan fydd dyddiad yn cael ei yrru gan swyddogaeth arall megis DATE neu TODAY(), cydgadwynwch weithredwr cymharu a ffwythiant. Er enghraifft:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

Excel SUMIFS rhwng dyddiadau ddim yn gweithio

Rhag ofn nad yw eich fformiwla'n gweithio neu'n cynhyrchu canlyniadau anghywir, efallai y bydd yr awgrymiadau datrys problemau canlynol yn taflu goleuni ar pam yn methu ac yn eich helpu i drwsio'r mater.

Gwiriwch fformat dyddiadau a rhifau

Os yw fformiwla SUMIFS sy'n ymddangos yn gywir yn dychwelyd dim byd ond sero, y peth cyntaf i'w wirio yw mai dyddiadau yw eich dyddiadau mewn gwirionedd , ac nid llinynnau testun sydd ond yn edrych fel dyddiadau. Nesaf, gwnewch yn siŵr eich bod yn crynhoi rhifau, ac nid rhifau sydd wedi'u storio fel testun. Bydd y tiwtorialau canlynol yn eich helpu i adnabod a thrwsio'r materion hyn.

• Sut i newid "dyddiadau testun" i ddyddiadau real
• Sut i drosi testun i rif

Wrth wirio dyddiadau gan ddefnyddio SUMIFS, dylid rhoi dyddiad y tu mewn i'r dyfynodau fel ">=9/10/2020"; cyfeiriadau cell adylid gosod swyddogaethau y tu allan i'r dyfyniadau fel "<="&G1 neu "<="&TODAY(). Am fanylion llawn, gweler cystrawen meini prawf dyddiad.

Gwiriwch resymeg y fformiwla

Gallai teipio bach mewn cyllideb gostio miliynau. Gallai camgymeriad bach mewn fformiwla gostio oriau o amser dadfygio. Felly, wrth grynhoi rhwng 2 ddyddiad, gwiriwch a yw'r gweithredwr mwy na (>) neu yn fwy na neu'n hafal i (>=) o flaen y dyddiad cychwyn a'r diwedd mae'r dyddiad wedi'i ragnodi gan llai na (<) neu llai na neu'n hafal i (<=).

Sicrhewch fod pob ystod yr un maint<15

Er mwyn i ffwythiant SUMIFS weithio'n gywir, dylai'r ystod symiau a'r ystodau meini prawf fod yn gyfartal o ran maint, fel arall yn #VALUE! gwall yn digwydd. I'w drwsio, sicrhewch fod gan bob arg maen prawf_range yr un nifer o resi a cholofnau â sum_range .

Dyna sut i ddefnyddio ffwythiant Excel SUMIFS i grynhoi data i mewn ystod dyddiadau. Os oes gennych rai atebion diddorol eraill mewn golwg, byddaf yn ddiolchgar iawn os byddwch yn rhannu sylwadau. Diolch am ddarllen a gobeithio eich gweld ar ein blog wythnos nesaf!

Gweithlyfr ymarfer i'w lawrlwytho

Enghreifftiau amrediad dyddiadau SUMIFS (ffeil .xlsx)