Упатството покажува како да се користи IFERROR во Excel за да се фатат грешките и да се заменат со празна ќелија, друга вредност или приспособена порака. Ќе научите како да ја користите функцијата IFERROR со Vlookup и Index Match, и како таа се споредува со IF ISERROR и IFNA.

„Дајте ми место да стојам и јас ќе ја поместам земјата“ Архимед еднаш рекол. „Дајте ми формула и јас ќе ја направам да врати грешка“, би рекол корисник на Excel. Во ова упатство, нема да разгледуваме како да враќаме грешки во Excel, туку повеќе би сакале да научиме како да ги спречиме за да ги одржуваме вашите работни листови чисти и вашите формули транспарентни.

Excel IFERROR функција - синтакса и основни употреби

Функцијата IFERROR во Excel е дизајнирана да ги заробува и управува грешките во формулите и пресметките. Поконкретно, IFERROR проверува формула и ако се процени на грешка, враќа друга вредност што ќе ја наведете; во спротивно, го враќа резултатот од формулата.

Синтаксата на функцијата Excel IFERROR е следна:

Каде:

• Вредност (задолжително) - што да проверите за грешки. Тоа може да биде формула, израз, вредност или референца на ќелија.
• Value_if_error (задолжително) - што да се врати ако се најде грешка. Тоа може да биде празна низа (празна ќелија), текстуална порака, нумеричка вредност, друга формула или пресметка.

На пример, кога делите две колони со броеви, виеможе да добие куп различни грешки ако една од колоните содржи празни ќелии, нули или текст.

За да спречите тоа да се случи, користете ја функцијата IFERROR за фаќање и справување со грешките како што сакате.

Ако е грешка, тогаш празно

Наведете празна низа (") на аргументот value_if_error за да вратите празна ќелија доколку се најде грешка:

=IFERROR(A2/B2, "")

Ако е грешка, тогаш прикажете порака

Можете и да ја прикажете вашата сопствена порака наместо стандардната нотација за грешка на Excel:

=IFERROR(A2/B2, "Error in calculation")

5 работи што треба да ги знаете за Excel IFERROR функцијата

1. Функцијата IFERROR во Excel се справува со сите типови грешки вклучувајќи # DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF!, и #VALUE!.
2. Во зависност од содржината на value_if_error аргумент, IFERROR може да ги замени грешките со вашата приспособена текстуална порака, број, датум или логичка вредност, резултат од друга формула или празна низа (празна ќелија).
3. Ако аргументот вредност е празна клетка, се третира како празна низа (''''), но не и грешка.
4. IFERROR беше воведен во Excel 2007 и е достапен во сите наредни верзии на Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021 и Excel 365.
5. За да ги заробите грешките во Excel 2003 и претходните верзии, користете ја функцијата ISERROR во комбинација со IF, како што е прикажано во овој пример.

Примери на формула IFERROR

Следниве примерипокажете како да се користи IFERROR во Excel во комбинација со други функции за да се постигнат посложени задачи.

Excel IFERROR со Vlookup

Една од најчестите употреби на функцијата IFERROR е да им се каже на корисниците дека вредноста што ја бараат не постои во множеството податоци. За ова, ја завиткувате формулата VLOOKUP во IFERROR вака:

Ако вредноста за пребарување не е во табелата што ја барате , обична формула Vlookup би ја вратила грешката #N/A:

За да размислуваат вашите корисници, завиткајте го VLOOKUP во IFERROR и прикажете поинформативен и попријатен за корисникот порака:

=IFERROR(VLOOKUP(A2, 'Lookup table'!$A$2:$B$4, 2,FALSE), "Not found")

Сликата од екранот подолу ја покажува оваа формула за Iferror во Excel:

Ако сакате да заробите само #N /A грешки, но не сите грешки, користете ја функцијата IFNA наместо IFERROR.

За повеќе примери на формулата за Excel IFERROR VLOOKUP, проверете ги овие упатства:

• Iferror со Vlookup за заробување и да се справи со грешки
• Како да се добие N-та појава на вредност за пребарување
• Како да ги добиете сите појави на пребарување вредност

Вгнездени функции IFERROR за да направите секвенцијални Vlookups во Excel

Во ситуации кога треба да извршите повеќе Vlookup врз основа на тоа дали претходниот Vlookup успеал или не успеал, можете да вгнездите две или повеќе IFERROR функционира една во друга.

Да претпоставиме дека имате голем број на извештаи за продажба од регионалните филијали на вашиоткомпанија, а сакате да добиете сума за одреден ID на нарачка. Со A2 како вредност за пребарување во тековниот лист и A2:B5 како опсег на пребарување во 3 листа за пребарување (Извештај 1, Извештај 2 и Извештај 3), формулата оди како што следува:

=IFERROR(VLOOKUP(A2,'Report 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 3'!A2:B5,2,0),"not found")))

Резултатот ќе изгледа нешто слично на ова:

За детално објаснување на логиката на формулата, погледнете Како да направите секвенцијални Vlookups во Excel.

IFERROR во формули на низи

Како што веројатно знаете, формулите за низи во Excel се наменети да вршат повеќе пресметки во една формула. Ако наведете формула или израз на низа што резултира со низа во аргументот вредност на функцијата IFERROR, таа ќе врати низа вредности за секоја ќелија во наведениот опсег. Примерот подолу ги прикажува деталите.

Да речеме, имате Вкупно во колоната Б и Цена во колоната В, и сакате да пресметате Вкупна количина . Ова може да се направи со користење на следнава формула на низа, која ја дели секоја ќелија во опсегот B2:B4 со соодветната ќелија од опсегот C2:C4, а потоа ги собира резултатите:

=SUM($B$2:$B$4/$C$2:$C$4)

Формулата работи добро се додека опсегот на делители нема нули или празни ќелии. Ако има барем една вредност 0 или празна ќелија, #DIV/0! се враќа грешката:

За да ја поправите таа грешка, едноставно направете ја поделбата во функцијата IFERROR:

=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))

Што прави формулатае да се подели вредност во колоната B со вредност во колоната C во секој ред (100/2, 200/5 и 0/0) и да се врати низата резултати {50; 40; #DIV/0!}. Функцијата IFERROR ги фаќа сите #DIV/0! грешки и ги заменува со нули. И потоа, функцијата SUM ги собира вредностите во добиената низа {50; 40; 0} и го дава конечниот резултат (50+40=90).

Забелешка. Запомнете дека формулите за низи треба да се пополнат со притискање на кратенката Ctrl + Shift + Enter.

IFERROR наспроти IF ISERROR

Сега кога знаете колку е лесно да се користи функцијата IFERROR во Excel, можеби се прашувате зошто некои луѓе сè уште се склони кон користење на комбинацијата IF ISERROR. Дали има некои предности во споредба со IFERROR? Никој. Во старите лоши времиња на Excel 2003 и пониски кога не постоеше IFERROR, IF ISERROR беше единствениот можен начин да се заробат грешките. Во Excel 2007 и подоцна, тоа е само малку покомплексен начин да се постигне истиот резултат.

На пример, за да се фатат грешките во Vlookup, можете да користите која било од формулите подолу.

Во Excel 2007 - Excel 2016:

Во сите верзии на Excel:

Забележете дека во формулата IF ISERROR VLOOKUP, треба да Vlookup двапати. На обичен англиски јазик, формулата може да се прочита на следниов начин: Ако Vlookup резултира со грешка, вратете го „Not found“, инаку излезете го резултатот Vlookup.

И тука е вистински-животен пример на формулата Excel If Iserror Vlookup:

=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)),"Not found", VLOOKUP(D2, A2:B5,2,FALSE ))

За повеќе информации, видете Користење на функцијата ISERROR во Excel.

IFERROR наспроти IFNA

Воведена со Excel 2013, IFNA е уште една функција за проверка на формула за грешки. Неговата синтакса е слична на онаа на IFERROR:

На кој начин IFNA се разликува од IFERROR? Функцијата IFNA фаќа само #N/A грешки додека IFERROR се справува со сите типови грешки.

Во кои ситуации можеби ќе сакате да користите IFNA? Кога не е паметно да се прикријат сите грешки. На пример, кога работите со важни или чувствителни податоци, можеби ќе сакате да бидете предупредени за можни дефекти во вашиот сет на податоци, а стандардните пораки за грешка на Excel со симболот „#“ може да бидат живописни визуелни индикатори.

Ајде да видиме како можете да направите формула која ја прикажува пораката „Не е пронајдена“ наместо грешката N/A, која се појавува кога вредноста на пребарувањето не е присутна во множеството податоци, но ви носи внимание на други грешки на Excel.

Да претпоставиме дека сакате да го повлечете Кол. од табелата за пребарување до резимената табела како што е прикажано на сликата од екранот подолу. Користењето на формулата Excel Iferror Vlookup ќе произведе естетски пријатен резултат, кој е технички неточен бидејќи Лимоните постојат во табелата за пребарување:

За да се фати # Не, но прикажете ја грешката #DIV/0, користете ја функцијата IFNA во Excel 2013 и Excel2016:

=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Not found")

Или, комбинацијата IF ISNA во Excel 2010 и претходните верзии:

=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)),"Not found", VLOOKUP(F3,$A$3:$D$6,4,FALSE))

Синтаксата на IFNA VLOOKUP и IF ISNA Формулите VLOOKUP се слични на оние на IFERROR VLOOKUP и IF ISERROR VLOOKUP за кои беше дискутирано претходно.

Како што е прикажано на сликата подолу, формулата Ifna Vlookup враќа „Не е пронајдена“ само за ставката што не е присутна во табелата за пребарување ( Праски ). За Лимони , покажува #DIV/0! што покажува дека нашата табела за пребарување содржи грешка со делење со нула:

За повеќе детали, видете Користење на функцијата IFNA во Excel.

Најдобри практики за користење IFERROR во Excel

Досега веќе знаете дека функцијата IFERROR е најлесниот начин да се фатат грешките во Excel и да се маскираат со празни ќелии, нула вредности или сопствени пораки. Сепак, тоа не значи дека треба да ја завиткате секоја формула со справување со грешки. Следниве едноставни препораки може да ви помогнат да ја одржите рамнотежата.

1. Не заробувајте грешки без причина.
2. Завиткајте го најмалиот можен дел од формулата во IFERROR.
3. 8>За да се справите само со одредени грешки, користете функција за справување со грешки со помал опсег:
   • IFNA или IF ISNA за да ги фатите само грешките #N/A.
   • ISERR за да ги фатите сите грешки освен за #Не/не.

Вака ја користите функцијата IFERROR во Excel за заробување и справување со грешките. За да ги погледнете подетално формулите што се дискутирани во оваупатство, добредојдени сте да го преземете нашиот примерок за работна книга IFERROR Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела.