Fljót leið til að breyta fjölda hólfa í eina röð með hjálp TOROW aðgerðarinnar.

Microsoft Excel 365 hefur kynnt nokkrar nýjar aðgerðir til að framkvæma ýmsar meðhöndlun með fylki. Með TOROW geturðu framkvæmt umbreytingar frá röð til röð á skömmum tíma. Hér er listi yfir verkefni sem þessi nýja aðgerð getur framkvæmt:

Excel TOROW aðgerð

TOROW aðgerðin í Excel er notuð til að umbreyta fylki eða svið af frumum í ein röð.

Fallið tekur samtals þrjár frumbreytur, þar af er aðeins krafist fyrsta.

TOROW(fylki, [hunsa], [skanna_eftir_dálki])

Hvar:

Fylki (áskilið) - fylki eða svið til að breyta í eina línu.

Hunsa (valfrjálst) - ákvarðar hvort hunsa eigi eyður eða/og villur. Getur tekið eitt af þessum gildum:

• 0 eða sleppt (sjálfgefið) - haldið öllum gildum
• 1 - hunsa eyður
• 2 - hunsa villur
• 3 - hunsa eyður og villur

Scan_by_column (valfrjálst) - skilgreinir hvernig á að skanna fylkið:

• FALSE eða sleppt (sjálfgefið) - skannaðu fylkið lárétt eftir röð.
• TRUE - skannaðu fylkið lóðrétt eftir dálki.

Ráð:

• Til að umbreyta fylki í einn dálk, notaðu TOCOL aðgerðina.
• Til að framkvæma öfuga röð-til-fylki umbreytingu, notaðu annað hvort WRAPCOLS aðgerðina til að vefja inn í dálka eða WRAPROWS aðgerðina til að vefjafylki í raðir.
• Til að breyta línum í dálka, notaðu TRANSPOSE aðgerðina.

TOROW framboð

TOROW er ný aðgerð, sem er aðeins studd í Excel fyrir Microsoft 365 (fyrir Windows og Mac) og Excel fyrir vefinn.

Grunnformúla TOROW í Excel

Notaðu TOROW formúluna til að gera einfalda umbreytingu á bili til röð. í grunnformi sínu. Til þess þarftu aðeins að skilgreina fyrstu rökin ( fylki ).

Til dæmis, til að breyta tvívíða fylki sem samanstendur af 3 dálkum og 3 línum í eina röð, formúlan er:

=TOROW(A3:C6)

Þú slærð formúluna inn í aðeins einn reit (A10 í okkar tilfelli), og hún hellist sjálfkrafa í eins marga reiti og þarf til að geyma allar niðurstöðurnar. Í Excel skilmálum er framleiðslusviðið umkringt þunnum bláum ramma kallað lekasvið.

Hvernig þessi formúla virkar:

Í fyrsta lagi er meðfylgjandi svið af frumum umbreytt í tvívítt fylki. Vinsamlega takið eftir dálkunum sem eru aðgreindir með kommum og línur aðskildar með semíkommu:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

Síðan les TOROW aðgerðin fylkið frá vinstri til hægri og breytir því í einvídd lárétt fylki:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

Niðurstaðan fer í reit A10, þaðan sem hún lekur inn í nágrannareitinn hægra megin.

Breyta svið í röð og hunsa eyður og villur

Sjálfgefið er að TOROW aðgerðin heldur öllum gildum frá upprunafylki, þar á meðal tómum hólfum ogvillur. Í úttakinu birtast núllgildi í stað auðra hólfa, sem gæti verið frekar ruglingslegt.

Til að útiloka auða skaltu stilla ígnore röksemdin á 1:

=TOROW(A3:C5, 1)

Til að huna villur skaltu stilla huna röksemdin á 2:

=TOROW(A3:C5, 2)

Til að sleppa bæði, eyður og villur , notaðu 3 fyrir ignore rökin:

=TOROW(A3:C5, 3)

Myndin hér að neðan sýnir allar þrjár aðstæðurnar í gangi:

Lesa fylki lárétt eða lóðrétt

Með sjálfgefna hegðun, vinnur TOROW aðgerðin fylkið lárétt frá vinstri til hægri. Til að skanna gildin eftir dálki frá toppi til botns, stillirðu 3. frumbreytu ( skanna_eftir_dálki ) á TRUE eða 1.

Til dæmis, til að lesa upprunasvið eftir röð, formúlan í E3 er:

=TOROW(A3:C5)

Til að skanna svið eftir dálki er formúlan í E8:

=TOROW(A3:C5, ,TRUE)

Í báðum tilfellum eru fylkin sem myndast sömu stærð, en gildunum er raðað í aðra röð.

Sameina mörg svið í eina röð

Til að sameina nokkur svið sem ekki eru aðliggjandi í eina röð, staflarðu þeim fyrst lárétt eða lóðrétt í eina fylki með hjálp HSTACK eða VSTACK, í sömu röð. , og notaðu síðan TOROW fallið til að breyta sameinuðu fylki í röð.

Það fer eftir viðskiptarökfræði þinni, ein af eftirfarandi formúlum mun framkvæma verkefnið.

Stafla fylkjum lárétt og umbreyta með röð

Með þeirri fyrstusvið í A3:C4 og annað svið í A8:C9, formúlan hér að neðan mun stafla sviðunum tveimur láréttum í eina fylki og umbreyta því síðan í röð sem les gildin frá vinstri til hægri. Niðurstaðan er í E3 á myndinni hér að neðan.

=TOROW(HSTACK(A3:C4, A8:C9))

Stafla fylki lárétt og umbreyta eftir dálki

Til að lesa staflað fylki lóðrétt frá toppi til botns, þú stillir 3. rök TOROW á TRUE eins og sýnt er í E5 á myndinni hér að neðan:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

Stafla fylkjum lóðrétt og umbreytir eftir röð

Til að bæta við hverri síðari fylki neðst í fyrra fylki og lestu sameinaða fylkið lárétt, formúlan í E12 er:

=TOROW(VSTACK(A3:C4, A8:C9))

Stafla fylkjum lóðrétt og umbreyta eftir dálki

Til að bæta hverri síðari fylki við botn þeirrar fyrri og skanna sameinaða fylkið lóðrétt er formúlan:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

Til að skilja rökfræðina betur skaltu fylgjast með mismunandi röð gilda í fylkin sem myndast:

Dregið út einstök gildi úr svið í röð

Frá og með Microsoft Excel 2016 höfum við frábæra aðgerð, sem heitir UNIQUE, sem getur auðveldlega fengið einstök gildi úr einum dálki eða röð. Hins vegar getur það ekki séð um fjöldálka fylki. Til að vinna bug á þessari takmörkun, notaðu UNIQUE og TOROW aðgerðirnar saman.

Til dæmis, til að draga öll mismunandi (aðgreind) gildi úr bilinu A2:C7 og setja niðurstöðurnar í eina röð,formúlan er:

=UNIQUE(TOROW(A2:C7), TRUE)

Þar sem TOROW skilar einvíða láréttu fylki, setjum við 2. ( by_col ) rök fyrir UNIQUE á TRUE til að bera saman dálkana á móti hverjum annað.

Ef þú vilt að niðurstöðunum sé raðað í stafrófsröð, settu formúluna hér að ofan í SORT aðgerðina:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

Eins og með UNIQUE, by_col rökin af SORT eru einnig stillt á TRUE.

TOROW valkostur fyrir Excel 365 - 2010

Í Excel útgáfum þar sem TOROW aðgerðin er ekki tiltæk, geturðu umbreytt bili í eina röð með því að nota blöndu af nokkrum mismunandi aðgerðum sem virka í eldri útgáfur. Þessar lausnir eru flóknari, en þær virka.

Til að skanna svið lárétt er almenna formúlan:

INDEX( svið , KVÓTI(DÁLUR (A1)-1, COLUMNS( svið ))+1, MOD(COLUMN(A1)-1, COLUMNS( svið ))+1)

Til að skanna bilið lóðrétt er almenna formúlan :

INDEX( svið , MOD(COLUMN(A1)-1, COLUMNS( svið ))+1, QUOTIENT(COLUMN (A1)-1, COLUMNS(<15)>svið ))+1)

Fyrir sýnishorn gagnasafnsins okkar í A3:C5 hafa formúlurnar þessa lögun:

Til að skanna svið eftir röð:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Þessi formúla er valkostur við TOROW fallið með 3. frumbreytu stillt á FALSE eða sleppt:

=TOROW(A3:C5)

Til að skanna bilið með því að dálkur:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Þessi formúla jafngildir TOROW fallinu með 3. frumbreytu stillt áTRUE:

=TOROW(A3:C5, ,TRUE)

Vinsamlegast athugaðu að ólíkt TOROW virkninni í kraftmiklu fylki ætti að slá inn þessar hefðbundnu formúlur í hvern reit þar sem þú vilt að niðurstöðurnar birtist. Í okkar tilviki fer fyrsta formúlan (eftir röð) í E3 og er afrituð í gegnum M3. Önnur formúlan (eftir dálki) lendir í E8 og er dregin í gegnum M8.

Til þess að formúlurnar afriti rétt, læsum við sviðinu með því að nota algjörar tilvísanir ($A$3:$C$5). Nafngreint svið mun líka duga.

Ef þú hefur afritað formúlurnar í fleiri frumur en þörf er á, er #REF! villa mun birtast í "auka" hólfum. Til að laga þetta skaltu pakka formúlunni þinni inn í IFERROR aðgerðina svona:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

Hvernig þessar formúlur virka

Hér að neðan er ítarleg sundurliðun af fyrstu formúlunni sem raðar gildunum eftir röð:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Í hjarta formúlunnar notum við INDEX fallið til að fá gildi reits byggt á hlutfallslegri staðsetningu hennar í bil.

línunúmerið er reiknað út með þessari formúlu:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Hugmyndin er að búa til endurtekna talnaröð eins og 1,1 ,1,2,2,2,3,3,3, … þar sem hver tala endurtekur sig eins oft og það eru dálkar á upprunasviðinu. Og svona gerum við þetta:

QUOTIENT skilar heiltöluhluta deilingar.

Fyrir teljara notum við COLUMN(A1)-1, sem skilar röð tala frá 0 í fyrsta hólfinu þar sem formúlan er slegin inn í n (heildarfjöldi gilda á bilinumínus 1) í síðasta hólfinu þar sem formúlan kom inn. Í þessu dæmi höfum við 0 í E2 og 8 í M3.

Fyrir nefnara notum við COLUMNS($A$3:$C$5)). Þetta skilar föstu númeri sem jafngildir fjölda dálka á bilinu þínu (3 í okkar tilfelli).

Þar af leiðandi skilar QUOTIENT fallið 0 í fyrstu 3 reitunum (E3:G3), sem við bætið við 1, þannig að línunúmerið er 1.

Fyrir næstu 3 hólf (H3:J3) skilar QUOTIENT 1 og +1 gefur línunúmerið 2. Og svo framvegis.

Til að reikna dálkanúmerið byggir þú viðeigandi talnarunu með því að nota MOD fallið:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Þar sem það eru 3 dálkar á bilinu okkar verður röðin að líta út eins og : 1,2,3,1,2,3,…

MOD fallið skilar afganginum eftir skiptingu.

Í E3, MOD(COLUMN(A1)-1, COLUMNS($ A$3:$C$5))+

verður

MOD(1-1, 3)+1)

og skilar 1.

Í F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

verður

MOD(2-1, 3)+1)

og skilar 2.

Þegar röð og dálknúmer hafa verið staðfest, sækir INDEX gildið auðveldlega á mótum þeirrar línu og dálks.

Í E3, INDEX($A$3 :$C$5, 1, 1) skilar gildi úr 1. línu og 1. dálki úr reit A3.

Í F3, INDEX($A$3:$C$5, 1, 2) skilar gildi úr 1. línu og 2. dálki, þ.e. úr reit B3.

Og svo framvegis.

Önnur formúlan sem skannar svið eftir dálki, virkar ísvipaðan hátt. Munurinn er sá að við notum MOD til að reikna út línunúmerið og QUOTIENT til að finna út dálknúmerið.

TOROW aðgerðin virkar ekki

Ef TOROW aðgerðin leiðir til villu, þá er það líklegast ein af þessum ástæðum:

#NAME? villa

Með flestum Excel aðgerðum er #NAME? villa er skýr vísbending um að nafn fallsins sé rangt stafsett. Með TOROW getur það líka þýtt að aðgerðin sé ekki tiltæk í Excel. Ef Excel útgáfan þín er í öðru en 365, reyndu að nota TOROW valkost.

#NUM villa

#NUM villa gefur til kynna að fylkið sem skilað er getur ekki passað inn í röð. Oftast gerist það þegar þú vísar í heila dálka og/eða raðir í stað minna sviðs.

#SPILL villa

Í flestum tilfellum bendir #SPILL villa til þess að röðin sé þar sem þú hefur slegið inn formúluna hefur ekki nægilega auða reiti til að hella niðurstöðunum inn í. Ef nærliggjandi hólf eru sjónrænt tóm skaltu ganga úr skugga um að engin bil séu í þeim eða aðrir stafir sem ekki eru prentaðir. Fyrir frekari upplýsingar, sjá Hvað #SPILL villa þýðir í Excel.

Þannig notarðu TOROW fallið í Excel til að breyta tvívíðu fylki eða svið í eina röð. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Æfingabók til niðurhals

Excel TOROW aðgerð - formúludæmi (.xlsx skrá)