Ffordd gyflym o droi ystod o gelloedd yn un rhes gyda chymorth ffwythiant TOROW .

Mae Microsoft Excel 365 wedi cyflwyno sawl swyddogaeth newydd i berfformio manipulations amrywiol gyda araeau. Gyda TOROW, gallwch chi berfformio trawsnewidiadau ystod-i-rhes mewn dim o amser. Dyma restr o dasgau y gall y swyddogaeth newydd hon eu cyflawni:

Swyddogaeth Excel TOROW

Defnyddir y ffwythiant TOROW yn Excel i drosi arae neu ystod o gelloedd yn un rhes.

Mae'r ffwythiant yn cymryd cyfanswm o dair dadl, a dim ond yr un gyntaf sydd ei hangen.

TOROW(arae, [anwybyddu], [scan_by_column])

Ble:

Arae (gofynnol) - arae neu ystod i'w thrawsnewid yn un rhes.

Anwybyddu (dewisol) - yn penderfynu a ddylid anwybyddu bylchau neu/a gwallau. Yn gallu cymryd un o'r gwerthoedd hyn:

• 0 neu wedi'i hepgor (rhagosodedig) - cadw pob gwerth
• 1 - anwybyddu bylchau
• 2 - anwybyddu gwallau
• 3 - anwybyddu bylchau a gwallau

Scan_by_column (dewisol) - yn diffinio sut i sganio'r arae:

• FALSE neu wedi'i hepgor (diofyn) - sganiwch yr arae yn llorweddol fesul rhes.
• CYWIR - sganiwch yr arae yn fertigol fesul colofn.

Awgrymiadau:

• I drawsnewid arae i mewn i un golofn, defnyddiwch y ffwythiant TOCOL.
• I ragffurfio'r trawsnewidiad rhes-i-arae o chwith, defnyddiwch naill ai'r ffwythiant WRAPCOLS i lapio mewn colofnau neu'r ffwythiant WRAPROWS i lapioarae yn rhesi.
• I droi rhesi yn golofnau, defnyddiwch y ffwythiant TRANSPOSE.

Argaeledd TOROW

Swyddogaeth newydd yw TOROW, a gefnogir yn Excel yn unig ar gyfer Microsoft 365 (ar gyfer Windows a Mac) ac Excel ar gyfer y we.

Fformiwla TOROW sylfaenol yn Excel

I wneud trawsnewidiad ystod-i-rhes syml, defnyddiwch y fformiwla TOROW yn ei ffurf sylfaenol. Ar gyfer hyn, dim ond y ddadl gyntaf y mae angen i chi ei diffinio ( arae ).

Er enghraifft, i droi arae dau ddimensiwn sy'n cynnwys 3 colofn a 3 rhes yn un rhes, mae'r y fformiwla yw:

=TOROW(A3:C6)

Rydych chi'n mewnbynnu'r fformiwla i un gell yn unig (A10 yn ein hachos ni), ac mae'n arllwys yn awtomatig i gynifer o gell ag sydd ei angen i ddal yr holl ganlyniadau. Yn nhermau Excel, gelwir yr ystod allbwn sydd wedi'i amgylchynu gan ffin las denau yn ystod gollyngiad.

Sut mae'r fformiwla hon yn gweithio:

Yn gyntaf, mae ystod o gelloedd a gyflenwir yn cael ei drawsnewid yn arae dau ddimensiwn. Sylwch ar y colofnau sydd wedi'u hamffinio gan goma a'r rhesi wedi'u gwahanu â hanner colon:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

Yna, mae'r swyddogaeth TOROW yn darllen yr arae o'r chwith i'r dde ac yn ei throsi'n arae llorweddol un dimensiwn:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

Mae'r canlyniad yn mynd i gell A10, lle mae'n arllwys i'r gell gyfagos ar y dde.

Trawsnewid ystod i res gan anwybyddu bylchau a gwallau

Yn ddiofyn, mae'r swyddogaeth TOROW yn cadw'r holl werthoedd o'r arae ffynhonnell, gan gynnwys celloedd gwag agwallau. Yn yr allbwn, mae gwerthoedd sero yn ymddangos yn lle celloedd gwag, a all fod yn eithaf dryslyd.

I hepgor bylchau , gosodwch y ddadl anwybyddu i 1:

=TOROW(A3:C5, 1)

I anwybyddu gwallau , gosodwch y ddadl anwybyddu i 2:

=TOROW(A3:C5, 2)

I neidio y ddau, bylchau a gwallau , defnyddiwch 3 ar gyfer y ddadl anwybyddu :

=TOROW(A3:C5, 3)

Mae'r ddelwedd isod yn dangos y tri senario ar waith: <18

Darllen arae yn llorweddol neu'n fertigol

Gyda'r ymddygiad rhagosodedig, mae'r ffwythiant TOROW yn prosesu'r arae yn llorweddol o'r chwith i'r dde. I sganio'r gwerthoedd fesul colofn o'r top i'r gwaelod, rydych chi'n gosod y 3edd arg ( scan_by_column ) i TRUE neu 1.

Er enghraifft, i ddarllen yr ystod ffynhonnell fesul rhes, mae'r fformiwla yn E3 yw:

=TOROW(A3:C5)

I sganio'r amrediad fesul colofn, y fformiwla yn E8 yw:

=TOROW(A3:C5, ,TRUE)

Yn y ddau achos, yr araeau canlyniadol yw yr un maint, ond trefnir y gwerthoedd mewn trefn wahanol.

Cyfuno ystodau lluosog yn un rhes

I gyfuno nifer o ystodau nad ydynt yn gyfagos yn un rhes, yn gyntaf rydych yn eu pentyrru yn llorweddol neu'n fertigol i mewn i gyfres sengl gyda chymorth HSTACK neu VSTACK, yn y drefn honno , ac yna defnyddiwch y ffwythiant TOROW i drosi'r arae gyfun yn rhes.

Yn dibynnu ar resymeg eich busnes, bydd un o'r fformiwlâu canlynol yn cyflawni'r dasg.

Stack araeau yn llorweddol a throsi gan rhes

Gyda'r cyntafamrediad yn A3:C4 a'r ail amrediad yn A8:C9, bydd y fformiwla isod yn pentyrru'r ddwy ystod yn llorweddol yn arae sengl, ac yna'n ei drawsnewid yn rhes gan ddarllen y gwerthoedd o'r chwith i'r dde. Mae'r canlyniad yn E3 yn y ddelwedd isod.

=TOROW(HSTACK(A3:C4, A8:C9))

Stack araeau yn llorweddol a throsi fesul colofn

I ddarllen yr arae wedi'i bentyrru yn fertigol o'r top i'r gwaelod, Rydych chi'n gosod y 3edd arg o TOROW i TRUE fel y dangosir yn E5 yn y ddelwedd isod:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

Pentyrru araeau yn fertigol a throsi fesul rhes

I atodi pob un arae dilynol i waelod yr arae flaenorol a darllenwch yr arae gyfun yn llorweddol, y fformiwla yn E12 yw:

=TOROW(VSTACK(A3:C4, A8:C9))

Stack araeau yn fertigol a throsi fesul colofn

I adio pob arae ddilynol i waelod yr un blaenorol a sganio'r arae gyfun yn fertigol, y fformiwla yw:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

I ddeall y rhesymeg yn well, arsylwch y drefn wahanol o werthoedd yn yr araeau canlyniadol:

Tynnu gwerthoedd unigryw o ystod i res

Gan ddechrau gyda Microsoft Excel 2016, mae gennym swyddogaeth wych, o'r enw UNIGRYW, sy'n gallu cael gwerthoedd unigryw yn hawdd o un golofn neu rhes. Fodd bynnag, ni all drin araeau aml-golofn. I oresgyn y cyfyngiad hwn, defnyddiwch y ffwythiannau UNIGRYW a TOROW gyda'i gilydd.

Er enghraifft, i echdynnu'r holl werthoedd gwahanol (neilltuol) o'r ystod A2:C7 a gosod y canlyniadau mewn un rhes, mae'ry fformiwla yw:

=UNIQUE(TOROW(A2:C7), TRUE)

Wrth i TOROW ddychwelyd arae lorweddol un-dimensiwn, rydym yn gosod yr 2il arg ( by_col ) o UNIGRYW i WIR i gymharu'r colofnau yn erbyn pob un arall.

Rhag ofn eich bod am i'r canlyniadau gael eu trefnu yn nhrefn yr wyddor, lapiwch y fformiwla uchod yn y ffwythiant SORT:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

Fel yn UNIGRYW, mae'r by_col Mae dadl SORT hefyd wedi'i gosod yn WIR.

dewis arall TOROW ar gyfer Excel 365 - 2010

Mewn fersiynau Excel lle nad yw'r swyddogaeth TOROW ar gael, gallwch drawsnewid ystod yn un rhes gan ddefnyddio cyfuniad o ychydig o swyddogaethau gwahanol sy'n gweithio ynddynt fersiynau hŷn. Mae'r datrysiadau hyn yn fwy cymhleth, ond maen nhw'n gweithio.

I sganio'r amrediad yn llorweddol, y fformiwla generig yw:

INDEX( ystod , QUOTIENT(COLOFN (A1)-1, COLUMNS( ystod ))+1, MOD(COLUMN(A1)-1, COLUMNS( range ))+1)

I sganio'r amrediad yn fertigol, y fformiwla generig yw :

MYNEGAI( ystod , MOD(COLOFN(A1)-1, COLOFN( ystod )))+1, QUOTIENT(COLOFN(A1)-1, COLUMNS(<15)>ystod ))+1)

Ar gyfer ein set ddata sampl yn A3:C5, mae'r fformiwlâu yn cymryd y siâp hwn:

I sganio'r amrediad fesul rhes:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Mae'r fformiwla hon yn ddewis arall i'r ffwythiant TOROW gyda'r 3edd arg wedi'i gosod i ANGHYWIR neu wedi'i hepgor:

=TOROW(A3:C5)

I sganio'r amrediad erbyn colofn:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Mae'r fformiwla hon yn cyfateb i'r ffwythiant TOROW gyda'r 3edd arg wedi ei gosod iCYWIR:

=TOROW(A3:C5, ,TRUE)

Sylwch, yn wahanol i'r ffwythiant TOROW arae deinamig, y dylid rhoi'r fformiwlâu traddodiadol hyn ym mhob cell lle rydych am i'r canlyniadau ymddangos. Yn ein hachos ni, mae'r fformiwla gyntaf (yn ôl rhes) yn mynd i E3 ac yn cael ei chopïo trwy M3. Mae'r ail fformiwla (fesul colofn) yn glanio yn E8 ac yn cael ei llusgo trwy M8.

Er mwyn i'r fformiwlâu gopïo'n gywir, rydym yn cloi'r amrediad gan ddefnyddio cyfeirnodau absoliwt ($A$3:$C$5). Bydd amrediad a enwir hefyd yn gwneud hynny.

Os ydych chi wedi copïo'r fformiwlâu i fwy o gelloedd nag sydd angen, mae #REF! bydd gwall yn ymddangos mewn celloedd "ychwanegol". I drwsio hyn, amlapiwch eich fformiwla yn y ffwythiant IFERROR fel hyn:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

Sut mae'r fformiwlâu hyn yn gweithio

Isod mae dadansoddiad manwl o'r fformiwla gyntaf sy'n trefnu'r gwerthoedd fesul rhes:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Wrth wraidd y fformiwla, rydym yn defnyddio'r ffwythiant MYNEGAI i gael gwerth cell yn seiliedig ar ei safle cymharol yn y amrediad.

Caiff y rhif rhes ei gyfrifo gan y fformiwla hon:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Y syniad yw cynhyrchu dilyniant rhif sy'n ailadrodd fel 1,1 ,1,2,2,2,3,3,3, … lle mae pob rhif yn ailadrodd cymaint o weithiau ag y mae colofnau yn yr ystod ffynhonnell. A dyma sut rydym yn gwneud hyn: Mae

QUOTIENT yn dychwelyd cyfran gyfanrif rhaniad.

Ar gyfer rhifiadur , rydym yn defnyddio COLUMN(A1)-1, sy'n dychwelyd cyfres rhif o 0 yn y gell gyntaf lle rhoddir y fformiwla i n (cyfanswm nifer y gwerthoedd yn yr amrediadminws 1) yn y gell olaf lle cofnodwyd y fformiwla. Yn yr enghraifft hon, mae gennym ni 0 yn E2 ac 8 yn M3.

Ar gyfer enwadur , rydyn ni'n defnyddio COLUMNS($A$3:$C$5)). Mae hyn yn dychwelyd rhif cyson sy'n hafal i nifer y colofnau yn eich amrediad (3 yn ein hachos ni).

O ganlyniad, mae'r ffwythiant QUOTIENT yn dychwelyd 0 yn y 3 cell cyntaf (E3:G3), yr ydym ni adio 1, felly rhif y rhes yw 1.

Ar gyfer y 3 cell nesaf (H3:J3), mae QUOTIENT yn dychwelyd 1, a +1 yn rhoi rhif rhes 2. Ac yn y blaen.

I gyfrifo'r rhif colofn , rydych yn adeiladu dilyniant rhif priodol gan ddefnyddio'r ffwythiant MOD:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Gan fod 3 colofn yn ein hystod, rhaid i'r dilyniant edrych fel : 1,2,3,1,2,3,…

Mae ffwythiant y Weinyddiaeth Amddiffyn yn dychwelyd y gweddill ar ôl rhannu.

Yn E3, MOD(COLUMN(A1)-1, COLUMNS($ A$3:$C$5))+

yn dod yn

MOD(1-1, 3)+1)

ac yn dychwelyd 1.

Yn F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

yn dod yn

MOD(2-1, 3)+1)

ac yn dychwelyd 2.

Unwaith y bydd y rhifau rhes a cholofn wedi'u sefydlu, mae MYNEGAI yn nôl y gwerth yn hawdd ar groesffordd y rhes a'r golofn honno.

Yn E3, INDEX($A$3 :$C$5, 1, 1) yn dychwelyd gwerth o'r rhes 1af a'r golofn 1af o'r ystod y cyfeirir ati, h.y. o gell A3.

Yn F3, mae INDEX($A$3:$C$5, 1, 2) yn dychwelyd gwerth o'r rhes 1af a'r 2il golofn, h.y. o gell B3.

Ac yn y blaen.

Mae'r ail fformiwla sy'n sganio'r amrediad fesul colofn, yn gweithio mewn affordd debyg. Y gwahaniaeth yw ein bod yn defnyddio MOD i gyfrifo'r rhif rhes a QUOTIENT i gyfrifo rhif y golofn.

Swyddogaeth TOROW ddim yn gweithio

Os yw'r ffwythiant TOROW yn arwain at wall, mae'n yn fwyaf tebygol o fod yn un o'r rhesymau hyn:

#NAME? gwall

Gyda'r rhan fwyaf o swyddogaethau Excel, mae #NAME? gwall yn arwydd clir bod enw'r ffwythiant wedi'i gamsillafu. Gyda TOROW, gall hefyd olygu nad yw'r swyddogaeth ar gael yn eich Excel. Os yw eich fersiwn Excel mewn heblaw 365, ceisiwch ddefnyddio dewis arall TOROW.

#NUM error

Mae gwall #NUM yn nodi na all yr arae a ddychwelwyd ffitio i mewn i res. Gan amlaf mae hynny'n digwydd pan fyddwch chi'n cyfeirio at golofnau a/neu resi cyfan yn lle ystod lai.

Gwall #SPILL

Yn y rhan fwyaf o achosion, mae gwall #SPILL yn awgrymu bod y rhes lle Nid oes gennych ddigon o gelloedd gwag i arllwys y canlyniadau iddynt. Os yw'r celloedd cyfagos yn wag yn weledol, gwnewch yn siŵr nad oes unrhyw fylchau neu nodau eraill nad ydynt yn argraffu ynddynt. Am ragor o wybodaeth, gweler Beth mae gwall #SPILL yn ei olygu yn Excel.

Dyna sut rydych chi'n defnyddio'r swyddogaeth TOROW yn Excel i drosi arae neu ystod 2-ddimensiwn yn un rhes. Diolch i chi am ddarllen a gobeithio eich gweld ar ein blog wythnos nesaf!

Gweithlyfr ymarfer i'w lawrlwytho

Swyddogaeth Excel TOROW - enghreifftiau fformiwla (ffeil .xlsx)

<3.3.3.3.3.3.3.3.3.3.3.3.3.