Tutorial ini menjelaskan cara menggunakan fungsi MATCH di Excel dengan contoh rumus. Ini juga menunjukkan cara meningkatkan rumus pencarian Anda dengan membuat rumus dinamis dengan VLOOKUP dan MATCH.

Di Microsoft Excel, ada banyak fungsi pencarian / referensi berbeda yang dapat membantu Anda menemukan nilai tertentu dalam rentang sel, dan MATCH adalah salah satunya. Pada dasarnya, ini mengidentifikasi posisi relatif item dalam rentang sel. Namun, fungsi MATCH dapat melakukan lebih dari esensi murni.

Fungsi Excel MATCH - sintaks dan penggunaan

Fungsi MATCH di Excel mencari nilai tertentu dalam rentang sel, dan mengembalikan posisi relatif dari nilai tersebut.

Sintaks untuk fungsi MATCH adalah sebagai berikut:

Lookup_value (wajib) - nilai yang ingin Anda temukan. Ini bisa berupa nilai numerik, teks atau logika serta referensi sel.

Lookup_array (wajib) - rentang sel yang akan dicari.

Match_type (opsional) - mendefinisikan tipe kecocokan. Ini bisa menjadi salah satu dari nilai-nilai ini: 1, 0, -1. Argumen match_type yang disetel ke 0 hanya mengembalikan kecocokan yang tepat, sementara dua jenis lainnya memungkinkan untuk perkiraan kecocokan.

• 1 atau dihilangkan (default) - temukan nilai terbesar dalam larik pencarian yang kurang dari atau sama dengan nilai pencarian. Memerlukan pengurutan larik pencarian dalam urutan menaik, dari yang terkecil ke yang terbesar atau dari A ke Z.
• 0 - menemukan nilai pertama dalam larik yang persis sama ke nilai pencarian. Tidak diperlukan penyortiran.
• -1 - temukan nilai terkecil dalam larik yang lebih besar atau sama dengan nilai pencarian. Larik pencarian harus diurutkan dalam urutan menurun, dari yang terbesar ke terkecil atau dari Z ke A.

Untuk lebih memahami fungsi MATCH, mari kita buat rumus sederhana berdasarkan data ini: nama siswa di kolom A dan nilai ujian mereka di kolom B, diurutkan dari yang terbesar ke terkecil. Untuk mengetahui di mana siswa tertentu (katakanlah, Laura ) berdiri di antara yang lainnya, menggunakan rumus sederhana ini:

=MATCH("Laura", A2:A8, 0)

Secara opsional, kamu bisa menaruh nilai pencariannya di suatu cell (E1 dalam contoh ini) dan mereferensikan cell tersebut dalam rumus Excel Match-mu:

=MATCH(E1, A2:A8, 0)

Seperti yang Anda lihat pada screenshot di atas, nama-nama siswa dimasukkan dalam urutan sembarang, dan oleh karena itu kami menetapkan match_type argumen ke 0 (pencocokan tepat), karena hanya jenis pencocokan ini yang tidak memerlukan pengurutan nilai dalam larik pencarian. Secara teknis, rumus Pencocokan mengembalikan posisi relatif Laura dalam rentang. Tetapi karena nilainya diurutkan dari yang terbesar ke terkecil, ini juga memberi tahu kita bahwa Laura memiliki nilai terbaik ke-5 di antara semua siswa.

Tip. Di Excel 365 dan Excel 2021, Anda dapat menggunakan fungsi XMATCH, yang merupakan penerus MATCH yang modern dan lebih kuat.

4 hal yang harus Anda ketahui tentang fungsi MATCH

Seperti yang baru saja Anda lihat, menggunakan MATCH di Excel itu mudah. Namun, seperti halnya dengan hampir semua fungsi lainnya, ada beberapa kekhususan yang harus Anda ketahui:

1. Fungsi MATCH mengembalikan posisi relatif dari nilai pencarian dalam larik, bukan nilai itu sendiri.
2. MATCH adalah tidak peka huruf besar-kecil , yang berarti tidak membedakan antara karakter huruf kecil dan huruf besar ketika berhadapan dengan nilai teks.
3. Jika larik pencarian berisi beberapa kemunculan nilai pencarian, posisi nilai pertama dikembalikan.
4. Jika nilai pencarian tidak ditemukan dalam array pencarian, kesalahan #N/A dikembalikan.

Cara menggunakan MATCH di Excel - contoh rumus

Sekarang setelah kamu mengetahui penggunaan dasar dari fungsi MATCH Excel, mari kita bahas beberapa contoh rumus lainnya yang lebih dari sekedar dasar-dasarnya.

Kecocokan parsial dengan wildcard

Seperti banyak fungsi lainnya, MATCH memahami karakter wildcard berikut ini:

• Tanda tanya (?) - menggantikan karakter tunggal apa pun
• Asterisk (*) - menggantikan urutan karakter apa pun

Catatan. Wildcard hanya bisa digunakan dalam rumus Match dengan match_type diatur ke 0.

Formula Match dengan wildcard berguna dalam situasi ketika Anda ingin mencocokkan bukan seluruh string teks, tetapi hanya beberapa karakter atau beberapa bagian dari string. Untuk mengilustrasikan intinya, pertimbangkan contoh berikut.

Misalkan Anda memiliki daftar pengecer regional dan angka penjualan mereka selama sebulan terakhir. Anda ingin menemukan posisi relatif dari pengecer tertentu dalam daftar (diurutkan berdasarkan jumlah penjualan dalam urutan menurun) tetapi Anda tidak dapat mengingat namanya dengan tepat, meskipun Anda ingat beberapa karakter pertama.

Dengan mengasumsikan nama pengecer berada dalam kisaran A2:A11, dan Anda mencari nama yang diawali dengan "car", rumusnya adalah sebagai berikut:

=MATCH("car*", A2:A11,0)

Untuk membuat rumus Pencocokan kita lebih serbaguna, Anda dapat mengetikkan nilai pencarian di beberapa sel (E1 dalam contoh ini), dan menggabungkan sel itu dengan karakter wildcard, seperti ini:

=MATCH(E1& "*", A2:A11,0)

Seperti yang ditunjukkan pada gambar di bawah, rumus mengembalikan 2, yang merupakan posisi "Carter":

Untuk mengganti hanya satu karakter dalam nilai pencarian, gunakan operator wildcard "?", seperti ini:

=MATCH("ba?er", A2:A11,0)

Rumus di atas akan cocok dengan nama " Baker " dan menjalankan kembali posisi relatifnya, yaitu 5.

Rumus MATCH yang peka huruf besar-kecil

Seperti yang disebutkan di awal tutorial ini, fungsi MATCH tidak membedakan karakter huruf besar dan huruf kecil. Untuk membuat rumus Pencocokan yang peka huruf besar-kecil, gunakan MATCH yang dikombinasikan dengan fungsi EXACT yang membandingkan sel dengan tepat, termasuk kasus karakter.

Berikut rumus umum case-sensitive untuk mencocokkan data:

Rumus ini bekerja dengan logika berikut:

• Fungsi EXACT membandingkan nilai pencarian dengan setiap elemen dari array pencarian. Jika sel yang dibandingkan persis sama, fungsi mengembalikan TRUE, FALSE jika tidak.
• Dan kemudian, fungsi MATCH membandingkan TRUE (yang merupakan fungsi lookup_value ) dengan setiap nilai dalam larik yang dikembalikan oleh EXACT, dan mengembalikan posisi kecocokan pertama.

Harap diingat bahwa ini adalah rumus array yang membutuhkan penekanan Ctrl + Shift + Enter untuk diselesaikan dengan benar.

Dengan mengasumsikan nilai pencarian Anda berada di sel E1 dan larik pencariannya adalah A2:A9, rumusnya adalah sebagai berikut:

=MATCH(TRUE, EXACT(A2:A9,E1),0)

Tangkapan layar berikut menunjukkan rumus Pencocokan peka huruf besar-kecil di Excel:

Bandingkan 2 kolom untuk kecocokan dan perbedaan (ISNA MATCH)

Memeriksa dua daftar untuk kecocokan dan perbedaan adalah salah satu tugas paling umum di Excel, dan itu dapat dilakukan dengan berbagai cara. Rumus ISNA/MATCH adalah salah satunya:

Untuk nilai apapun dari Daftar 2 yang tidak ada dalam Daftar 1, rumus mengembalikan " Tidak dalam Daftar 1 ". Dan begini caranya:

• Fungsi MATCH mencari nilai dari Daftar 1 dalam Daftar 2. Jika nilai ditemukan, ia mengembalikan posisi relatifnya, # N / A kesalahan jika tidak.
• Fungsi ISNA di Excel hanya melakukan satu hal - memeriksa kesalahan # N / A (artinya "tidak tersedia"). Jika nilai yang diberikan adalah kesalahan # N / A, fungsi mengembalikan TRUE, jika tidak, SALAH. Dalam kasus kami, TRUE berarti bahwa nilai dari Daftar 1 tidak ditemukan dalam Daftar 2 (yaitu kesalahan # N / A dikembalikan oleh MATCH).
• Karena mungkin sangat membingungkan bagi pengguna Anda untuk melihat TRUE untuk nilai yang tidak muncul dalam Daftar 1, Anda membungkus fungsi IF di sekitar ISNA untuk menampilkan " Tidak dalam Daftar 1 " sebagai gantinya, atau teks apa pun yang Anda inginkan.

Misalnya, untuk membandingkan nilai dalam kolom B terhadap nilai dalam kolom A, rumusnya mengambil bentuk berikut (di mana B2 adalah sel paling atas):

=IF(ISNA(MATCH(B2,A:A,0)), "Tidak dalam Daftar 1", "")

Seperti yang Anda ingat, fungsi MATCH di Excel tidak peka huruf besar-kecil dengan sendirinya. Untuk membuatnya membedakan kasus karakter, sematkan fungsi EXACT di lookup_array argumen, dan ingat untuk menekan Ctrl + Shift + Enter untuk menyelesaikan ini rumus larik :

=IF(ISNA(MATCH(TRUE, EXACT(A:A, B2),0)), "Tidak dalam Daftar 1", "")

Tangkapan layar berikut ini menunjukkan kedua rumus yang sedang beraksi:

Untuk mempelajari cara lain untuk membandingkan dua daftar di Excel, silakan lihat tutorial berikut: Cara membandingkan 2 kolom di Excel.

Excel VLOOKUP dan MATCH

Contoh ini mengasumsikan kamu sudah memiliki pengetahuan dasar mengenai fungsi Excel VLOOKUP. Dan jika kamu sudah memilikinya, kemungkinan besar kamu sudah mengalami berbagai keterbatasannya (gambaran detailnya bisa kamu lihat di Mengapa Excel VLOOKUP tidak bekerja) dan sedang mencari alternatif yang lebih kuat.

Salah satu kelemahan VLOOKUP yang paling menjengkelkan adalah bahwa VLOOKUP berhenti bekerja setelah menyisipkan atau menghapus kolom dalam tabel pencarian. Ini terjadi karena VLOOKUP menarik nilai yang cocok berdasarkan nomor kolom pengembalian yang Anda tentukan (nomor indeks). nomor indeks "hard-coded" dalam formula, Excel tidak dapat menyesuaikannya ketika kolom baru ditambahkan atau dihapus dari tabel.

Fungsi Excel MATCH berurusan dengan posisi relatif dari nilai pencarian, yang membuatnya sangat cocok untuk col_index_num Dengan kata lain, alih-alih menentukan kolom yang dikembalikan sebagai angka statis, Anda menggunakan MATCH untuk mendapatkan posisi saat ini dari kolom itu.

Untuk membuat segalanya lebih mudah dipahami, mari kita gunakan tabel dengan nilai ujian siswa lagi (mirip dengan yang kita gunakan di awal tutorial ini), tetapi kali ini kita akan mengambil nilai sebenarnya dan bukan posisi relatifnya.

Dengan asumsi nilai pencarian ada di sel F1, larik tabelnya adalah $ A $ 1: $ C $ 2 (ini adalah praktik yang baik untuk menguncinya menggunakan referensi sel absolut jika Anda berencana menyalin rumus ke sel lain), rumusnya adalah sebagai berikut:

=VLOOKUP(F1, $A$1:$C$8, 3, FALSE)

Argumen ke-3 ( col_index_num ) ditetapkan ke 3 karena Nilai Matematika yang ingin kita tarik adalah kolom ke-3 dalam tabel. Seperti yang Anda lihat pada gambar di bawah, rumus Vlookup biasa ini berfungsi dengan baik:

Tetapi hanya sampai Anda menyisipkan atau menghapus kolom:

Jadi, mengapa #REF! error? Karena col_index_num diatur ke 3 memberitahu Excel untuk mendapatkan nilai dari kolom ketiga, sedangkan sekarang hanya ada 2 kolom dalam array tabel.

Untuk mencegah hal-hal seperti itu terjadi, Anda dapat membuat rumus Vlookup Anda lebih dinamis dengan menyertakan fungsi Match berikut:

COCOKKAN (E2, A1: C1, 0)

Di mana:

• E2 adalah nilai pencarian, yaitu persis sama ke nama kolom return, yaitu kolom dari mana Anda ingin menarik nilai ( Nilai Matematika dalam contoh ini).
• A1:C1 adalah larik pencarian yang berisi tajuk tabel.

Dan sekarang, sertakan fungsi Match ini dalam col_index_num argumen rumus Vlookup Anda, seperti ini:

=VLOOKUP(F1,$A$1:$C$8, MATCH(E2,$A$1:$C$1, 0), FALSE)

Dan pastikan ini bekerja tanpa cela, berapa pun banyaknya kolom yang Anda tambahkan atau hapus:

Pada tangkapan layar di atas, saya mengunci semua referensi sel agar rumusnya berfungsi dengan benar meskipun pengguna saya memindahkannya ke tempat lain di lembar kerja. Seperti yang Anda lihat pada gambar di bawah ini, rumusnya berfungsi dengan baik setelah menghapus kolom; selain itu Excel cukup pintar untuk menyesuaikan referensi absolut dengan benar dalam kasus ini:

Excel HLOOKUP dan MATCH

Dengan cara yang sama, Anda dapat menggunakan fungsi MATCH Excel untuk meningkatkan rumus HLOOKUP Anda. Prinsip umumnya pada dasarnya sama seperti dalam kasus Vlookup: Anda menggunakan fungsi Match untuk mendapatkan posisi relatif dari kolom kembali, dan memasok nomor itu ke row_index_num argumen rumus Hlookup Anda.

Misalkan nilai pencarian ada di sel B5, larik tabel adalah B1: H3, nama baris kembalinya (nilai pencarian untuk MATCH) ada di sel A6 dan tajuk baris adalah A1: A3, rumus lengkapnya adalah sebagai berikut:

=HLOOKUP(B5, B1:H3, MATCH(A6, A1:A3, 0), FALSE)

Seperti yang baru saja Anda lihat, kombinasi Hlookup/Vlookup & Match tentu saja merupakan peningkatan dari rumus Hlookup dan Vlookup biasa. Namun, fungsi MATCH tidak menghilangkan semua keterbatasannya. Secara khusus, rumus Vlookup Match masih tidak dapat melihat di sebelah kirinya, dan Hlookup Match gagal mencari di baris mana pun selain yang paling atas.

Untuk mengatasi keterbatasan di atas (dan beberapa lainnya), pertimbangkan untuk menggunakan kombinasi INDEX MATCH, yang menyediakan cara yang sangat kuat dan serbaguna untuk melakukan pencarian di Excel, lebih unggul dari Vlookup dan Hlookup dalam banyak hal. Panduan terperinci dan contoh rumus dapat ditemukan di INDEX &; MATCH di Excel - alternatif yang lebih baik untuk VLOOKUP.

Semoga contoh-contoh yang dibahas dalam tutorial ini akan terbukti bermanfaat dalam pekerjaan Anda. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Buku kerja latihan untuk diunduh

Contoh rumus Excel MATCH (file .xlsx)