Isi kandungan
Mengusahakan laporan, pelan pelaburan atau mana-mana set data lain dengan tarikh, anda mungkin sering perlu menjumlahkan nombor dalam tempoh tertentu. Tutorial ini akan mengajar anda penyelesaian yang cepat dan mudah - formula SUMIFS dengan julat tarikh sebagai kriteria.
Di blog kami dan forum Excel yang lain, orang sering bertanya cara menggunakan SUMIF untuk julat tarikh. Intinya ialah untuk menjumlahkan antara dua tarikh, anda perlu menentukan kedua-dua tarikh manakala fungsi Excel SUMIF hanya membenarkan satu syarat. Nasib baik, kami juga mempunyai fungsi SUMIFS yang menyokong berbilang kriteria.
Cara menjumlahkan jika antara dua tarikh dalam Excel
Untuk menjumlahkan nilai dalam julat tarikh tertentu, gunakan formula SUMIFS dengan tarikh mula dan tamat sebagai kriteria. Sintaks fungsi SUMIFS memerlukan anda terlebih dahulu menentukan nilai untuk ditambah (sum_range), dan kemudian menyediakan pasangan julat/kriteria. Dalam kes kami, julat (senarai tarikh) adalah sama untuk kedua-dua kriteria.
Memandangkan perkara di atas, formula generik untuk menjumlahkan nilai antara dua tarikh mengambil bentuk ini:
Termasuk tarikh ambang:
SUMIFS( julat_jumlah, tarikh,">= tarikh_mula", tarikh, "<= tarikh_akhir")Tidak termasuk tarikh ambang:
SUMIFS( julat_jumlah, tarikh,"> tarikh_mula", tarikh, "< tarikh_akhir")Seperti yang anda lihat, perbezaannya hanya dalam pengendali logik. Dalam formula pertama, kami menggunakan lebih hebatdaripada atau sama dengan (>=) dan kurang daripada atau sama dengan (<=) untuk memasukkan tarikh ambang dalam keputusan. Formula kedua menyemak sama ada tarikh adalah lebih besar daripada (>) atau kurang daripada (<), meninggalkan tarikh mula dan tamat.
Dalam jadual di bawah, katakan anda ingin menjumlahkan projek yang perlu dibayar dalam julat tarikh tertentu, termasuk. Untuk melakukannya, gunakan formula ini:
=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")
Jika anda lebih suka tidak mengekod keras julat tarikh dalam formula, maka anda boleh menaip tarikh mula dalam F1, tarikh tamat dalam G1, gabungkan operator logik dan rujukan sel dan sertakan keseluruhan kriteria dalam tanda petikan seperti ini:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)
Untuk mengelakkan kesilapan yang mungkin berlaku, anda boleh membekalkan tarikh dengan bantuan fungsi DATE:
=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))
Jumlah dalam julat dinamik berdasarkan tarikh hari ini
Dalam situasi apabila anda perlu menjumlahkan data dalam julat tarikh dinamik (X hari kembali dari hari ini atau Y hari ke hadapan), bina kriteria dengan menggunakan fungsi TODAY, yang akan mendapatkan tarikh semasa dan mengemas kininya secara automatik.
Sebagai contoh, untuk menjumlahkan belanjawan yang perlu dibayar pada masa lalu 7 hari termasuk tarikh hari ini , formulanya ialah:
=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)
Jika anda lebih suka tidak memasukkan tarikh semasa dalam hasil akhir, gunakan kurang daripada operator (<) untuk kriteria pertama untuk mengecualikan tarikh hari ini dan lebih besar daripada atau sama dengan (>=) untuk kriteria kedua kepadasertakan tarikh iaitu 7 hari sebelum hari ini:
=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)
Dengan cara yang sama, anda boleh menjumlahkan nilai jika tarikh ialah bilangan hari tertentu ke hadapan.
Sebagai contoh, untuk mendapatkan jumlah belanjawan yang perlu dibayar dalam tempoh 3 hari seterusnya, gunakan salah satu daripada formula berikut:
Tarikh hari ini disertakan dalam keputusan:
=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)
Tarikh hari ini tidak termasuk dalam keputusan:
=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)
Jumlah jika antara dua tarikh dan kriteria lain
Untuk menjumlahkan nilai dalam julat tarikh yang memenuhi beberapa syarat lain dalam lajur yang berbeza, cuma tambah satu lagi pasangan julat/kriteria pada formula SUMIFS anda.
Sebagai contoh, untuk menjumlahkan belanjawan dalam lingkungan tertentu julat tarikh untuk semua projek yang mengandungi "tip" dalam namanya, lanjutkan formula dengan kriteria kad bebas:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")
Di mana A2:A10 ialah nama projek, B2:B10 ialah nombor untuk dijumlahkan, C2:C10 ialah tarikh untuk diperiksa, F1 ialah tarikh mula dan G1 ialah tarikh tamat.
Sudah tentu, tiada apa yang menghalang anda daripada memasukkan kriteria ketiga dalam sepa kadar sel juga dan merujuk sel itu seperti yang ditunjukkan dalam tangkapan skrin:
Sintaks kriteria tarikh SUMIFS
Apabila ia datang untuk menggunakan tarikh sebagai kriteria untuk Excel SUMIF dan fungsi SUMIFS, anda tidak akan menjadi orang pertama yang keliru :)
Walau bagaimanapun, apabila dilihat lebih dekat, semua kepelbagaian kes penggunaan berpunca kepada beberapa peraturan mudah:
Jika anda meletakkan tarikh terus dalam kriteriaargumen , kemudian taip operator logik (>, <, =, ) betul-betul sebelum tarikh dan sertakan keseluruhan kriteria dalam petikan. Contohnya:
=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")
Apabila tarikh dimasukkan dalam sel yang dipratakrif, sediakan kriteria dalam bentuk rentetan teks: sertakan operator logik dalam tanda petikan ke mulakan rentetan dan gunakan ampersand (&) untuk menggabungkan dan menamatkan rentetan itu. Contohnya:
=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)
Apabila tarikh didorong oleh fungsi lain seperti DATE atau TODAY(), gabungkan operator perbandingan dan fungsi. Contohnya:
=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())
Excel SUMIFS antara tarikh tidak berfungsi
Sekiranya formula anda tidak berfungsi atau menghasilkan hasil yang salah, petua penyelesaian masalah berikut mungkin menjelaskan sebabnya gagal dan membantu anda menyelesaikan isu ini.
Semak format tarikh dan nombor
Jika formula SUMIFS yang kelihatan betul tidak mengembalikan apa-apa selain sifar, perkara pertama yang perlu disemak ialah tarikh anda benar-benar tarikh , dan bukan rentetan teks yang hanya kelihatan seperti tarikh. Seterusnya, pastikan anda menjumlahkan nombor, dan bukan nombor yang disimpan sebagai teks. Tutorial berikut akan membantu anda melihat dan membetulkan isu ini.
- Cara menukar "tarikh teks" kepada tarikh sebenar
- Cara menukar teks kepada nombor
Gunakan sintaks yang betul untuk kriteria
Apabila menyemak tarikh menggunakan SUMIFS, tarikh hendaklah diletakkan di dalam tanda petikan seperti ">=9/10/2020"; rujukan sel danfungsi hendaklah diletakkan di luar petikan seperti "<="&G1 atau "<="&TODAY(). Untuk butiran penuh, sila lihat sintaks kriteria tarikh.
Sahkan logik formula
Tipe kesilapan kecil dalam belanjawan boleh menelan belanja berjuta-juta. Sedikit kesilapan dalam formula mungkin memerlukan masa berjam-jam untuk menyahpepijat. Jadi, apabila menjumlahkan antara 2 tarikh, semak sama ada tarikh mula didahului oleh operator lebih besar daripada (>) atau lebih daripada atau sama dengan (>=) dan penghujungnya tarikh diawali dengan kurang daripada (<) atau kurang daripada atau sama dengan (<=).
Pastikan semua julat adalah saiz yang sama
Untuk fungsi SUMIFS berfungsi dengan betul, julat jumlah dan julat kriteria hendaklah bersaiz sama, jika tidak, #VALUE! ralat berlaku. Untuk membetulkannya, pastikan semua argumen julat_kriteria mempunyai bilangan baris dan lajur yang sama seperti julat_jumlah .
Begitulah cara menggunakan fungsi Excel SUMIFS untuk menjumlahkan data dalam julat tarikh. Jika anda mempunyai beberapa penyelesaian menarik lain dalam fikiran, saya akan sangat berterima kasih jika anda berkongsi dalam komen. Terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!
Buku kerja latihan untuk muat turun
Contoh julat tarikh SUMIFS (fail.xlsx)
