Падручнік тлумачыць, як выдаліць пустыя месцы ў Excel з дапамогай формул і інструмента Text Toolkit. Вы даведаецеся, як выдаліць прабелы ў пачатку і ў канцы ячэйкі, ліквідаваць лішнія прабелы паміж словамі, пазбавіцца ад непарыўных прабелаў і недрукаваных сімвалаў.

Якая самая вялікая праблема з прабеламі? Яны часта непрыкметныя чалавечаму воку. Уважлівы карыстальнік час ад часу можа ўлавіць першы прабел, які хаваецца перад тэкстам, або некалькі дадатковых прабелаў паміж словамі. Але няма магчымасці заўважыць прабелы ў канцы, тыя, што не бачныя ў канцы клетак.

Гэта не было б вялікай праблемай, калі б лішнія прабелы проста валяліся, але яны псуюць ваш формулы. Справа ў тым, што дзве ячэйкі, якія змяшчаюць адзін і той жа тэкст з прабеламі і без іх, нават калі гэта ўсяго толькі адзін прабел, лічацца рознымі значэннямі. Такім чынам, вы можаце ламаць галаву, спрабуючы высветліць, чаму відавочна правільная формула не можа адпавядаць дзвюм, здавалася б, аднолькавым запісам.

Цяпер, калі вы цалкам разумееце праблему, прыйшоў час працаваць з рашэння. Ёсць некалькі спосабаў выдаліць прабелы з радка, і гэты падручнік дапаможа вам выбраць метад, які лепш за ўсё падыходзіць для вашай канкрэтнай задачы і тыпу даных, з якімі вы працуеце.

Як выдаліць прабел прабелы ў Excel - у пачатку, у канцы, паміж словамі

Калі ваш набор даных змяшчае лішнія прабелы, ExcelФункцыя TRIM можа дапамагчы вам выдаліць іх усе за адзін раз - у пачатку, у канцы і некалькі прабелаў паміж словамі, за выключэннем аднаго прабелу паміж словамі.

Звычайная формула TRIM такая ж простая:

=TRIM(A2)

Дзе A2 — ячэйка, з якой вы хочаце выдаліць прабелы.

Як паказана на наступным скрыншоце, формула Excel TRIM паспяхова выдаліла ўсе прабелы да і пасля тэксту. як паслядоўныя прабелы ў сярэдзіне радка.

І цяпер вам трэба толькі замяніць значэнні ў зыходным слупку абрэзанымі значэннямі. Самы просты спосаб зрабіць гэта з дапамогай Спецыяльная ўстаўка > Значэнні , падрабязныя інструкцыі можна знайсці тут: Як скапіяваць значэнні ў Excel.

Акрамя таго, вы можа выкарыстоўваць функцыю Excel TRIM, каб выдаліць толькі першыя прабелы , захоўваючы ўсе прабелы ў сярэдзіне тэкставага радка некранутымі. Прыклад формулы тут: Як абрэзаць прабелы ў пачатку ў Excel (Абрэзка злева).

Як выдаліць разрывы радкоў і недрукаваныя сімвалы

Калі вы імпартуеце даныя з знешніх крыніц, гэта не толькі дадаткова прабелы, якія сустракаюцца разам, але таксама розныя недрукаваныя сімвалы, такія як вяртанне карэткі, перавод радка, вертыкальная або гарызантальная табуляцыя і г.д.

Функцыя TRIM можа пазбавіцца ад прабелаў, але не можа выдаліць недрукаваныя сімвалы . Тэхнічна Excel TRIM прызначаны толькі для выдалення значэння 32 у 7-бітнай сістэме ASCII, якое з'яўляецца прабеламсімвал.

Каб выдаліць прабелы і недрукаваныя сімвалы ў радку, выкарыстоўвайце TRIM у спалучэнні з функцыяй CLEAN. Як вынікае з назвы, CLEAN прызначаны для ачысткі даных і можа выдаляць любыя і ўсе першыя 32 недрукаваныя сімвалы ў 7-бітным наборы ASCII (значэнні ад 0 да 31), уключаючы разрыў радка ( значэнне 10).

Калі выказаць здагадку, што дадзеныя, якія трэба ачысціць, знаходзяцца ў ячэйцы A2, формула выглядае наступным чынам:

=TRIM(CLEAN(A2))

Калі Trim/ Чыстая формула аб'ядноўвае змесціва некалькіх радкоў без прабелаў, вы можаце выправіць гэта, выкарыстоўваючы адзін з наступных метадаў:

• Выкарыстайце функцыю "Замяніць усё" ў Excel: у полі "Знайсці што" увядзіце вяртанне карэткі, націснуўшы спалучэнне клавіш Ctrl+J; і ў полі «Замяніць на» увядзіце прабел. Націсканне кнопкі Замяніць усё заменіць усе разрывы радкоў у выбраным дыяпазоне прабеламі.
• Выкарыстоўвайце наступную формулу, каб замяніць сімвалы вяртання карэткі (значэнне 13) і пераводу радка (значэнне 10) на сімвалы. прабелы:

  =SUBSTITUTE(SUBSTITUTE(A2, CHAR(13)," "), CHAR(10), " ")

  Глядзі_таксама: Як абагуліць каляндар Outlook з Google

Для атрымання дадатковай інфармацыі глядзіце, як выдаліць знакі вяртання карэткі (разрывы радкоў) у Excel.

Як выдаліць неразрыўныя прабелы ў Excel

Калі пасля выкарыстання TRIM & ЧЫСТАЯ формула некаторыя ўпартыя прабелы ўсё яшчэ ёсць, хутчэй за ўсё, вы скапіравалі/ўставілі даныя аднекуль і пракраліся некалькі неразрыўных прабелаў.

Каб пазбавіцца ад неразрыўных прабелаў (сімвал html ), заменіце іх звычайныміпрабелы, а потым выдаліце ​​іх функцыяй TRIM:

=TRIM(SUBSTITUTE(A2, CHAR(160), " "))

Каб лепш зразумець логіку, разбяром формулу:

• Неразрыўны сімвал мае значэнне 160 у 7-бітнай сістэме ASCII, так што вы можаце вызначыць яго з дапамогай формулы CHAR(160).
• Функцыя SUBSTITUTE выкарыстоўваецца для пераўтварэння неразрыўных прабелаў у звычайныя.
• І, нарэшце, вы ўбудоўваеце аператар SUBSTITUTE у функцыю TRIM, каб выдаліць пераўтвораныя прабелы.

Калі ваш працоўны аркуш таксама змяшчае недрукаваныя сімвалы, выкарыстоўвайце функцыю CLEAN разам з TRIM і SUBSTITUTE, каб атрымаць пазбавіцца ад прабелаў і непажаданых сімвалаў адным махам:

=TRIM(CLEAN((SUBSTITUTE(A2,CHAR(160)," "))))

На наступным здымку экрана дэманструецца розніца:

Як выдаліць пэўны не- друкаваны сімвал

Калі ўзаемасувязь 3 функцый, разгледжаных у прыведзеным вышэй прыкладзе (TRIM, CLEAN і SUBSTITUTE), не змагла ліквідаваць прабелы або недрукаваныя сімвалы на вашым аркушы, гэта азначае, што гэтыя сімвалы маюць іншыя значэнні ASCII, чым 0 да 3 2 (недрукаваныя сімвалы) або 160 (неразрыўны прабел).

У гэтым выпадку выкарыстоўвайце функцыю CODE, каб вызначыць значэнне сімвала, а потым выкарыстоўвайце SUBSTITUTE, каб замяніць яго на звычайны прабел, і TRIM на выдаліце ​​прабел.

Мяркуючы, што прабелы або іншыя непажаданыя сімвалы, ад якіх вы хочаце пазбавіцца, знаходзяцца ў ячэйцы A2, вы пішаце 2 формулы:

1. У ячэйцы B2 вызначце праблемнысімвальнае значэнне з дапамогай адной з наступных функцый CODE:
   • Пачатковы прабел або недрукаваны сімвал у пачатку радка:

     =CODE(LEFT(A2,1))

   • Канечны прабел або недрукаваны сімвал сімвал у канцы радка:

     =CODE(RIGHT(A2,1))

   • Прабел або недрукаваны сімвал у сярэдзіне радка, дзе n — пазіцыя праблемнага сімвала:

     =CODE(MID(A2, n , 1)))

   У гэтым прыкладзе ў сярэдзіне тэксту, на 4-й пазіцыі, ёсць нейкі невядомы недрукаваны сімвал, і мы знаходзім яго значэнне з дапамогай гэтай формулы:

   =CODE(MID(A2,4,1))

   Функцыя CODE вяртае значэнне 127 (гл. скрыншот ніжэй).

2. У ячэйцы C2 вы замяняеце CHAR(127) звычайным прабелам (" "), а потым скарачаеце гэты прабел:

   =TRIM(SUBSTITUTE(A2, CHAR(127), " "))

Вынік павінен выглядаць прыкладна так:

Калі вашы даныя ўтрымліваюць некалькі розных недрукаваных знакаў, а таксама неразрыўных прабелаў, вы можаце ўкласці дзве або больш функцый SUBSTITUTE для выдалення усе непажаданыя коды сімвалаў адначасова:

=TRIM(SUBSTITUTE(SUBSTITUTE(A2, CHAR(127), " "), CHAR(160), " ")))

Як выдаліць усе прабелы ў Excel

У некаторых сітуацыях вы можаце выдаліць абсалютна усе прабелы ў клетцы, уключаючы адзінкавыя прабелы паміж словамі або лічбамі. Напрыклад, калі вы імпартавалі лікавы слупок, у якім у якасці падзельнікаў тысяч выкарыстоўваюцца прабелы, што палягчае чытанне вялікіх лікаў, але перашкаджае вылічэнню вашых формул.

Каб выдаліць усе прабелыадначасова выкарыстоўвайце SUBSTITUTE, як тлумачылася ў папярэднім прыкладзе, з той толькі розніцай, што вы замяняеце прабел, які вяртае CHAR(32), нічым (""):

=SUBSTITUTE(A2, CHAR(32), "")

Або , вы можаце проста ўвесці прабел (" ") у формуле, як гэта:

=SUBSTITUTE(A2," ","")

Пасля гэтага заменіце формулы значэннямі, і вашы лічбы будуць правільна разлічаны .

Як падлічыць прабелы ў Excel

Перш чым выдаляць прабелы з пэўнай ячэйкі, вам можа быць цікава даведацца, колькі іх там насамрэч.

Каб атрымаць агульная колькасць прабелаў у ячэйцы, зрабіце наступнае:

• Вылічыце ўсю даўжыню радка з дапамогай функцыі LEN: LEN(A2)
• Заменіце ўсе прабелы нічым: SUBSTITUTE(A2 ," ","")
• Вылічыць даўжыню радка без прабелаў: LEN(ЗАМЕНА(A2," ",""))
• Адняць даўжыню радка без прабелаў ад агульнай даўжыні.

Пры ўмове, што зыходны тэкставы радок знаходзіцца ў ячэйцы A2, поўная формула выглядае наступным чынам:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))

Каб даведацца, колькі дап ra прабелы знаходзяцца ў ячэйцы, атрымаеце даўжыню тэксту без лішніх прабелаў, а потым аднімеце яе ад агульнай даўжыні радка:

=LEN(A2)-LEN(TRIM(A2))

На наступным скрыншоце дэманструюцца абедзве формулы ў дзеянні:

Цяпер, калі вы ведаеце, колькі прабелаў змяшчае кожная ячэйка, вы можаце смела выдаляць лішнія прабелы з дапамогай формулы TRIM.

Спосаб выдалення прабелаў і ачысткі даных без формулы

Як вы ўжоВедайце, шмат лішніх прабелаў і іншых непажаданых сімвалаў могуць незаўважна хавацца ў вашых аркушах, асабліва калі вы імпартуеце свае дадзеныя з знешніх крыніц. Вы таксама ведаеце, як выдаліць прабелы ў Excel з дапамогай формулы. Вядома, вывучэнне невялікай колькасці формул з'яўляецца добрым практыкаваннем для адточвання вашых навыкаў, але гэта можа заняць шмат часу.

Карыстальнікі Excel, якія цэняць свой час і цэняць зручнасць, могуць скарыстацца тэкставымі інструментамі, якія ўваходзяць у наш Канчатковы пакет для Excel. Адзін з гэтых зручных інструментаў дазваляе выдаляць прабелы і недрукаваныя сімвалы адным націскам кнопкі.

Пасля ўсталявання Ultimate Suite дадае некалькі карысных кнопак на вашу стужку Excel, такіх як Скарачэнне прабелаў , Выдаленне сімвалаў , Пераўтварэнне тэксту , Ачысціць фарматаванне і яшчэ некалькі.

Кожны раз, калі вы хочаце выдаліць пустыя месцы ў вашых аркушаў Excel, выканайце наступныя 4 хуткія крокі:

1. Вылучыце ячэйкі (дыяпазон, увесь слупок або радок), дзе вы хочаце выдаліць лішнія прабелы.
2. Націсніце Абрэзаць Кнопка прабелаў на ўкладцы Даныя Ablebits .
3. Выберыце адзін або некалькі варыянтаў:
   • Выдаліць пачатак і канец прабелы
   • Скараціць лішнія прабелы паміж словамі да аднаго
   • Выдаліць неразрыўныя прабелы ( )
4. Націсніце кнопку Абрэзаць .

Гатова! Усе лішнія прабелы выдаляюцца ў адзін клік.

Вось як можна хутка выдаліць прабелыу вочках Excel. Калі вам цікава азнаёміцца ​​з іншымі магчымасцямі, вы можаце загрузіць пробную версію Ultimate Suite. Я дзякую вам за чытанне і з нецярпеннем чакаю сустрэчы з вамі ў нашым блогу на наступным тыдні!