ວິ​ທີ​ທີ່​ໄວ​ທີ່​ຈະ​ປ່ຽນ​ຊ່ວງ​ຂອງ​ເຊ​ລ​ເປັນ​ແຖວ​ດຽວ​ດ້ວຍ​ການ​ຊ່ວຍ​ເຫຼືອ​ຂອງ​ຟັງ​ຊັນ TOROW .

Microsoft Excel 365 ໄດ້​ນຳ​ສະ​ເໜີ​ໜ້າ​ທີ່​ໃໝ່​ຫຼາຍ​ຢ່າງ. ເພື່ອປະຕິບັດການຫມູນໃຊ້ຕ່າງໆກັບ arrays. ດ້ວຍ TOROW, ທ່ານສາມາດປະຕິບັດການຫັນປ່ຽນຈາກແຖວຕໍ່ແຖວໄດ້ໃນເວລາບໍ່ດົນ. ນີ້ແມ່ນລາຍການໜ້າວຽກທີ່ຟັງຊັນໃໝ່ນີ້ສາມາດເຮັດໄດ້:

ຟັງຊັນ Excel TOROW

ຟັງຊັນ TOROW ໃນ Excel ແມ່ນໃຊ້ເພື່ອປ່ຽນອາເຣ ຫຼືໄລຍະຂອງເຊລເປັນ. ແຖວໜຶ່ງ.

ຟັງຊັນຈະໃຊ້ທັງໝົດສາມອາກິວເມັນ, ເຊິ່ງມີພຽງອັນທຳອິດທີ່ຕ້ອງການ.

TOROW(array, [ignore], [scan_by_column])

ບ່ອນທີ່:

Array (ຕ້ອງການ) - array ຫຼືໄລຍະເພື່ອປ່ຽນເປັນແຖວດຽວ. ຄວາມຜິດພາດ. ສາມາດເອົາໜຶ່ງໃນຄ່າເຫຼົ່ານີ້:

• 0 ຫຼືຖືກລະເວັ້ນ (ຄ່າເລີ່ມຕົ້ນ) - ຮັກສາຄ່າທັງໝົດ
• 1 - ignore blanks
• 2 - ignore errors
• 3 - ignore blanks and errors

Scan_by_column (ທາງເລືອກ) - ກໍານົດວິທີການສະແກນ array:

• FALSE ຫຼື omitted (ຄ່າເລີ່ມຕົ້ນ) - ສະແກນອາເຣຕາມແນວນອນຕາມແຖວ.
• TRUE - ສະແກນອາເຣຕາມແນວຕັ້ງຕາມຖັນ.

ເຄັດລັບ:

• ເພື່ອປ່ຽນອາເຣ ເຂົ້າໄປໃນຖັນດຽວ, ໃຊ້ຟັງຊັນ TOCOL.
• ເພື່ອເຮັດການປ່ຽນແຖວເປັນແຖວແບບປີ້ນກັບແຖວ, ໃຫ້ໃຊ້ຟັງຊັນ WRAPCOLS ເພື່ອຫໍ່ເປັນຖັນ ຫຼືຟັງຊັນ WRAPROWS ເພື່ອຫໍ່.array ເປັນແຖວ.
• ເພື່ອປ່ຽນແຖວເປັນຖັນ, ໃຫ້ໃຊ້ຟັງຊັນ TRANSPOSE.

TOROW available

TOROW ແມ່ນຟັງຊັນໃໝ່, ເຊິ່ງຮອງຮັບໃນ Excel ເທົ່ານັ້ນ. ສໍາລັບ Microsoft 365 (ສໍາລັບ Windows ແລະ Mac) ແລະ Excel ສໍາລັບເວັບ.

ສູດ TOROW ພື້ນຖານໃນ Excel

ເພື່ອເຮັດການຫັນປ່ຽນໄລຍະຕໍ່ແຖວແບບງ່າຍດາຍ, ໃຫ້ໃຊ້ສູດ TOROW ໃນຮູບແບບພື້ນຖານຂອງມັນ. ເພື່ອເຮັດສິ່ງນີ້, ທ່ານຕ້ອງກໍານົດພຽງແຕ່ argument ທໍາອິດ ( array ). ສູດແມ່ນ:

=TOROW(A3:C6)

ທ່ານໃສ່ສູດເຂົ້າໄປໃນພຽງແຕ່ຫນຶ່ງເຊນ (A10 ໃນກໍລະນີຂອງພວກເຮົາ), ແລະມັນອັດຕະໂນມັດ spills ເຂົ້າໄປໃນຫຼາຍເຊນຕາມຄວາມຕ້ອງການເພື່ອເກັບຜົນໄດ້ຮັບທັງຫມົດ. ໃນຄໍາສັບຂອງ Excel, ຂອບເຂດຜົນຜະລິດທີ່ອ້ອມຮອບດ້ວຍຂອບສີຟ້າບາງໆເອີ້ນວ່າໄລຍະການຮົ່ວໄຫຼ.

ສູດ​ນີ້​ເຮັດ​ວຽກ​ແນວ​ໃດ:

ອັນ​ທຳ​ອິດ, ຊ່ວງ​ຂອງ​ເຊ​ລ​ທີ່​ໃຫ້​ມາ​ຖືກ​ປ່ຽນ​ໄປ​ເປັນ​ອາ​ເຣ​ສອງ​ມິ​ຕິ​ລະ​ດັບ. ກະລຸນາສັງເກດຖັນທີ່ຂັ້ນດ້ວຍເຄື່ອງໝາຍຈຸດ ແລະແຖວທີ່ຂັ້ນດ້ວຍເຄື່ອງໝາຍຈຸດ:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

ຈາກນັ້ນ, ຟັງຊັນ TOROW ຈະອ່ານອາເຣຈາກຊ້າຍໄປຂວາ ແລະປ່ຽນເປັນອາເຣແນວນອນໜຶ່ງມິຕິ:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

ຜົນ​ໄດ້​ຮັບ​ໄປ​ຫາ​ເຊ​ລ A10, ຈາກ​ທີ່​ມັນ​ຮົ່ວ​ເຂົ້າ​ໄປ​ໃນ​ຕາ​ລາງ​ໃກ້​ຄຽງ​ທາງ​ດ້ານ​ຂວາ.

ການ​ປ່ຽນ​ຂອບ​ເຂດ​ເປັນ​ແຖວ​ໂດຍ​ບໍ່​ສົນ​ກັບ​ຊ່ອງ​ຫວ່າງ​ແລະ​ຄວາມ​ຜິດ​ພາດ

ໂດຍຄ່າເລີ່ມຕົ້ນ, ຟັງຊັນ TOROW ຈະຮັກສາຄ່າທັງໝົດຈາກ array ແຫຼ່ງ, ລວມທັງເຊລເປົ່າ ແລະຄວາມຜິດພາດ. ໃນຜົນໄດ້ຮັບ, ຄ່າສູນຈະປາກົດຢູ່ໃນສະຖານທີ່ຂອງຕາລາງຫວ່າງເປົ່າ, ເຊິ່ງອາດຈະສັບສົນຫຼາຍ.

ເພື່ອ ຍົກເວັ້ນຊ່ອງຫວ່າງ , ໃຫ້ຕັ້ງອາກິວເມັນ ບໍ່ສົນໃຈ ເປັນ 1:

=TOROW(A3:C5, 1)

ເພື່ອ ບໍ່ສົນໃຈຂໍ້ຜິດພາດ , ໃຫ້ຕັ້ງອາກິວເມັນ ບໍ່ສົນໃຈ ເປັນ 2:

=TOROW(A3:C5, 2)

ເພື່ອຂ້າມ. ທັງສອງ, ຫວ່າງເປົ່າ ແລະຂໍ້ຜິດພາດ , ໃຊ້ 3 ສໍາລັບການໂຕ້ແຍ້ງ ລະເລີຍ :

=TOROW(A3:C5, 3)

ຮູບພາບຂ້າງລຸ່ມນີ້ສະແດງໃຫ້ເຫັນທັງສາມສະຖານະການໃນການປະຕິບັດ: <18

ອ່ານ array ລວງນອນ ຫຼືແນວຕັ້ງ

ດ້ວຍພຶດຕິກຳເລີ່ມຕົ້ນ, ຟັງຊັນ TOROW ຈະປະມວນຜົນອາເຣຕາມລວງນອນຈາກຊ້າຍຫາຂວາ. ເພື່ອສະແກນຄ່າຕາມຖັນຈາກເທິງຫາລຸ່ມສຸດ, ທ່ານຕັ້ງອາກິວເມັນທີ 3 ( scan_by_column ) ເປັນ TRUE ຫຼື 1.

ຕົວຢ່າງ, ເພື່ອອ່ານແຫຼ່ງທີ່ມາຕາມແຖວ, ສູດໃນ E3 ແມ່ນ:

=TOROW(A3:C5)

ເພື່ອສະແກນໄລຍະໂດຍຖັນ, ສູດໃນ E8 ແມ່ນ:

=TOROW(A3:C5, ,TRUE)

ໃນທັງສອງກໍລະນີ, array ຜົນໄດ້ຮັບແມ່ນ ຂະ​ຫນາດ​ດຽວ​ກັນ​, ແຕ່​ຄ່າ​ແມ່ນ​ຈັດ​ລຽງ​ລໍາ​ດັບ​ທີ່​ແຕກ​ຕ່າງ​ກັນ​.

ຮວມຫຼາຍໄລຍະເຂົ້າກັນເປັນແຖວດຽວ

ເພື່ອລວມເອົາຫຼາຍຊ່ວງທີ່ບໍ່ຢູ່ຕິດກັນເຂົ້າເປັນແຖວດຽວ, ທຳອິດທ່ານວາງພວກມັນຕາມແນວນອນ ຫຼືແນວຕັ້ງເປັນແຖວໜຶ່ງດ້ວຍຄວາມຊ່ວຍເຫຼືອຂອງ HSTACK ຫຼື VSTACK, ຕາມລຳດັບ. , ແລະຈາກນັ້ນໃຊ້ຟັງຊັນ TOROW ເພື່ອປ່ຽນອາເຣລວມກັນເປັນແຖວ.

ຂຶ້ນກັບເຫດຜົນທາງທຸລະກິດຂອງເຈົ້າ, ຫນຶ່ງໃນສູດຕໍ່ໄປນີ້ຈະປະຕິບັດຫນ້າວຽກ.

stack arrays ຕາມລວງນອນ ແລະປ່ຽນໂດຍ ແຖວ

ກັບອັນທໍາອິດໄລຍະໃນ A3:C4 ແລະໄລຍະທີສອງໃນ A8:C9, ສູດຂ້າງລຸ່ມນີ້ຈະ stack ສອງໄລຍະຕາມລວງນອນເຂົ້າໄປໃນອາເຣດຽວ, ແລະຫຼັງຈາກນັ້ນປ່ຽນເປັນແຖວອ່ານຄ່າຈາກຊ້າຍໄປຂວາ. ຜົນໄດ້ຮັບແມ່ນຢູ່ໃນ E3 ໃນຮູບຂ້າງລຸ່ມນີ້.

=TOROW(HSTACK(A3:C4, A8:C9))

Stack arrays ຕາມລວງນອນ ແລະ convert ໂດຍຖັນ

ເພື່ອອ່ານ array stacked ໃນລວງຕັ້ງຈາກເທິງຫາລຸ່ມສຸດ, ທ່ານຕັ້ງອາກິວເມັນທີ 3 ຂອງ TOROW ເປັນ TRUE ດັ່ງທີ່ສະແດງໃນ E5 ໃນຮູບຂ້າງລຸ່ມນີ້:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

ຈັດວາງອາເຣໃນແນວຕັ້ງ ແລະປ່ຽນເປັນແຖວ

ເພື່ອຕໍ່ທ້າຍແຕ່ລະອັນ ຕໍ່ໄປ array ໄປຫາລຸ່ມສຸດຂອງ array ກ່ອນໜ້າ ແລະອ່ານ array ລວມກັນຕາມລວງນອນ, ສູດໃນ E12 ແມ່ນ:

=TOROW(VSTACK(A3:C4, A8:C9))

Stack arrays ລວງຕັ້ງ ແລະ convert by column

ເພື່ອເພີ່ມແຕ່ລະ array ຕໍ່ໆໄປໃສ່ລຸ່ມສຸດຂອງອັນກ່ອນໜ້າ ແລະສະແກນ array ລວມກັນຕາມແນວຕັ້ງ, ສູດແມ່ນ:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

ເພື່ອເຂົ້າໃຈເຫດຜົນໄດ້ດີຂຶ້ນ, ໃຫ້ສັງເກດລໍາດັບຂອງຄ່າທີ່ແຕກຕ່າງກັນໃນ arrays ຜົນໄດ້ຮັບ:

ສະກັດຄ່າທີ່ເປັນເອກະລັກຈາກໄລຍະເປັນແຖວ

ໂດຍເລີ່ມຕົ້ນດ້ວຍ Microsoft Excel 2016, ພວກເຮົາມີຟັງຊັນທີ່ຍອດຢ້ຽມ, ຊື່ວ່າ UNIQUE, ເຊິ່ງສາມາດເອົາຄ່າທີ່ເປັນເອກະລັກຈາກຖັນດຽວໄດ້ຢ່າງງ່າຍດາຍ. ຫຼືແຖວ. ແນວໃດກໍ່ຕາມ, ມັນບໍ່ສາມາດຈັດການອາເຣຫຼາຍຖັນໄດ້. ເພື່ອເອົາຊະນະຂໍ້ຈຳກັດນີ້, ໃຫ້ໃຊ້ຟັງຊັນ UNIQUE ແລະ TOROW ຮ່ວມກັນ.

ຕົວຢ່າງ, ເພື່ອເອົາຄ່າທີ່ແຕກຕ່າງກັນທັງໝົດ (ທີ່ແຕກຕ່າງ) ຈາກຊ່ວງ A2:C7 ແລະຈັດວາງຜົນໄດ້ຮັບໃນແຖວດຽວ,ສູດແມ່ນ:

=UNIQUE(TOROW(A2:C7), TRUE)

ເມື່ອ TOROW ສົ່ງຄືນອາເຣແນວນອນໜຶ່ງມິຕິ, ພວກເຮົາຕັ້ງອາກິວເມັນທີ 2 ( by_col ) ຂອງ UNIQUE ເປັນ TRUE ເພື່ອປຽບທຽບຖັນຕໍ່ກັບແຕ່ລະຖັນ. ອື່ນໆ.

ໃນກໍລະນີທີ່ທ່ານຕ້ອງການໃຫ້ຜົນໄດ້ຮັບຈັດລຽງຕາມລຳດັບຕົວອັກສອນ, ຫໍ່ສູດຄຳນວນຂ້າງເທິງໃນຟັງຊັນ SORT:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

ເຊັ່ນດຽວກັບ UNIQUE, the by_col ອາກິວເມັນຂອງ SORT ຍັງຖືກຕັ້ງເປັນ TRUE.

TOROW ທາງເລືອກສໍາລັບ Excel 365 - 2010

ໃນ Excel ຮຸ່ນທີ່ຟັງຊັນ TOROW ບໍ່ສາມາດໃຊ້ໄດ້, ທ່ານສາມາດປ່ຽນໄລຍະເປັນແຖວດຽວໂດຍໃຊ້ການປະສົມປະສານຂອງຟັງຊັນທີ່ແຕກຕ່າງກັນຈໍານວນຫນຶ່ງທີ່ເຮັດວຽກຢູ່ໃນ. ຮຸ່ນເກົ່າ. ວິທີແກ້ໄຂເຫຼົ່ານີ້ແມ່ນສັບສົນກວ່າ, ແຕ່ພວກມັນເຮັດວຽກໄດ້.

ເພື່ອສະແກນໄລຍະຕາມລວງນອນ, ສູດທົ່ວໄປແມ່ນ:

INDEX( range , QUOTIENT(COLUMN (A1)-1, COLUMNS( range ))+1, MOD(COLUMN(A1)-1, COLUMNS( range )))+1)

ເພື່ອສະແກນໄລຍະແນວຕັ້ງ, ສູດທົ່ວໄປແມ່ນ :

INDEX( ໄລຍະ , MOD(COLUMN(A1)-1, COLUMNS( range ))+1, QUOTIENT(COLUMN (A1)-1, COLUMNS(<15)>range ))+1)

ສຳ​ລັບ​ຊຸດ​ຂໍ້​ມູນ​ຕົວ​ຢ່າງ​ຂອງ​ພວກ​ເຮົາ​ໃນ A3:C5, ສູດ​ຈະ​ໃຊ້​ຮູບ​ແບບ​ນີ້:

ເພື່ອ​ສະ​ແກນ​ໄລ​ຍະ​ຕາມ​ແຖວ:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

ສູດນີ້ແມ່ນເປັນທາງເລືອກຂອງຟັງຊັນ TOROW ທີ່ມີອາກິວເມັນທີ 3 ທີ່ຕັ້ງເປັນ FALSE ຫຼືຖືກລະເວັ້ນ:

=TOROW(A3:C5)

ເພື່ອສະແກນໄລຍະໂດຍ ຖັນ:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

ສູດນີ້ທຽບເທົ່າກັບຟັງຊັນ TOROW ກັບອາກິວເມັນທີ 3 ທີ່ຕັ້ງເປັນTRUE:

=TOROW(A3:C5, ,TRUE)

ກະລຸນາຮັບຊາບວ່າບໍ່ຄືກັບຟັງຊັນ TOROW ແບບໄດນາມິກ, ສູດສູດດັ້ງເດີມເຫຼົ່ານີ້ຄວນຈະຖືກໃສ່ໃນແຕ່ລະຕາລາງທີ່ທ່ານຕ້ອງການໃຫ້ຜົນໄດ້ຮັບປາກົດ. ໃນກໍລະນີຂອງພວກເຮົາ, ສູດທໍາອິດ (ໂດຍແຖວ) ໄປຫາ E3 ແລະຖືກຄັດລອກຜ່ານ M3. ສູດທີສອງ (ໂດຍຖັນ) ລົງຈອດຢູ່ໃນ E8 ແລະຖືກລາກຜ່ານ M8.

ເພື່ອໃຫ້ສູດການຄັດລອກຢ່າງຖືກຕ້ອງ, ພວກເຮົາລັອກຂອບເຂດໂດຍໃຊ້ການອ້າງອີງຢ່າງແທ້ຈິງ ($A$3:$C$5). ໄລຍະທີ່ມີຊື່ກໍ່ຈະເຮັດໄດ້ເຊັ່ນກັນ.

ຖ້າທ່ານໄດ້ສຳເນົາສູດຄຳນວນໄປໃສ່ຕາລາງຫຼາຍກວ່າທີ່ຕ້ອງການ, #REF! ຂໍ້ຜິດພາດຈະປາກົດຢູ່ໃນຈຸລັງ "ພິເສດ". ເພື່ອແກ້ໄຂບັນຫານີ້, ຫໍ່ສູດຂອງທ່ານໃນຟັງຊັນ IFERROR ແບບນີ້:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

ສູດເຫຼົ່ານີ້ເຮັດວຽກແນວໃດ

ຂ້າງລຸ່ມນີ້ແມ່ນການແບ່ງຂັ້ນລາຍລະອຽດ ຂອງສູດທໍາອິດທີ່ຈັດລຽງຄ່າໂດຍແຖວ:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

ຢູ່ໃນຫົວໃຈຂອງສູດ, ພວກເຮົາໃຊ້ຟັງຊັນ INDEX ເພື່ອໃຫ້ໄດ້ຮັບຄ່າຂອງເຊລໂດຍອີງຕາມຕໍາແຫນ່ງທີ່ກ່ຽວຂ້ອງຂອງມັນຢູ່ໃນ ໄລຍະ.

ເລກແຖວ ຖືກຄິດໄລ່ໂດຍສູດນີ້:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

ແນວຄວາມຄິດແມ່ນເພື່ອສ້າງລໍາດັບຕົວເລກຊໍ້າຄືນເຊັ່ນ 1,1. ,1,2,2,2,3,3,3, … ເຊິ່ງແຕ່ລະຕົວເລກຈະຊໍ້າຄືນຫຼາຍເທື່ອເທົ່າທີ່ມີຖັນຢູ່ໃນຂອບເຂດແຫຼ່ງ. ແລະນີ້ຄືວິທີທີ່ພວກເຮົາເຮັດອັນນີ້:

QUOTIENT ຕອບຄ່າຈຳນວນເຕັມຂອງການຫານ.

ສຳລັບ ຕົວເລກ , ພວກເຮົາໃຊ້ COLUMN(A1)-1, ເຊິ່ງໃຫ້ຄ່າເປັນ serial. ຕົວເລກຈາກ 0 ໃນຕາລາງທຳອິດທີ່ສູດຄຳນວນຖືກໃສ່ເປັນ n (ຈຳນວນທັງໝົດຂອງຄ່າໃນໄລຍະລົບ 1) ໃນເຊລສຸດທ້າຍທີ່ສູດຄຳນວນເຂົ້າມາ. ໃນຕົວຢ່າງນີ້, ພວກເຮົາມີ 0 ໃນ E2 ແລະ 8 ໃນ M3.

ສຳລັບ ຕົວຫານ , ພວກເຮົາໃຊ້ COLUMNS($A$3:$C$5)). ອັນນີ້ໃຫ້ຜົນເປັນຈໍານວນຄົງທີ່ເທົ່າກັບຈໍານວນຖັນໃນໄລຍະຂອງທ່ານ (3 ໃນກໍລະນີຂອງພວກເຮົາ).

ຜົນ, ຟັງຊັນ QUOTIENT ຕອບ 0 ໃນ 3 ເຊລທໍາອິດ (E3:G3), ທີ່ພວກເຮົາ. ເພີ່ມ 1, ດັ່ງນັ້ນຕົວເລກແຖວແມ່ນ 1.

ສຳລັບ 3 ຕາລາງຕໍ່ໄປ (H3:J3), QUOTIENT ຕອບເປັນ 1, ແລະ +1 ໃຫ້ເລກແຖວ 2. ແລະອື່ນໆ.

ເພື່ອຄິດໄລ່ ຖັນຕົວເລກ , ທ່ານສ້າງລໍາດັບຕົວເລກທີ່ເຫມາະສົມໂດຍໃຊ້ຟັງຊັນ MOD:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

ເນື່ອງຈາກມີ 3 ຖັນຢູ່ໃນຂອບເຂດຂອງພວກເຮົາ, ລໍາດັບຕ້ອງມີລັກສະນະຄື. : 1,2,3,1,2,3,…

ຟັງຊັນ MOD ສົ່ງຄືນສ່ວນທີ່ເຫຼືອຫຼັງຈາກການແບ່ງ.

ໃນ E3, MOD(COLUMN(A1)-1, COLUMNS($ A$3:$C$5))+

ກາຍເປັນ

MOD(1-1, 3)+1)

ແລະກັບຄືນ 1.

ໃນ F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

ກາຍເປັນ

MOD(2-1, 3)+1)

ແລະກັບຄືນ 2.

ເມື່ອຕັ້ງຕົວເລກແຖວ ແລະຖັນແລ້ວ, INDEX ຈະເອົາຄ່າຢູ່ຈຸດຕັດກັນຂອງແຖວ ແລະຖັນນັ້ນໄດ້ຢ່າງງ່າຍດາຍ.

ໃນ E3, INDEX($A$3 :$C$5, 1, 1) ຕອບຄ່າຈາກແຖວທີ 1 ແລະຖັນທີ 1 ຂອງຂອບເຂດທີ່ອ້າງອີງ, ເຊັ່ນ: ຈາກຕາລາງ A3.

ໃນ F3, INDEX($A$3:$C$5, 1, 2) ຕອບຄ່າຈາກແຖວທີ 1 ແລະຖັນທີ 2, ເຊັ່ນ: ຈາກຕາລາງ B3.

ແລະອື່ນໆ.

ສູດທີສອງທີ່ສະແກນໄລຍະໂດຍຖັນ, ເຮັດວຽກຢູ່ໃນວິທີທີ່ຄ້າຍຄືກັນ. ຄວາມແຕກຕ່າງຄືພວກເຮົາໃຊ້ MOD ເພື່ອຄິດໄລ່ເລກແຖວ ແລະ QUOTIENT ເພື່ອຄິດໄລ່ເລກຖັນ. ສ່ວນຫຼາຍອາດຈະເປັນເຫດຜົນເຫຼົ່ານີ້:

#NAME? ຜິດພາດ

ກັບຟັງຊັນ Excel ສ່ວນໃຫຍ່, ເປັນ #NAME ບໍ? ຄວາມຜິດພາດເປັນຕົວຊີ້ບອກທີ່ຊັດເຈນວ່າຊື່ຂອງຟັງຊັນຖືກສະກົດຜິດ. ດ້ວຍ TOROW, ມັນອາດຈະຫມາຍຄວາມວ່າຟັງຊັນບໍ່ມີຢູ່ໃນ Excel ຂອງທ່ານ. ຖ້າ Excel ຂອງທ່ານໃນເວີຊັນອື່ນນອກເໜືອໄປຈາກ 365, ໃຫ້ລອງໃຊ້ທາງເລືອກ TOROW.

#NUM ຂໍ້ຜິດພາດ

ຂໍ້ຜິດພາດ #NUM ຊີ້ບອກວ່າອາເຣທີ່ສົ່ງຄືນບໍ່ສາມາດເຂົ້າແຖວໄດ້. ສ່ວນຫຼາຍມັກຈະເກີດຂຶ້ນເມື່ອທ່ານອ້າງອີງຖັນ ແລະ/ຫຼືແຖວທັງໝົດ ແທນທີ່ຈະເປັນໄລຍະທີ່ນ້ອຍກວ່າ.

ຄວາມຜິດພາດ #SPILL

ໃນກໍລະນີຫຼາຍທີ່ສຸດ, ຄວາມຜິດພາດ #SPILL ແນະນໍາວ່າແຖວທີ່ຢູ່ ທ່ານ​ໄດ້​ເຂົ້າ​ໄປ​ໃນ​ສູດ​ບໍ່​ມີ​ຈຸ​ລັງ​ເປົ່າ​ພຽງ​ພໍ​ທີ່​ຈະ​ຮົ່ວ​ຜົນ​ໄດ້​ຮັບ​ເຂົ້າ​ໄປ​ໃນ​. ຖ້າຈຸລັງໃກ້ຄຽງຫວ່າງເປົ່າ, ໃຫ້ແນ່ໃຈວ່າບໍ່ມີຊ່ອງຫວ່າງຫຼືຕົວອັກສອນອື່ນໆທີ່ບໍ່ໄດ້ພິມຢູ່ໃນພວກມັນ. ສໍາລັບຂໍ້ມູນເພີ່ມເຕີມ, ເບິ່ງວ່າຄວາມຜິດພາດ #SPILL ຫມາຍຄວາມວ່າແນວໃດໃນ Excel.

ນັ້ນແມ່ນວິທີທີ່ທ່ານໃຊ້ຟັງຊັນ TOROW ໃນ Excel ເພື່ອປ່ຽນອາເຣ 2 ມິຕິ ຫຼືໄລຍະເປັນແຖວດຽວ. ຂ້າພະເຈົ້າຂໍຂອບໃຈທ່ານສໍາລັບການອ່ານແລະຫວັງວ່າຈະໄດ້ພົບທ່ານໃນ blog ຂອງພວກເຮົາໃນອາທິດຕໍ່ໄປ! 3>