In deze handleiding wordt uitgelegd hoe u spaties in Excel kunt verwijderen met behulp van formules en de Text Toolkit tool. U leert hoe u voorloop- en sleepspaties in een cel kunt verwijderen, extra spaties tussen woorden kunt wegwerken, niet-brekende witruimte en niet-afdrukbare tekens kunt verwijderen.

Wat is het grootste probleem met spaties? Ze zijn vaak onzichtbaar voor het menselijk oog. Een oplettende gebruiker kan af en toe een voorloopspatie vóór de tekst of een paar extra spaties tussen woorden opmerken. Maar er is geen manier om slepende spaties, die aan het eind van cellen uit het zicht blijven, te ontdekken.

Het zou niet zo'n probleem zijn als extra spaties gewoon rondslingerden, maar ze verpesten uw formules. Het punt is dat twee cellen met dezelfde tekst met en zonder spaties, ook al is het maar één spatie, als verschillende waarden worden beschouwd. U kunt dus uw hersenen pijnigen om uit te zoeken waarom een duidelijk correcte formule niet kan overeenkomen met twee schijnbaar identieke invoer.

Nu u zich volledig bewust bent van het probleem, is het tijd om een oplossing uit te werken. Er zijn verschillende manieren om spaties uit strings te verwijderen, en deze handleiding zal u helpen de techniek te kiezen die het meest geschikt is voor uw specifieke taak en het gegevenstype waarmee u werkt.

Hoe spaties verwijderen in Excel - voor, achter, tussen woorden

Indien uw gegevensverzameling overbodige spaties bevat, kan de TRIM-functie van Excel u helpen deze in één keer te verwijderen - leidende, slepende en meerdere spaties ertussen, met uitzondering van een enkele spatie tussen woorden.

Een gewone TRIM formule is zo simpel als dit:

=TRIM(A2)

Waarbij A2 de cel is waaruit u spaties wilt verwijderen.

Zoals in de volgende schermafbeelding te zien is, verwijdert de Excel TRIM formule met succes alle spaties voor en na de tekst, alsmede opeenvolgende spaties in het midden van een string.

En nu hoeft u alleen de waarden in de oorspronkelijke kolom te vervangen door getrimde waarden. De eenvoudigste manier om dit te doen is met behulp van Speciaal plakken > Waarden De gedetailleerde instructies vindt u hier: Hoe waarden kopiëren in Excel.

Bovendien kunt u de TRIM-functie van Excel gebruiken om het volgende te verwijderen alleen leidende spaties Het formulevoorbeeld staat hier: Hoe spaties in het midden van een tekstreeks bij te snijden in Excel (Left Trim).

Hoe regelafbrekingen en niet-afdrukbare tekens verwijderen

Wanneer u gegevens uit externe bronnen importeert, komen niet alleen extra spaties mee, maar ook diverse niet-afdrukbare tekens zoals carriage return, line feed, verticale of horizontale tab, enz.

De TRIM-functie kan witte spaties verwijderen, maar niet niet-afdrukbare tekens. Technisch gezien is Excel TRIM ontworpen om alleen waarde 32 in het 7-bits ASCII-systeem te verwijderen, dat is het spatieteken.

Om spaties en niet-afdrukbare tekens in een tekenreeks te verwijderen, gebruikt u TRIM in combinatie met de functie CLEAN. Zoals de naam al aangeeft, is CLEAN bedoeld voor het opschonen van gegevens, en kan het alle eerste 32 niet-afdrukbare tekens in de 7-bits ASCII-set (waarden 0 tot en met 31) verwijderen, inclusief regeleinde (waarde 10).

Ervan uitgaande dat de op te schonen gegevens in cel A2 staan, is de formule als volgt:

=TRIM(CLEAN(A2))

Als de Trim/Clean-formule de inhoud van meerdere regels zonder spaties samenvoegt, kunt u dit oplossen door een van deze technieken te gebruiken:

• Gebruik de functie "Alles vervangen" van Excel: voer in het vak "Zoek wat" een carriage return in door op de sneltoets Ctrl+J te drukken; en typ in het vak "Vervangen door" een spatie. Klik op de knop Alles vervangen knop verwisselt alle regeleinden in het geselecteerde bereik voor spaties.
• Gebruik de volgende formule om Carriage Return (waarde 13) en Line Feed (waarde 10) tekens te vervangen door spaties:

  =SUBSTITUTE(SUBSTITUTE(A2, CHAR(13)," "), CHAR(10), " ")

Voor meer informatie, zie Hoe carriage returns (regeleinden) te verwijderen in Excel.

Hoe niet-brekende spaties verwijderen in Excel

Als er na gebruik van de formule TRIM & CLEAN nog enkele hardnekkige spaties staan, hebt u waarschijnlijk de gegevens ergens vandaan gekopieerd/geplakt en zijn er een paar niet-breekbare spaties ingeslopen.

Om niet-brekende spaties (html karakter ), vervang ze door gewone spaties, en laat de TRIM-functie ze dan verwijderen:

=TRIM(SUBSTITUTE(A2, CHAR(160), " "))

Om de logica beter te begrijpen, laten we de formule uit elkaar halen:

• Een niet-breekbaar teken heeft waarde 160 in het 7-bits ASCII-systeem, dus u kunt het definiëren met de formule CHAR(160).
• De functie SUBSTITUTE wordt gebruikt om niet-brekende spaties om te zetten in gewone spaties.
• En tenslotte voegt u de SUBSTITUTE-instructie in de TRIM-functie in om de omgezette spaties te verwijderen.

Als uw werkblad ook niet-afdrukbare tekens bevat, gebruikt u de functie CLEAN samen met TRIM en SUBSTITUTE om spaties en ongewenste symbolen in één klap te verwijderen:

=TRIM(CLEAN((SUBSTITUTE(A2,CHAR(160)," "))))

De volgende schermafbeelding toont het verschil:

Hoe een specifiek niet-afdrukbaar teken verwijderen

Indien de verbinding van 3 functies uit het bovenstaande voorbeeld (TRIM, CLEAN en SUBSTITUTE) geen spaties of niet-afdrukbare tekens in uw blad kon elimineren, betekent dit dat die tekens andere ASCII-waarden hebben dan 0 tot 32 (niet-afdrukbare tekens) of 160 (niet-afbreekbare spatie).

In dit geval gebruikt u de functie CODE om de tekenwaarde te identificeren, en vervolgens gebruikt u SUBSTITUTE om deze te vervangen door een gewone spatie en TRIM om de spatie te verwijderen.

Ervan uitgaande dat de spaties of andere ongewenste tekens die u wilt verwijderen zich in cel A2 bevinden, schrijft u 2 formules:

1. Detecteer in cel B2 de waarde van het problematische teken door een van de volgende CODE functies te gebruiken:
   • Voorloopspatie of niet-afdrukbaar teken aan het begin van de string:

     =CODE(LEFT(A2,1))

   • Spatie of niet-afdrukbaar teken aan het einde van de string:

     =CODE(RIGHT(A2,1))

   • Spatie of niet-afdrukbaar teken in het midden van de string, waarbij n is de positie van het problematische karakter:

     =CODE(MID(A2, n , 1)))

   In dit voorbeeld hebben we een onbekend niet-drukkend karakter in het midden van de tekst, op de 4e positie, en we vinden de waarde ervan met deze formule:

   =CODE(MID(A2,4,1))

   De CODE-functie geeft waarde 127 terug (zie onderstaande schermafbeelding).

2. In cel C2 vervangt u CHAR(127) door een gewone spatie (" "), en dan knipt u die spatie bij:

   =TRIM(SUBSTITUTE(A2, CHAR(127), " "))

Het resultaat zou er ongeveer zo uit moeten zien:

Als uw gegevens een aantal verschillende niet-afdrukbare tekens en niet-breekbare spaties bevatten, kunt u twee of meer SUBSTITUTE-functies nesten om alle ongewenste tekencodes tegelijk te verwijderen:

=TRIM(SUBSTITUTE(SUBSTITUTE(A2, CHAR(127), " "), CHAR(160), " ")))

Hoe verwijder je alle spaties in Excel

In sommige situaties wilt u misschien absoluut alle witruimtes in een cel verwijderen, inclusief enkele spaties tussen woorden of getallen. Bijvoorbeeld wanneer u een numerieke kolom hebt geïmporteerd waarin spaties worden gebruikt als scheidingsteken tussen duizendtallen, waardoor grote getallen gemakkelijker te lezen zijn, maar uw formules niet kunnen worden berekend.

Om alle spaties in één keer te verwijderen, gebruikt u SUBSTITUTE zoals uitgelegd in het vorige voorbeeld, met als enige verschil dat u het spatieteken dat CHAR(32) teruggeeft, vervangt door niets (""):

=SUBSTITUTE(A2, CHAR(32), "")

Of u kunt gewoon de spatie (" ") in de formule typen, zoals dit:

=SUBSTITUTE(A2," ","")

Vervang daarna formules door waarden en uw getallen zullen goed rekenen.

Hoe spaties tellen in Excel

Voordat u spaties uit een bepaalde cel verwijdert, wilt u misschien weten hoeveel spaties er eigenlijk zijn.

Om het totale aantal spaties in een cel te krijgen, doe je het volgende:

• Bereken de volledige lengte van de string met de LEN-functie: LEN(A2)
• Alle spaties vervangen door niets: SUBSTITUTE(A2," ","")
• Bereken de lengte van de string zonder spaties: LEN(SUBSTITUTE(A2," ",""))
• Trek de "ruimtevrije" stringlengte af van de totale lengte.

Ervan uitgaande dat de oorspronkelijke tekststring in cel A2 staat, gaat de volledige formule als volgt:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))

Om uit te vinden hoeveel extra ruimtes in de cel staan, krijg je de tekstlengte zonder extra spaties, en trek je die af van de totale lengte van de tekenreeks:

=LEN(A2)-LEN(TRIM(A2))

De volgende schermafbeelding toont beide formules in actie:

Nu u weet hoeveel spaties elke cel bevat, kunt u veilig extra spaties verwijderen met de TRIM-formule.

Formulevrije manier om spaties te verwijderen en gegevens op te schonen

Zoals u al weet, kunnen veel extra spaties en andere ongewenste tekens ongemerkt op de loer liggen in uw sheets, vooral als u uw gegevens importeert uit externe bronnen. U weet ook hoe u spaties in Excel kunt verwijderen met een formule. Natuurlijk is het leren van een handvol formules een goede oefening om uw vaardigheden aan te scherpen, maar het kan tijdrovend zijn.

Excel-gebruikers die waarde hechten aan hun tijd en gemak, kunnen hun voordeel doen met de teksthulpmiddelen die zijn opgenomen in onze Ultimate Suite voor Excel. Een van deze handige hulpmiddelen maakt het mogelijk om spaties en niet-afdrukbare tekens met één klik op de knop te verwijderen.

Eenmaal geïnstalleerd voegt Ultimate Suite verschillende handige knoppen toe aan uw Excel-lint, zoals Trimruimtes , Tekens verwijderen , Converteer tekst , Duidelijke opmaak en nog een paar meer.

Wanneer u lege ruimten in uw Excel-bladen wilt verwijderen, voert u deze 4 snelle stappen uit:

1. Selecteer de cellen (bereik, hele kolom of rij) waar u extra spaties wilt verwijderen.
2. Klik op de Trimruimtes knop op de Ablebits gegevens tab.
3. Kies één of meerdere opties:
   • Verwijder toonaangevend en volgend ruimtes
   • Trim extra spaties tussen woorden aan een
   • Verwijder niet-brekende ruimtes ( )
4. Klik op de Trim knop.

Klaar! Alle extra spaties worden met één klik verwijderd.

Zo kunt u snel spaties in Excel-cellen verwijderen. Als u benieuwd bent naar andere mogelijkheden, bent u van harte welkom om een evaluatieversie van de Ultimate Suite te downloaden. Ik dank u voor het lezen en zie u graag volgende week op onze blog!