Dirbant su ataskaita, investiciniu planu ar bet kuriuo kitu duomenų rinkiniu su datomis, dažnai gali prireikti sumuoti tam tikro laikotarpio skaičius. Šioje pamokoje išmoksite greito ir paprasto sprendimo - SUMIFS formulės, kurios kriterijus yra datų intervalas.

Mūsų tinklaraštyje ir kituose "Excel" forumuose žmonės dažnai klausia, kaip naudoti SUMIF datų intervalui. Esmė ta, kad norint sumuoti tarp dviejų datų, reikia apibrėžti abi datas, o "Excel" funkcija SUMIF leidžia naudoti tik vieną sąlygą. Laimei, taip pat turime funkciją SUMIFS, kuri palaiko kelis kriterijus.

Kaip "Excel" programoje susumuoti jei tarp dviejų datų

Jei norite sumuoti tam tikro datų intervalo reikšmes, naudokite SUMIFS formulę, kurios kriterijai yra pradžios ir pabaigos datos. Pagal SUMIFS funkcijos sintaksę pirmiausia reikia nurodyti sumuojamas reikšmes (sum_range), o tada pateikti intervalų ir kriterijų poras. Mūsų atveju abiejų kriterijų intervalas (datų sąrašas) bus tas pats.

Atsižvelgiant į tai, kas išdėstyta pirmiau, bendrosios formulės, skirtos dviejų datų reikšmėms sumuoti, yra tokios:

Įskaitant ribines datas:

Išskyrus ribines datas:

Kaip matote, skiriasi tik loginiai operatoriai. Pirmojoje formulėje naudojame didesnis nei arba lygus (>=) ir mažesnis arba lygus (<=), kad į rezultatą būtų įtrauktos ribinės datos. Antroji formulė tikrina, ar data yra didesnis nei (>) arba mažiau nei (<), palikdami pradžios ir pabaigos datas.

Tarkime, kad toliau pateiktoje lentelėje norite susumuoti projektus, kurie turi būti įvykdyti tam tikrame datų intervale imtinai. Kad tai padarytumėte, naudokite šią formulę:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Jei nenorite formulėje įrašyti datos intervalo, tuomet pradžios datą galite įrašyti į F1, pabaigos datą - į G1, sujungti loginius operatorius ir ląstelių nuorodas ir visą kriterijų uždaryti kabutėmis taip:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Kad išvengtumėte galimų klaidų, datas galite pateikti naudodami funkciją DATA:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

Suma dinaminiame intervale pagal šiandienos datą

Jei reikia sumuoti duomenis, kurie patenka į dinaminį datos intervalą (X dienų atgal nuo šios dienos arba Y dienų į priekį), sudarykite kriterijus naudodami funkciją TODAY, kuri gaus dabartinę datą ir automatiškai ją atnaujins.

Pavyzdžiui, norėdami susumuoti biudžetus, kurie turi būti įvykdyti per pastarąsias 7 dienas. įskaitant šiandienos datą , formulė yra tokia:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

Jei nenorėtumėte, kad į galutinį rezultatą būtų įtraukta dabartinė data, naudokite mažiau nei operatorius (<) pirmajam kriterijui, kad būtų neįtraukta šiandienos data ir didesnis arba lygus (>=), kad į antrąjį kriterijų būtų įtraukta data, kuri yra 7 dienos iki šios dienos:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

Panašiai galite sumuoti reikšmes, jei data yra tam tikrą dienų skaičių į priekį.

Pavyzdžiui, norėdami gauti bendrą biudžetų, kurie turi būti įvykdyti per artimiausias 3 dienas, sumą, naudokite vieną iš šių formulių:

Į rezultatą įtraukiama šiandienos data:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

Šiandienos data į rezultatą neįtraukiama:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

Suma, jei tarp dviejų datų ir kito kriterijaus

Jei norite sumuoti datų intervalo reikšmes, atitinkančias kitą kito stulpelio sąlygą, į SUMIFS formulę paprasčiausiai įtraukite dar vieną intervalų ir kriterijų porą.

Pavyzdžiui, norėdami susumuoti visų projektų, kurių pavadinimuose yra žodis "tip", biudžetus tam tikros datos intervale, išplėskite formulę naudodami pakaitinio simbolio kriterijų:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

Kai A2:A10 yra projekto pavadinimai, B2:B10 - numeriai, kuriuos reikia sumuoti, C2:C10 - datos, kurias reikia patikrinti, F1 - pradžios data, o G1 - pabaigos data.

Žinoma, niekas nedraudžia trečiąjį kriterijų įvesti ir atskiroje ląstelėje bei pateikti nuorodą į tą ląstelę, kaip parodyta paveikslėlyje:

SUMIFS datos kriterijų sintaksė

Kai reikia naudoti datas kaip kriterijus "Excel" SUMIF ir SUMIFS funkcijoms, ne jūs pirmas susipainiojate :)

Tačiau, atidžiau pažvelgus, visi įvairūs naudojimo atvejai susiveda į kelias paprastas taisykles:

Jei datas įrašote tiesiai į kriterijų argumentai tada prieš pat datą įveskite loginį operatorių (>, <, =, ) ir visą kriterijų uždarykite kabutėmis, pvz:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Kai data įvedama į iš anksto nustatytą ląstelė , pateikite kriterijus kaip teksto eilutę: loginį operatorių uždarykite kabutėse, kad pradėtumėte eilutę, ir naudokite ampersandą (&), kad eilutę sujungtumėte ir užbaigtumėte, pvz:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Kai datą lemia kita funkcija pavyzdžiui, DATA arba TODAY(), sujungti palyginimo operatorių ir funkciją. Pavyzdžiui:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

"Excel" SUMIFS tarp datų neveikia

Jei jūsų formulė neveikia arba pateikia neteisingus rezultatus, toliau pateikiami trikčių šalinimo patarimai gali padėti išsiaiškinti, kodėl ji neveikia, ir išspręsti problemą.

Patikrinkite datų ir skaičių formatą

Jei iš pažiūros teisinga SUMIFS formulė grąžina tik nulį, pirmiausia reikia patikrinti, ar jūsų datos tikrai yra datos, o ne teksto eilutės, kurios tik atrodo kaip datos. Tada įsitikinkite, kad sumuojate skaičius, o ne skaičius, išsaugotus kaip tekstas. Toliau pateikiamos pamokos padės jums pastebėti ir išspręsti šias problemas.

• Kaip pakeisti "teksto datas" į tikras datas
• Kaip konvertuoti tekstą į skaičių

Naudokite teisingą kriterijų sintaksę

Tikrinant datas naudojant SUMIFS, datą reikia įrašyti kabutėse, pavyzdžiui, ">=9/10/2020"; langelių nuorodos ir funkcijos turi būti įrašytos už kabučių, pavyzdžiui, "<="&G1 arba "<="&TODAY(). Išsamios informacijos rasite dalyje Datos kriterijų sintaksė.

Patikrinkite formulės logiką

Nedidelė klaida biudžete gali kainuoti milijonus. Nedidelė klaida formulėje gali kainuoti valandų valandas derinimo laiko. Taigi, kai sumuojate 2 datas, patikrinkite, ar prieš pradžios datą yra simbolis didesnis nei (>) arba didesnis arba lygus (>=) operatorius, o pabaigos data žymima priešdėliu mažiau nei (<) arba mažesnis arba lygus (<=).

Įsitikinkite, kad visi diapazonai yra vienodo dydžio

Kad funkcija SUMIFS veiktų teisingai, sumos intervalas ir kriterijų intervalai turi būti vienodo dydžio, nes priešingu atveju įvyks #VALUE! klaida. Norėdami ją ištaisyti, įsitikinkite, kad visi kriterijų_diapazonas argumentai turi tiek pat eilučių ir stulpelių, kiek ir sum_range .

Štai kaip naudoti "Excel" funkciją SUMIFS, kad būtų galima sumuoti duomenis datos intervale. Jei turite kitų įdomių sprendimų, būsiu labai dėkingas, jei pasidalinsite jais komentaruose. Dėkojame, kad skaitėte, ir tikimės, kad kitą savaitę susitiksime mūsų tinklaraštyje!

Atsisiųsti praktikos sąsiuvinį

SUMIFS datų intervalų pavyzdžiai (.xlsx failas)