Microsoft Excel menawarkan sejumlah opsi untuk membandingkan dan mencocokkan data, tetapi kebanyakan dari mereka fokus pada pencarian dalam satu kolom. Dalam tutorial ini, kita akan mengeksplorasi beberapa teknik untuk membandingkan dua kolom di Excel dan menemukan kecocokan dan perbedaan di antara mereka.

Cara membandingkan 2 kolom di Excel baris demi baris

Saat Anda melakukan analisis data di Excel, salah satu tugas yang paling sering dilakukan adalah membandingkan data di setiap baris individu. Tugas ini dapat dilakukan dengan menggunakan fungsi IF, seperti yang ditunjukkan pada contoh berikut.

Contoh 1. Bandingkan dua kolom untuk kecocokan atau perbedaan dalam baris yang sama

Untuk membandingkan dua kolom di Excel baris demi baris, tulis rumus IF biasa yang membandingkan dua sel pertama. Masukkan rumus di beberapa kolom lain di baris yang sama, lalu salin ke sel lain dengan menyeret gagang isian (kotak kecil di sudut kanan bawah sel yang dipilih). Saat Anda melakukan ini, kursor berubah menjadi tanda plus:

Formula untuk pertandingan

Untuk menemukan sel dalam baris yang sama yang memiliki konten yang sama, A2 dan B2 dalam contoh ini, rumusnya adalah sebagai berikut:

=IF(A2=B2,"Match","")

Rumus untuk perbedaan

Untuk menemukan sel di baris yang sama dengan nilai yang berbeda, cukup ganti tanda sama dengan tanda non-kesetaraan ():

=IF(A2B2, "Tidak cocok","")

Kecocokan dan perbedaan

Dan tentu saja, tidak ada yang menghalangi Anda untuk menemukan kecocokan dan perbedaan dengan satu formula:

=IF(A2=B2, "Cocok", "Tidak cocok")

Atau

=IF(A2B2, "Tidak cocok", "Cocok")

Hasilnya mungkin terlihat mirip dengan ini:

Seperti yang Anda lihat, rumus menangani angka , tanggal , kali dan string teks sama baiknya.

Tip. Anda juga dapat membandingkan dua kolom baris demi baris menggunakan Excel Advanced Filter. Berikut adalah contoh yang menunjukkan cara memfilter kecocokan dan perbedaan antara 2 kolom.

Contoh 2. Bandingkan dua daftar untuk kecocokan case-sensitive dalam baris yang sama

Seperti yang mungkin Anda perhatikan, rumus dari contoh sebelumnya mengabaikan case ketika membandingkan nilai teks, seperti pada baris 10 pada screenshot di atas. Jika Anda ingin mencari kecocokan yang peka huruf besar-kecil antara 2 kolom di setiap baris, lalu gunakan fungsi EXACT:

=IF(EXACT(A2, B2), "Cocok", "")

Untuk menemukan perbedaan yang sensitif terhadap kasus di baris yang sama, masukkan teks yang sesuai ("Unique" dalam contoh ini) dalam argumen ke-3 dari fungsi IF, mis:

=IF(EXACT(A2, B2), "Cocok", "Unik")

Bandingkan beberapa kolom untuk kecocokan di baris yang sama

Di lembar kerja Excel Anda, beberapa kolom dapat dibandingkan berdasarkan kriteria berikut:

• Temukan baris dengan nilai yang sama di semua kolom (Contoh 1)
• Temukan baris dengan nilai yang sama di 2 kolom apa saja (Contoh 2)

Contoh 1. Temukan kecocokan di semua sel dalam baris yang sama

Jika tabel Anda memiliki tiga kolom atau lebih dan Anda ingin menemukan baris yang memiliki nilai yang sama di semua sel, rumus IF dengan pernyataan AND akan bekerja dengan baik:

=IF(AND(A2=B2, A2=C2), "Cocok penuh", "")

Jika tabel Anda memiliki banyak kolom, solusi yang lebih elegan adalah menggunakan fungsi COUNTIF:

=IF(COUNTIF($A2:$E2, $A2)=5, "Full match", "")

Di mana 5 adalah jumlah kolom yang Anda bandingkan.

Contoh 2. Temukan kecocokan dalam dua sel mana pun di baris yang sama

Jika Anda mencari cara untuk membandingkan kolom untuk dua sel atau lebih dengan nilai yang sama dalam baris yang sama, gunakan rumus IF dengan pernyataan OR:

=IF(OR(A2=B2, B2=C2, A2=C2), "Cocok", "")

Jika ada banyak kolom untuk dibandingkan, pernyataan OR Anda mungkin tumbuh terlalu besar ukurannya. Dalam hal ini, solusi yang lebih baik adalah menambahkan beberapa fungsi COUNTIF. COUNTIF pertama menghitung berapa banyak kolom yang memiliki nilai yang sama dengan kolom ke-1, COUNTIF kedua menghitung berapa banyak kolom yang tersisa yang sama dengan kolom ke-2, dan seterusnya. Jika hitungannya adalah 0, rumusnya mengembalikan "Unik","Cocokkan" jika tidak. Misalnya:

=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0, "Unik", "Cocok")

Cara membandingkan dua kolom di Excel untuk kecocokan dan perbedaan

Misalkan Anda memiliki 2 daftar data di Excel, dan Anda ingin menemukan semua nilai (angka, tanggal atau string teks) yang ada di kolom A tetapi tidak di kolom B.

Untuk ini, kamu bisa menyematkan fungsi COUNTIF($B:$B, $A2)=0 dalam tes logika IF dan mengecek apakah hasilnya nol (tidak ada kecocokan yang ditemukan) atau angka lainnya (setidaknya 1 kecocokan ditemukan).

Misalnya, rumus IF/COUNTIF berikut ini mencari di seluruh kolom B untuk nilai di sel A2. Jika tidak ada kecocokan yang ditemukan, rumus mengembalikan "Tidak ada kecocokan di B", sebaliknya string kosong:

=IF(COUNTIF($B:$B, $A2)=0, "Tidak ada kecocokan di B", "")

Tip. Jika tabel Anda memiliki jumlah baris yang tetap, Anda dapat menentukan rentang tertentu (misalnya $ B2: $ B10) daripada seluruh kolom ($ B: $ B) agar rumus bekerja lebih cepat pada kumpulan data yang besar.

Hasil yang sama dapat dicapai dengan menggunakan rumus IF dengan fungsi ISERROR dan MATCH yang disematkan:

=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)), "Tidak ada kecocokan di B","")

Atau, dengan menggunakan rumus larik berikut (ingat untuk menekan Ctrl + Shift + Enter untuk memasukkannya dengan benar):

=IF(SUM(--($B$2:$B$10=$A2))=0, " Tidak ada kecocokan di B", "")

Jika Anda menginginkan formula tunggal untuk mengidentifikasi kecocokan (duplikat) dan perbedaan (nilai unik), letakkan beberapa teks untuk kecocokan di dalam tanda kutip ganda kosong ("") dalam salah satu formula di atas. Misalnya:

=IF(COUNTIF($B:$B, $A2)=0, "Tidak ada kecocokan di B", "Cocok di B")

Cara membandingkan dua daftar di Excel dan menarik kecocokan

Terkadang Anda mungkin tidak hanya perlu mencocokkan dua kolom dalam dua tabel yang berbeda, tetapi juga menarik entri yang cocok dari tabel pencarian. Microsoft Excel menyediakan fungsi khusus untuk ini - fungsi VLOOKUP. Sebagai alternatif, Anda dapat menggunakan rumus INDEX MATCH yang lebih kuat dan serbaguna. Pengguna Excel 2021 dan Excel 365, dapat menyelesaikan tugas dengan fungsi XLOOKUP.

Misalnya, formula berikut membandingkan nama produk dalam kolom D dengan nama-nama dalam kolom A dan menarik angka penjualan yang sesuai dari kolom B jika ditemukan kecocokan, jika tidak, kesalahan #N/A akan dikembalikan.

=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)

=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))

=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)

Untuk informasi lebih lanjut, lihat Bagaimana membandingkan dua kolom menggunakan VLOOKUP.

Jika Anda merasa tidak nyaman dengan formula, Anda dapat menyelesaikan pekerjaan menggunakan solusi cepat dan intuitif - Merge Tables Wizard.

Bandingkan dua daftar dan soroti kecocokan dan perbedaannya

Saat Anda membandingkan kolom di Excel, Anda mungkin ingin "memvisualisasikan" item yang ada di satu kolom tetapi tidak ada di kolom lainnya. Anda dapat membuat bayangan sel seperti itu dalam warna apa pun yang Anda pilih dengan menggunakan fitur Pemformatan Bersyarat Excel dan contoh berikut menunjukkan langkah-langkah mendetail.

Contoh 1. Soroti kecocokan dan perbedaan di setiap baris

Untuk membandingkan dua kolom dan Excel dan menyorot sel di kolom A yang memiliki entri yang identik pada kolom B di baris yang sama, lakukan yang berikut ini:

• Pilih sel yang ingin Anda sorot (Anda dapat memilih sel dalam satu kolom atau dalam beberapa kolom jika Anda ingin mewarnai seluruh baris).
• Klik Pemformatan bersyarat> Aturan Baru.> Gunakan formula untuk menentukan sel mana yang akan diformat .
• Buat aturan dengan formula sederhana seperti =$B2=$A2 (dengan asumsi bahwa baris 2 adalah baris pertama dengan data, tidak termasuk header kolom). Harap periksa kembali apakah Anda menggunakan referensi baris relatif (tanpa tanda $) seperti pada rumus di atas.

Untuk menyoroti perbedaan antara kolom A dan B, buat aturan dengan rumus ini:

=$B2$A2

Jika Anda baru mengenal pemformatan bersyarat Excel, silakan lihat Cara membuat aturan pemformatan bersyarat berbasis rumus untuk petunjuk langkah demi langkah.

Contoh 2. Soroti entri unik dalam setiap daftar

Setiap kali Anda membandingkan dua daftar di Excel, ada 3 jenis item yang dapat Anda sorot:

• Item yang hanya ada di daftar pertama (unik)
• Item yang hanya ada dalam daftar ke-2 (unik)
• Item yang ada di kedua daftar (duplikat) - didemonstrasikan dalam contoh berikutnya.

Contoh ini mendemonstrasikan cara mewarnai item-item yang hanya ada dalam satu daftar.

Misalkan Daftar 1 Anda berada di kolom A (A2:A6) dan Daftar 2 di kolom C (C2:C5). Anda membuat aturan pemformatan bersyarat dengan rumus berikut:

Soroti nilai-nilai unik dalam Daftar 1 (kolom A):

=COUNTIF($C$2:$C$5, $A2)=0

Soroti nilai-nilai unik dalam Daftar 2 (kolom C):

=COUNTIF($A$2:$A$6, $C2)=0

Dan mendapatkan hasil sebagai berikut:

Contoh 3. Sorot kecocokan (duplikat) antara 2 kolom

Jika Anda mengikuti contoh sebelumnya dengan cermat, Anda tidak akan mengalami kesulitan menyesuaikan rumus COUNTIF sehingga mereka menemukan kecocokan daripada perbedaan. Yang harus Anda lakukan adalah mengatur hitungan lebih besar dari nol:

Sorot kecocokan dalam Daftar 1 (kolom A):

=COUNTIF($C$2:$C$5, $A2)>0

Sorot kecocokan dalam Daftar 2 (kolom C):

=COUNTIF($A$2:$A$6, $C2)>0

Soroti perbedaan baris dan kecocokan dalam beberapa kolom

Apabila membandingkan nilai dalam beberapa kolom baris demi baris, cara tercepat untuk menyoroti kecocokan adalah menciptakan aturan pemformatan bersyarat, dan cara tercepat untuk menaungi perbedaan adalah dengan menggunakan Pergi ke Khusus seperti ditunjukkan dalam contoh berikut ini.

Contoh 1. Bandingkan beberapa kolom dan sorot kecocokan baris

Untuk menyoroti baris yang memiliki nilai yang identik di semua kolom , buat aturan pemformatan bersyarat berdasarkan salah satu rumus berikut:

=AND($A2=$B2, $A2=$C2)

atau

=COUNTIF($A2:$C2, $A2)=3

Di mana A2, B2 dan C2 adalah sel paling atas dan 3 adalah jumlah kolom yang akan dibandingkan.

Tentu saja, baik rumus AND maupun COUNTIF tidak terbatas untuk membandingkan hanya 3 kolom, Anda dapat menggunakan rumus serupa untuk menyorot baris dengan nilai yang sama di 4, 5, 6 kolom atau lebih.

Contoh 2. Bandingkan beberapa kolom dan sorot perbedaan baris

Untuk menyorot sel dengan cepat dengan nilai yang berbeda di setiap baris individual, Anda bisa menggunakan Excel Pergi ke Khusus fitur.

1. Pilih rentang sel yang ingin Anda bandingkan. Dalam contoh ini, saya telah memilih sel A2 hingga C8.

   Secara default, sel paling atas dari rentang yang dipilih adalah sel aktif, dan sel dari kolom lain yang dipilih di baris yang sama akan dibandingkan dengan sel tersebut. Seperti yang dapat Anda lihat pada gambar di atas, sel aktif berwarna putih sementara semua sel lain dari rentang yang dipilih disorot. Dalam contoh ini, sel aktif adalah A2, jadi kolom perbandingan adalah kolom A.

   Untuk mengubah kolom perbandingan , gunakan tombol Tab untuk menavigasi melalui sel yang dipilih dari kiri ke kanan, atau tombol Enter untuk berpindah dari atas ke bawah.

   Tip. Untuk memilih kolom yang tidak berdekatan Pilih kolom pertama, tekan dan tahan Ctrl , lalu pilih kolom lainnya. Sel yang aktif akan berada di kolom terakhir (atau di blok terakhir dari kolom yang berdekatan). Untuk mengubah kolom perbandingan, gunakan tombol Tab atau Enter seperti yang dijelaskan di atas.

2. Pada Rumah tab, pergi ke Penyuntingan kelompok, dan klik Temukan &; Pilih > Pergi ke Special... Kemudian pilih Perbedaan baris dan klik tombol OK tombol.
3. Sel-sel yang nilainya berbeda dari sel pembanding di setiap baris diwarnai. Jika Anda ingin menaungi sel yang disorot dengan beberapa warna, cukup klik tombol Isi Warna ikon pada pita dan pilih warna yang Anda pilih.

Bagaimana membandingkan dua sel di Excel

Faktanya, membandingkan 2 sel adalah kasus khusus membandingkan dua kolom di Excel baris demi baris kecuali Anda tidak perlu menyalin rumus ke sel lain di kolom.

Misalnya, untuk membandingkan sel A1 dan C1, Anda dapat menggunakan rumus berikut.

Untuk pertandingan:

=IF(A1=C1, "Cocok", "")

Untuk perbedaan:

=IF(A1C1, "Perbedaan", "")

Untuk mempelajari beberapa cara lain untuk membandingkan sel di Excel, silakan lihat:

• Bagaimana membandingkan dua string di Excel
• Periksa apakah dua sel cocok atau beberapa sel sama

Cara bebas rumus untuk membandingkan dua kolom / daftar di Excel

Sekarang setelah Anda mengetahui penawaran Excel untuk membandingkan dan mencocokkan kolom, izinkan saya menunjukkan kepada Anda solusi kami sendiri untuk tugas ini. Alat ini diberi nama Bandingkan Dua Tabel dan disertakan dalam Suite Ultimate kami.

Add-in dapat membandingkan dua tabel atau daftar dengan sejumlah kolom dan keduanya mengidentifikasi kecocokan / perbedaan (seperti yang kami lakukan dengan rumus) dan menyorotinya (seperti yang kami lakukan dengan pemformatan bersyarat).

Untuk tujuan artikel ini, kita akan membandingkan 2 daftar berikut ini untuk menemukan nilai umum yang ada di keduanya.

Untuk membandingkan dua daftar, berikut ini langkah-langkah yang perlu Anda ikuti:

1. Mulai dengan mengklik tombol Bandingkan Tabel tombol pada Data Ablebits tab.
2. Pilih kolom/daftar pertama dan klik Berikutnya Dalam hal add-in, ini adalah Tabel 1 Anda.
3. Pilih yang kedua kolom/daftar dan klik Berikutnya Dalam hal add-in, ini adalah Tabel 2 Anda, dan dapat berada di lembar kerja yang sama atau berbeda atau bahkan di buku kerja lain.
4. Pilih jenis data apa yang akan dicari:
   • Duplikat nilai (cocok) - item-item yang ada di kedua daftar.
   • Unik nilai (perbedaan) - item-item yang ada dalam daftar 1, tetapi tidak ada dalam daftar 2.

   Karena tujuan kita adalah menemukan kecocokan, kita memilih opsi pertama dan klik Berikutnya .

5. Ini adalah langkah kunci di mana Anda memilih kolom untuk perbandingan Dalam kasus kita, pilihannya jelas karena kita hanya membandingkan 2 kolom: 2000 Pemenang terhadap Pemenang 2021 Pada tabel yang lebih besar, Anda bisa memilih beberapa pasangan kolom untuk dibandingkan.
6. Pada langkah terakhir, Anda memilih cara menangani item yang ditemukan dan klik Selesai .

   Beberapa opsi berbeda tersedia di sini. Untuk tujuan kita, dua opsi ini paling berguna:

   • Sorot dengan warna - nuansa kecocokan atau perbedaan dalam warna yang dipilih (seperti yang dilakukan pemformatan bersyarat Excel).
   • Identifikasi di kolom Status - menyisipkan Status kolom dengan label "Duplikat" atau "Unik" (seperti yang dilakukan rumus IF).

Untuk contoh ini, saya memutuskan untuk menyoroti duplikat dalam warna berikut ini:

Dan dalam sekejap, mendapatkan hasil sebagai berikut:

Dengan Status kolom, hasilnya akan terlihat sebagai berikut:

Tip. Jika daftar yang Anda bandingkan ada di lembar kerja atau buku kerja yang berbeda, mungkin akan membantu untuk melihat lembar Excel berdampingan.

Ini adalah cara Anda membandingkan kolom di Excel untuk kecocokan (duplikat) dan perbedaan (nilai unik). Jika Anda tertarik untuk mencoba alat ini, Anda dipersilakan untuk mengunduh versi evaluasi menggunakan tautan di bawah ini.

Saya berterima kasih telah membaca dan mendorong Anda untuk melihat tutorial bermanfaat lainnya yang kami miliki :)

Unduhan yang tersedia

Bandingkan Daftar Excel - contoh (file .xlsx)

Ultimate Suite - versi percobaan (file .exe)