Udhëzuesi shpjegon se si të hiqni hapësirat boshe në Excel duke përdorur formulat dhe mjetin Text Toolkit. Do të mësoni se si të fshini hapësirat kryesore dhe pasuese në një qelizë, të eliminoni hapësirat shtesë midis fjalëve, të hiqni qafe hapësirën e bardhë që nuk thyhet dhe karakteret që nuk shtypen.

Cili është problemi më i madh me hapësirat? Ato shpesh janë të padukshme për syrin e njeriut. Një përdorues i vëmendshëm herë pas here mund të kapë një hapësirë ​​kryesore të fshehur përpara tekstit ose disa hapësira shtesë midis fjalëve. Por nuk ka asnjë mënyrë për të dalluar hapësirat pasuese, ato që nuk shihen në fund të qelizave.

Nuk do të ishte shumë problem nëse hapësirat shtesë do të ishin të shtrira përreth, por ato ngatërrojnë formulat. Çështja është se dy qeliza që përmbajnë të njëjtin tekst me dhe pa hapësira, edhe nëse është sa një karakter i vetëm hapësinor, konsiderohen vlera të ndryshme. Pra, mund të jeni duke e trazuar trurin tuaj duke u përpjekur të kuptoni pse një formulë dukshëm e saktë nuk mund të përputhet me dy hyrje në dukje identike.

Tani që jeni plotësisht të vetëdijshëm për problemin, është koha për të punuar nxjerr një zgjidhje. Ka disa mënyra për të hequr hapësirat nga vargu, dhe ky tutorial do t'ju ndihmojë të zgjidhni teknikën më të përshtatshme për detyrën tuaj të veçantë dhe llojin e të dhënave me të cilin po punoni.

Si të hiqni boshllëqet hapësirat në Excel - kryesore, pasuese, ndërmjet fjalëve

Nëse grupi juaj i të dhënave përmban hapësira të tepërta, ExcelFunksioni TRIM mund t'ju ndihmojë t'i fshini të gjitha në të njëjtën kohë - hapësira kryesore, pasuese dhe të shumta ndërmjet tyre, përveç një karakteri të vetëm hapësinor midis fjalëve.

Një formulë e rregullt TRIM është kaq e thjeshtë sa kjo:

=TRIM(A2)

Ku A2 është qeliza nga e cila dëshironi të fshini hapësirat.

Siç tregohet në pamjen e mëposhtme të ekranit, formula Excel TRIM eliminoi me sukses të gjitha hapësirat para dhe pas tekstit gjithashtu si hapësira të njëpasnjëshme në mes të një vargu.

Dhe tani, ju duhet vetëm të zëvendësoni vlerat në kolonën origjinale me vlera të shkurtuara. Mënyra më e lehtë për ta bërë këtë është përdorimi i Paste Special > Vlerat , udhëzimet e detajuara mund të gjenden këtu: Si të kopjoni vlerat në Excel.

Për më tepër, ju mund të përdorë funksionin Excel TRIM për të hequr vetëm hapësirat kryesore , duke i mbajtur të paprekura të gjitha hapësirat në mes të një vargu teksti. Shembulli i formulës është këtu: Si të shkurtoni hapësirat kryesore në Excel (Trima majtas).

Si të fshini ndërprerjet e rreshtave dhe karakteret joprintuese

Kur importoni të dhëna nga burime të jashtme, nuk janë vetëm shtesë hapësirat që vijnë, por edhe karaktere të ndryshme që nuk printohen si kthimi i karrocës, furnizimi i linjës, skeda vertikale ose horizontale, etj.

Funksioni TRIM mund të heqë qafe hapësirat e bardha, por nuk mund të eliminojë karakteret që nuk printohen . Teknikisht, Excel TRIM është krijuar për të fshirë vetëm vlerën 32 në sistemin ASCII 7-bit, që është hapësirakarakter.

Për të hequr hapësirat dhe karakteret që nuk printohen në një varg, përdorni TRIM në kombinim me funksionin CLEAN. Siç sugjerojnë emrat e tij, CLEAN ka për qëllim pastrimin e të dhënave dhe mund të fshijë të gjitha 32 karakteret e para që nuk printohen në grupin ASCII 7-bit (vlerat 0 deri në 31) duke përfshirë ndërprerjen e linjës ( vlera 10).

Duke supozuar se të dhënat që do të pastrohen janë në qelizën A2, formula është si më poshtë:

=TRIM(CLEAN(A2))

Nëse shkurtimi/ Formula e pastër bashkon përmbajtjen e shumë rreshtave pa hapësira, mund ta rregulloni duke përdorur një nga këto teknika:

• Përdorni veçorinë "Zëvendësoni të gjitha" të Excel: në kutinë "Gjej çfarë", futni një kthim me karrocë duke shtypur shkurtoren Ctrl+J; dhe në kutinë "Zëvendëso me", shkruani një hapësirë. Klikimi i butonit Zëvendëso të gjitha do të ndërrojë të gjitha ndërprerjet e linjës në intervalin e zgjedhur me hapësira.
• Përdor formulën e mëposhtme për të zëvendësuar karakteret Carriage Return (vlera 13) dhe Line Feed (vlera 10) me hapësira:

  =SUBSTITUTE(SUBSTITUTE(A2, CHAR(13)," "), CHAR(10), " ")

Për më shumë informacion, ju lutemi shikoni Si të hiqni kthimet e transportit (ndërprerjet e linjës) në Excel.

Si të hiqni hapësirat që nuk prishen në Excel

Nëse pas përdorimit të TRIM & Formula e PASTËR disa hapësira kokëfortë janë ende atje, ka shumë të ngjarë që ju i keni kopjuar/ngjitur të dhënat nga diku dhe disa hapësira që nuk prishen.

Për të hequr qafe hapësirat që nuk prishen (karakteri html ), zëvendësojini ato me të rregulltahapësirat, dhe më pas bëni funksionin TRIM t'i heqë ato:

=TRIM(SUBSTITUTE(A2, CHAR(160), " "))

Për të kuptuar më mirë logjikën, le të zbërthejmë formulën:

• Një karakter që nuk prishet ka vlerën 160 në sistemin ASCII 7-bitësh, kështu që mund ta përcaktoni duke përdorur formulën CHAR(160).
• Funksioni SUBSTITUTE përdoret për të kthyer hapësirat pa ndërprerje në hapësira të rregullta.
• 13>Dhe së fundi, ju futni deklaratën SUBSTITUTE në funksionin TRIM për të hequr hapësirat e konvertuara.

Nëse fleta juaj e punës përmban gjithashtu karaktere që nuk printohen, përdorni funksionin CLEAN së bashku me TRIM dhe SUBSTITUTE për të marrë heqja e hapësirave dhe simboleve të padëshiruara me një goditje:

=TRIM(CLEAN((SUBSTITUTE(A2,CHAR(160)," "))))

Pamja e mëposhtme e ekranit tregon ndryshimin:

Si të fshini një jo-specifike printing karakter

Nëse ndërlidhja e 3 funksioneve të diskutuara në shembullin e mësipërm (TRIM, CLEAN dhe SUBSTITUTE) nuk ishte në gjendje të eliminonte hapësirat ose karakteret që nuk shtypeshin në fletën tuaj, kjo do të thotë se ato karaktere kanë vlera ASCII të ndryshme nga 0 deri 3 2 (karaktere që nuk shtypen) ose 160 (hapësirë ​​që nuk prishet).

Në këtë rast, përdorni funksionin CODE për të identifikuar vlerën e karakterit dhe më pas përdorni SUBSTITUTE për ta zëvendësuar atë me një hapësirë ​​të rregullt dhe TRIM në hiqni hapësirën.

Duke supozuar se hapësirat ose karakteret e tjera të padëshirueshme nga të cilat dëshironi të hiqni qëndrojnë në qelizën A2, ju shkruani 2 formula:

1. Në qelizën B2, zbuloni probleminvlerën e karakterit duke përdorur një nga funksionet e mëposhtme CODE:
   • Hapësira kryesore ose karakteri jo-printues në fillim të vargut:

     =CODE(LEFT(A2,1))

   • Hapësirë ​​pasuese ose jo printim karakteri në fund të vargut:

     =CODE(RIGHT(A2,1))

   • Hapësirë ​​ose karakter pa shtypje në mes të vargut, ku n është pozicioni i karakterit problematik:

     =CODE(MID(A2, n , 1)))

   Në këtë shembull, ne kemi një karakter të panjohur jo-printues në mes të tekstit, në pozicionin e 4-të, dhe e zbulojmë vlerën e tij me këtë formulë:

   =CODE(MID(A2,4,1))

   Funksioni CODE kthen vlerën 127 (ju lutemi shikoni pamjen e ekranit më poshtë).

2. Në qelizën C2, ju zëvendësoni CHAR(127) me një hapësirë ​​të rregullt (" ") dhe më pas shkurtoni atë hapësirë:

   =TRIM(SUBSTITUTE(A2, CHAR(127), " "))

Rezultati duhet të duket diçka e ngjashme me këtë:

Nëse të dhënat tuaja përmbajnë disa karaktere të ndryshme që nuk shtypen, si dhe hapësira që nuk prishen, mund të vendosni dy ose më shumë funksione SUBSTITUTE për t'i hequr të gjithë kodet e karaktereve të padëshiruara në të njëjtën kohë:

=TRIM(SUBSTITUTE(SUBSTITUTE(A2, CHAR(127), " "), CHAR(160), " ")))

Si të hiqni të gjitha hapësirat në Excel

Në disa situata, mund të dëshironi të hiqni absolutisht të gjitha hapësirat e bardha në një qelizë, duke përfshirë hapësirat e vetme midis fjalëve ose numrave. Për shembull, kur keni importuar një kolonë numerike ku hapësirat përdoren si ndarës të mijërave, gjë që e bën më të lehtë leximin e numrave të mëdhenj, por parandalon llogaritjen e formulave tuaja.

Për të fshirë të gjitha hapësiratme një lëvizje, përdorni SUBSTITUTE siç shpjegohet në shembullin e mëparshëm, me ndryshimin e vetëm që ju zëvendësoni karakterin e hapësirës të kthyer nga CHAR(32) me asgjë (""):

=SUBSTITUTE(A2, CHAR(32), "")

Ose , thjesht mund të shkruani hapësirën (" ") në formulë, si kjo:

=SUBSTITUTE(A2," ","")

Pas kësaj, zëvendësoni formulat me vlera dhe numrat tuaj do të llogariten siç duhet .

Si të numëroni hapësirat në Excel

Para se të hiqni hapësirat nga një qelizë e caktuar, mund të jeni kurioz të dini se sa prej tyre janë në të vërtetë atje.

Për të marrë numri total i hapësirave në një qelizë, bëni si më poshtë:

• Llogaritni të gjithë gjatësinë e vargut duke përdorur funksionin LEN: LEN(A2)
• Zëvendësoni të gjitha hapësirat me asgjë: SUBSTITUTE(A2 ," ","")
• Llogaritni gjatësinë e vargut pa hapësira: LEN(SUBSTITUTE(A2," ",""))
• Zbrisni gjatësinë e vargut "pa hapësirë" nga gjatësia totale.

Duke supozuar se vargu origjinal i tekstit është në qelizën A2, formula e plotë shkon si më poshtë:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))

Për të gjetur se sa ext hapësirat ra janë në qelizë, merrni gjatësinë e tekstit pa hapësira shtesë dhe më pas zbrisni atë nga gjatësia totale e vargut:

=LEN(A2)-LEN(TRIM(A2))

Pamja e mëposhtme e ekranit tregon të dyja formulat në veprim:

Tani që e dini se sa hapësira përmban çdo qelizë, mund të fshini në mënyrë të sigurt hapësirat shtesë duke përdorur formulën TRIM.

Mënyrë pa formula për të hequr hapësirat dhe për të pastruar të dhënat

Si ju tashmëe dini, shumë hapësira shtesë dhe karaktere të tjera të padëshiruara mund të fshihen pa u vënë re në fletët tuaja, veçanërisht nëse i importoni të dhënat tuaja nga burime të jashtme. Ju gjithashtu dini se si të fshini hapësirat në Excel me një formulë. Sigurisht, të mësuarit e një grushti formulash është një ushtrim i mirë për të mprehur aftësitë tuaja, por mund të marrë kohë.

Përdoruesit e Excel që vlerësojnë kohën e tyre dhe vlerësojnë komoditetin mund të përfitojnë nga Veglat e tekstit të përfshira në Ultimate Suite për Excel. Një nga këto mjete të dobishme lejon heqjen e hapësirave dhe karaktereve që nuk printohen me një klikim të butonit.

Pasi të instalohet, Ultimate Suite shton disa butona të dobishëm në shiritin tuaj të Excel si Trim Spaces , Hiq karakteret , Konverto tekstin , Pastro formatimin dhe disa të tjera.

Sa herë që dëshiron të heqësh hapësirat boshe në fletët tuaja të Excel-it, kryeni këto 4 hapa të shpejtë:

1. Zgjidhni qelizat (varg, të gjithë kolonën ose rreshtin) ku dëshironi të fshini hapësirat shtesë.
2. Klikoni Trim Butoni Spaces në skedën Ablebits Data .
3. Zgjidh një ose disa opsione:
   • Hiq leading dhe trailing hapësirat
   • Të shkurtosh ekstra hapësirat midis fjalëve në një
   • Fshi hapësirat që nuk prishen ( )
4. Klikoni butonin Trim .

U krye! Të gjitha hapësirat shtesë fshihen me një klikim të vetëm.

Kjo është mënyra se si mund t'i hiqni shpejt hapësiratnë qelizat e Excel. Nëse jeni kurioz të eksploroni aftësi të tjera, jeni të mirëpritur të shkarkoni një version vlerësimi të Ultimate Suite. Ju falënderoj që lexoni dhe mezi pres t'ju shoh në blogun tonë javën tjetër!