Opplæringen forklarer hvordan du fjerner mellomrom i Excel ved hjelp av formler og tekstverktøyet. Du vil lære hvordan du sletter innledende og etterfølgende mellomrom i en celle, eliminerer ekstra mellomrom mellom ord, kvitter seg med ikke-brytende mellomrom og tegn som ikke skrives ut.

Hva er det største problemet med mellomrom? De er ofte usynlige for det menneskelige øyet. En oppmerksom bruker kan av og til fange et ledende mellomrom som gjemmer seg foran teksten eller noen ekstra mellomrom mellom ordene. Men det er ingen måte å oppdage etterfølgende mellomrom, de som holder seg ute av syne ved enden av cellene.

Det ville ikke vært et stort problem hvis ekstra mellomrom bare lå rundt, men de ødelegger formler. Poenget er at to celler som inneholder samme tekst med og uten mellomrom, selv om det er så lite som et enkelt mellomromstegn, anses som forskjellige verdier. Så det kan hende du prøver å finne ut hvorfor en åpenbart korrekt formel ikke kan matche to tilsynelatende identiske oppføringer.

Nå som du er fullstendig klar over problemet, er det på tide å jobbe ut en løsning. Det er flere måter å fjerne mellomrom fra strenger på, og denne opplæringen vil hjelpe deg å velge den teknikken som passer best for din spesifikke oppgave og datatypen du jobber med.

Hvordan fjerne blanke mellomrom i Excel - førende, etterfølgende, mellom ord

Hvis datasettet ditt inneholder overflødige mellomrom, vil ExcelTRIM-funksjonen kan hjelpe deg med å slette dem alle på én gang – førende, etterfølgende og flere mellomrom, bortsett fra et enkelt mellomrom mellom ordene.

En vanlig TRIM-formel er så enkel som denne:

=TRIM(A2)

Hvor A2 er cellen du vil slette mellomrom fra.

Som vist på følgende skjermbilde, eliminerte Excel TRIM-formelen også alle mellomrom før og etter teksten som påfølgende mellomrom i midten av en streng.

Og nå trenger du bare å erstatte verdier i den opprinnelige kolonnen med trimmede verdier. Den enkleste måten å gjøre dette på er å bruke Lim inn spesielle > verdier , de detaljerte instruksjonene finner du her: Slik kopierer du verdier i Excel.

I tillegg kan du kan bruke Excel TRIM-funksjonen til å fjerne bare ledende mellomrom , og holde alle mellomrom i midten av en tekststreng intakt. Formeleksemplet er her: Hvordan trimme innledende mellomrom i Excel (Venstre trim).

Hvordan slette linjeskift og tegn som ikke skrives ut

Når du importerer data fra eksterne kilder, er det ikke bare ekstra mellomrom som følger med, men også forskjellige tegn som ikke skrives ut, som vognretur, linjeskift, vertikal eller horisontal tabulator osv.

TRIM-funksjonen kan kvitte seg med mellomrom, men den kan ikke eliminere tegn som ikke skrives ut . Teknisk sett er Excel TRIM designet for å bare slette verdi 32 i 7-bit ASCII-systemet, som er plassentegn.

For å fjerne mellomrom og tegn som ikke skrives ut i en streng, bruk TRIM i kombinasjon med CLEAN-funksjonen. Som navnene antyder, er CLEAN beregnet på å rense data, og den kan slette alle de første 32 ikke-utskriftstegnene i 7-bits ASCII-settet (verdier 0 til 31) inkludert linjeskift ( verdi 10).

Forutsatt at dataene som skal renses er i celle A2, er formelen som følger:

=TRIM(CLEAN(A2))

Hvis Trim/ Ren formel kombinerer innholdet i flere linjer uten mellomrom, du kan fikse det ved å bruke en av disse teknikkene:

• Bruk "Erstatt alle"-funksjonen i Excel: i "Finn hva"-boksen, skriv inn en vognretur ved å trykke på Ctrl+J snarveien; og i "Erstatt med"-boksen skriver du inn et mellomrom. Ved å klikke på Erstatt alle -knappen vil alle linjeskift i det valgte området byttes ut med mellomrom.
• Bruk følgende formel for å erstatte vognretur (verdi 13) og linjeskift (verdi 10) med tegn mellomrom:

  =SUBSTITUTE(SUBSTITUTE(A2, CHAR(13)," "), CHAR(10), " ")

For mer informasjon, se Hvordan fjerne vognretur (linjeskift) i Excel.

Hvordan fjerne ikke-brytende mellomrom i Excel

Hvis etter bruk av TRIM & CLEAN formel noen gjenstridige mellomrom er fortsatt der, mest sannsynlig har du kopiert/limt inn dataene fra et sted og noen få ikke-brytende mellomrom sniket seg inn.

For å bli kvitt ubrytende mellomrom (html-tegn ), erstatte dem med vanligemellomrom, og få TRIM-funksjonen til å fjerne dem:

=TRIM(SUBSTITUTE(A2, CHAR(160), " "))

For bedre å forstå logikken, la oss bryte ned formelen:

• En ikke-brytende karakter har verdi 160 i 7-bits ASCII-systemet, så du kan definere den ved å bruke CHAR(160)-formelen.
• ERSTATNING-funksjonen brukes til å gjøre ikke-avbrytende mellomrom til vanlige mellomrom.
• Og til slutt legger du inn SUBSTITUTE-setningen i TRIM-funksjonen for å fjerne de konverterte mellomrommene.

Hvis regnearket ditt også inneholder tegn som ikke skrives ut, bruk CLEAN-funksjonen sammen med TRIM og SUBSTITUTE for å få kvitt mellomrom og uønskede symboler med ett slag:

=TRIM(CLEAN((SUBSTITUTE(A2,CHAR(160)," "))))

Følgende skjermbilde viser forskjellen:

Hvordan slette en spesifikk ikke- skrive ut tegn

Hvis forbindelsen mellom 3 funksjoner omtalt i eksemplet ovenfor (TRIM, CLEAN og SUBSTITUTE) ikke var i stand til å eliminere mellomrom eller tegn som ikke skrives ut i arket, betyr det at disse tegnene har andre ASCII-verdier enn 0 til 3 2 (tegn som ikke skrives ut) eller 160 (ikke-brytende mellomrom).

I dette tilfellet bruker du CODE-funksjonen for å identifisere tegnverdien, og bruk deretter SUBSTITUTE for å erstatte den med et vanlig mellomrom og TRIM for å fjern mellomrommet.

Forutsatt at mellomrommene eller andre uønskede tegn som du ønsker å bli kvitt ligger i celle A2, skriver du 2 formler:

1. I celle B2, oppdage problematikkentegnverdi ved å bruke en av følgende CODE-funksjoner:
   • Innledende mellomrom eller tegn som ikke skrives ut i begynnelsen av strengen:

     =CODE(LEFT(A2,1))

   • Etterste mellomrom eller ikke-utskrift tegn på slutten av strengen:

     =CODE(RIGHT(A2,1))

   • Mellomrom eller tegn som ikke skrives ut i midten av strengen, der n er posisjonen til det problematiske tegnet:

     =CODE(MID(A2, n , 1)))

   I dette eksemplet har vi et ukjent ikke-utskriftstegn midt i teksten, i fjerde posisjon, og vi finner ut verdien med denne formelen:

   =CODE(MID(A2,4,1))

   KODE-funksjonen returnerer verdi 127 (se skjermbildet nedenfor).

2. I celle C2 erstatter du CHAR(127) med et vanlig mellomrom (" "), og trimmer deretter dette mellomrommet:

   =TRIM(SUBSTITUTE(A2, CHAR(127), " "))

Resultatet skal se noe lignende ut:

Hvis dataene dine inneholder noen få forskjellige tegn som ikke skrives ut, så vel som ikke-brytende mellomrom, kan du neste to eller flere SUBSTITUTE-funksjoner for å fjerne alle uønskede tegnkoder om gangen:

=TRIM(SUBSTITUTE(SUBSTITUTE(A2, CHAR(127), " "), CHAR(160), " ")))

Hvordan fjerne alle mellomrom i Excel

I noen situasjoner vil du kanskje fjerne absolutt alle mellomrom i en celle, inkludert enkeltrom mellom ord eller tall. For eksempel når du har importert en numerisk kolonne der mellomrom brukes som tusenskilletegn, noe som gjør det lettere å lese store tall, men hindrer formlene dine i å beregne.

For å slette alle mellomrompå én gang, bruk SUBSTITUTE som forklart i forrige eksempel, med den eneste forskjellen at du erstatter mellomromstegnet returnert av CHAR(32) med ingenting (""):

=SUBSTITUTE(A2, CHAR(32), "")

Eller , kan du ganske enkelt skrive mellomrommet (" ") i formelen, slik:

=SUBSTITUTE(A2," ","")

Deretter erstatter du formler med verdier, og tallene dine vil beregnes riktig .

Hvordan telle mellomrom i Excel

Før du fjerner mellomrom fra en bestemt celle, kan du være nysgjerrig på å vite hvor mange av dem som faktisk er der.

For å få totalt antall mellomrom i en celle, gjør følgende:

• Regn ut hele strenglengden ved å bruke LEN-funksjonen: LEN(A2)
• Erstatt alle mellomrom med ingenting: SUBSTITUTE(A2) ," ","")
• Beregn lengden på strengen uten mellomrom: LEN(SUBSTITUTE(A2," ",""))
• Strekk fra den "mellomromsfrie" strenglengden fra den totale lengden.

Forutsatt at den opprinnelige tekststrengen er i celle A2, går hele formelen som følger:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))

For å finne ut hvor mange ekst ra-mellomrom er i cellen, få tekstlengden uten ekstra mellomrom, og trekk den fra den totale strenglengden:

=LEN(A2)-LEN(TRIM(A2))

Følgende skjermbilde viser begge formlene i aksjon:

Nå som du vet hvor mange mellomrom hver celle inneholder, kan du trygt slette ekstra mellomrom ved hjelp av TRIM-formelen.

Formelfri måte å fjerne mellomrom og rense data på

Som du alleredevet, mange ekstra mellomrom og andre uvelkomne karakterer kan lure ubemerket i arkene dine, spesielt hvis du importerer data fra eksterne kilder. Du vet også hvordan du sletter mellomrom i Excel med en formel. Selvfølgelig er det en god øvelse å lære seg en håndfull formler for å skjerpe ferdighetene dine, men det kan være tidkrevende.

Excel-brukere som setter pris på tiden sin og setter pris på bekvemmelighet, kan dra nytte av tekstverktøyene som følger med vår Ultimate Suite for Excel. Et av disse praktiske verktøyene lar deg fjerne mellomrom og tegn som ikke skrives ut med et knappeklikk.

Når den er installert, legger Ultimate Suite til flere nyttige knapper til Excel-båndet ditt, for eksempel Trim mellomrom , Fjern tegn , Konverter tekst , Slett formatering og noen flere.

Når du vil fjerne tomme mellomrom i Excel-arkene dine, utfør disse 4 raske trinnene:

1. Velg cellene (område, hele kolonnen eller raden) der du vil slette ekstra mellomrom.
2. Klikk Trim Mellomrom -knappen på Ablebits Data -fanen.
3. Velg ett eller flere alternativer:
   • Fjern ledende og etterfølgende mellomrom
   • Klipp ekstra mellomrom mellom ord til ett
   • Slett ikke-avbrytende mellomrom ( )
4. Klikk på Trim -knappen.

Ferdig! Alle ekstra mellomrom slettes med et enkelt klikk.

Slik kan du raskt fjerne mellomromi Excel-celler. Hvis du er nysgjerrig på å utforske andre funksjoner, er du hjertelig velkommen til å laste ned en evalueringsversjon av Ultimate Suite. Jeg takker for at du leser og ser frem til å se deg på bloggen vår neste uke!