TOROW செயல்பாட்டின் உதவியுடன் கலங்களின் வரம்பை ஒற்றை வரிசையாக மாற்றுவதற்கான விரைவான வழி.

Microsoft Excel 365 பல புதிய செயல்பாடுகளை அறிமுகப்படுத்தியுள்ளது. வரிசைகள் மூலம் பல்வேறு கையாளுதல்களைச் செய்ய. TOROW மூலம், எந்த நேரத்திலும் வரம்பிலிருந்து வரிசை மாற்றங்களைச் செய்யலாம். இந்தப் புதிய செயல்பாடு நிறைவேற்றக்கூடிய பணிகளின் பட்டியல் இதோ:

Excel TOROW செயல்பாடு

Excel இல் உள்ள TOROW செயல்பாடு ஒரு வரிசை அல்லது கலங்களின் வரம்பை மாற்ற பயன்படுகிறது. ஒரு வரிசை.

செயல்பாடு மொத்தம் மூன்று வாதங்களை எடுக்கும், அதில் முதல் ஒன்று மட்டுமே தேவை.

TOROW(array, [ignore], [scan_by_column])

எங்கே:

அணி (அவசியம்) - ஒற்றை வரிசையாக மாற்ற ஒரு வரிசை அல்லது வரம்பு.

புறக்கணிப்பு (விரும்பினால்) - வெற்றிடங்களை புறக்கணிக்க வேண்டுமா அல்லது/மற்றும் பிழைகள். இந்த மதிப்புகளில் ஒன்றை எடுக்கலாம்:

• 0 அல்லது தவிர்க்கப்பட்டது (இயல்புநிலை) - எல்லா மதிப்புகளையும் வைத்திருங்கள்
• 1 - வெற்றிடங்களை புறக்கணிக்கவும்
• 2 - பிழைகளை புறக்கணிக்கவும்
• 3 - வெற்றிடங்களையும் பிழைகளையும் புறக்கணிக்கவும்

Scan_by_column (விரும்பினால்) - வரிசையை எப்படி ஸ்கேன் செய்வது என்பதை வரையறுக்கிறது:

• தவறு அல்லது தவிர்க்கப்பட்டது (இயல்புநிலை) - வரிசையை கிடைமட்டமாக வரிசையாக ஸ்கேன் செய்யவும்.
• சரி - நெடுவரிசை மூலம் வரிசையை செங்குத்தாக ஸ்கேன் செய்யவும்.

உதவிக்குறிப்புகள்:

• வரிசையை மாற்ற ஒற்றை நெடுவரிசையில், TOCOL செயல்பாட்டைப் பயன்படுத்தவும்.
• தலைகீழ் வரிசைக்கு-வரிசை மாற்றத்தை முன்கூட்டியே உருவாக்க, நெடுவரிசைகளில் மடிக்க WRAPCOLS செயல்பாட்டைப் பயன்படுத்தவும் அல்லது மடக்குவதற்கு WRAPROWS செயல்பாட்டைப் பயன்படுத்தவும்.வரிசையை வரிசைகளாக மாற்றவும்.
• வரிசைகளை நெடுவரிசைகளாக மாற்ற, TRANSPOSE செயல்பாட்டைப் பயன்படுத்தவும்.

TOROW கிடைக்கும்

TOROW என்பது ஒரு புதிய செயல்பாடு, இது Excel இல் மட்டுமே ஆதரிக்கப்படுகிறது. மைக்ரோசாப்ட் 365 (விண்டோஸ் மற்றும் மேக்கிற்கு) மற்றும் இணையத்திற்கான எக்செல் அதன் அடிப்படை வடிவத்தில். இதற்கு, நீங்கள் முதல் வாதத்தை மட்டுமே வரையறுக்க வேண்டும் ( வரிசை ).

உதாரணமாக, 3 நெடுவரிசைகள் மற்றும் 3 வரிசைகளைக் கொண்ட இரு பரிமாண அணிவரிசையை ஒற்றை வரிசையாக மாற்ற, சூத்திரம்:

=TOROW(A3:C6)

நீங்கள் சூத்திரத்தை ஒரே ஒரு கலத்தில் உள்ளிடுகிறீர்கள் (எங்கள் விஷயத்தில் A10), அது தானாகவே அனைத்து முடிவுகளையும் வைத்திருக்க தேவையான பல கலங்களில் பரவுகிறது. எக்செல் அடிப்படையில், ஒரு மெல்லிய நீல எல்லையால் சூழப்பட்ட வெளியீட்டு வரம்பு கசிவு வரம்பு என்று அழைக்கப்படுகிறது.

இந்த சூத்திரம் எவ்வாறு செயல்படுகிறது:

முதலில், வழங்கப்பட்ட கலங்களின் வரம்பு இரு பரிமாண வரிசையாக மாற்றப்படுகிறது. காற்புள்ளியால் பிரிக்கப்பட்ட நெடுவரிசைகள் மற்றும் அரைப்புள்ளியால் பிரிக்கப்பட்ட வரிசைகளைக் கவனியுங்கள்:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

பிறகு, TOROW செயல்பாடானது வரிசையை இடமிருந்து வலமாகப் படித்து, அதை ஒரு பரிமாண கிடைமட்ட அணிவரிசையாக மாற்றுகிறது:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

முடிவு செல் A10 க்கு செல்கிறது, அதில் இருந்து அது வலதுபுறத்தில் உள்ள அண்டை கலத்தில் பரவுகிறது.

வெற்றிடங்கள் மற்றும் பிழைகளை புறக்கணித்து வரம்பை வரிசையாக மாற்றவும்

முன்னிருப்பாக, TOROW செயல்பாடு அனைத்து மதிப்புகளையும் மூல வரிசையில் இருந்து, வெற்று செல்கள் மற்றும்பிழைகள். வெளியீட்டில், வெற்று கலங்களின் இடத்தில் பூஜ்ஜிய மதிப்புகள் தோன்றும், இது மிகவும் குழப்பமாக இருக்கலாம்.

வெற்றிடங்களை விலக்க , புறக்கணிப்பு வாதத்தை 1:<என அமைக்கவும். 3>

=TOROW(A3:C5, 1)

பிழைகளைப் புறக்கணிக்க , தவிர்க்க புறக்கணி வாதத்தை 2:

=TOROW(A3:C5, 2)

என அமைக்கவும் வெற்றிடங்கள் மற்றும் பிழைகள் இரண்டும், புறக்கணிப்பு வாதத்திற்கு 3 ஐப் பயன்படுத்தவும்:

=TOROW(A3:C5, 3)

கீழே உள்ள படம் மூன்று காட்சிகளையும் செயலில் காட்டுகிறது:

வரிசையை கிடைமட்டமாக அல்லது செங்குத்தாக படிக்கவும்

இயல்புநிலை நடத்தையுடன், TOROW செயல்பாடு வரிசையை இடமிருந்து வலமாக கிடைமட்டமாக செயலாக்குகிறது. மேலிருந்து கீழாக நெடுவரிசையின்படி மதிப்புகளை ஸ்கேன் செய்ய, நீங்கள் 3வது வாதத்தை ( scan_by_column ) TRUE அல்லது 1 என அமைத்தீர்கள்.

எடுத்துக்காட்டாக, மூல வரம்பை வரிசையாகப் படிக்க, உள்ள சூத்திரம் E3:

=TOROW(A3:C5)

நெடுவரிசை மூலம் வரம்பை ஸ்கேன் செய்ய, E8 இல் உள்ள சூத்திரம்:

=TOROW(A3:C5, ,TRUE)

இரண்டு நிலைகளிலும், விளைந்த அணிவரிசைகள் அதே அளவு, ஆனால் மதிப்புகள் வேறு வரிசையில் அமைக்கப்பட்டுள்ளன.

ஒரு வரிசையில் பல வரம்புகளை ஒன்றிணைக்கவும்

அருகாமையில் இல்லாத பல வரம்புகளை ஒரே வரிசையில் இணைக்க, முதலில் அவற்றை HSTACK அல்லது VSTACK உதவியுடன் ஒரே வரிசையில் கிடைமட்டமாக அல்லது செங்குத்தாக அடுக்கவும். , பின்னர் இணைந்த அணிவரிசையை ஒரு வரிசையாக மாற்ற TOROW செயல்பாட்டைப் பயன்படுத்தவும்.

உங்கள் வணிக தர்க்கத்தைப் பொறுத்து, பின்வரும் சூத்திரங்களில் ஒன்று பணியைச் செய்யும்.

வரிசைகளை கிடைமட்டமாக அடுக்கி, இதன் மூலம் மாற்றவும் வரிசை

முதல் உடன்A3:C4 இல் வரம்பு மற்றும் A8:C9 இல் உள்ள இரண்டாவது வரம்பு, கீழே உள்ள சூத்திரம் இரண்டு வரம்புகளையும் கிடைமட்டமாக ஒரே அணிவரிசையாக அடுக்கி, பின்னர் அதை இடமிருந்து வலமாக மதிப்புகளைப் படிக்கும் வரிசையாக மாற்றும். இதன் முடிவு கீழே உள்ள படத்தில் E3 இல் உள்ளது.

=TOROW(HSTACK(A3:C4, A8:C9))

வரிசைகளை கிடைமட்டமாக அடுக்கி, நெடுவரிசையாக மாற்றவும்

அடுக்கப்பட்ட வரிசையை செங்குத்தாக மேலிருந்து கீழாக படிக்க, கீழே உள்ள படத்தில் E5 இல் காட்டப்பட்டுள்ளபடி TOROW இன் 3வது வாதத்தை TRUE என அமைத்தீர்கள்:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

வரிசைகளை செங்குத்தாக அடுக்கி வரிசையாக மாற்றவும்

ஒவ்வொன்றையும் இணைக்க முந்தைய வரிசையின் கீழே உள்ள அடுத்தடுத்த அணிவரிசை மற்றும் ஒருங்கிணைந்த வரிசையை கிடைமட்டமாகப் படிக்கவும், E12 இல் உள்ள சூத்திரம்:

=TOROW(VSTACK(A3:C4, A8:C9))

வரிசைகளை செங்குத்தாக அடுக்கி, நெடுவரிசையாக மாற்றவும்

ஒவ்வொரு அடுத்தடுத்த வரிசையையும் முந்தைய வரிசையின் கீழே சேர்க்க மற்றும் ஒருங்கிணைந்த அணிவரிசையை செங்குத்தாக ஸ்கேன் செய்ய, சூத்திரம்:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

தர்க்கத்தை நன்கு புரிந்துகொள்ள, உள்ள மதிப்புகளின் வெவ்வேறு வரிசையைக் கவனிக்கவும் இதன் விளைவாக வரும் அணிவரிசைகள்:

தனிப்பட்ட மதிப்புகளை வரம்பிலிருந்து ஒரு வரிசையில் பிரித்தெடுக்கலாம்

Microsoft Excel 2016 இல் தொடங்கி, UNIQUE எனப் பெயரிடப்பட்ட ஒரு அற்புதமான செயல்பாடு எங்களிடம் உள்ளது, இது ஒரு நெடுவரிசையிலிருந்து தனித்துவமான மதிப்புகளை எளிதாகப் பெறலாம் அல்லது வரிசை. இருப்பினும், இது பல நெடுவரிசை வரிசைகளைக் கையாள முடியாது. இந்த வரம்பைக் கடக்க, UNIQUE மற்றும் TOROW செயல்பாடுகளை ஒன்றாகப் பயன்படுத்தவும்.

உதாரணமாக, A2:C7 வரம்பிலிருந்து அனைத்து வெவ்வேறு (தனித்துவமான) மதிப்புகளையும் பிரித்தெடுத்து முடிவுகளை ஒரே வரிசையில் வைக்க,சூத்திரம்:

=UNIQUE(TOROW(A2:C7), TRUE)

TOROW ஒரு பரிமாண கிடைமட்ட வரிசையை வழங்குவதால், ஒவ்வொன்றிற்கும் எதிரான நெடுவரிசைகளை ஒப்பிட, UNIQUE இன் 2வது ( by_col ) வாதத்தை TRUE ஆக அமைக்கிறோம் மற்றவை.

நீங்கள் முடிவுகளை அகரவரிசையில் வரிசைப்படுத்த விரும்பினால், மேலே உள்ள சூத்திரத்தை SORT செயல்பாட்டில் மடிக்கவும்:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

UNIQUE போலவே, by_col SORT இன் வாதமும் TRUE என அமைக்கப்பட்டுள்ளது.

Excel 365 - 2010க்கான TROOW மாற்று

TOROW செயல்பாடு கிடைக்காத Excel பதிப்புகளில், நீங்கள் வேலை செய்யும் சில வெவ்வேறு செயல்பாடுகளின் கலவையைப் பயன்படுத்தி வரம்பை ஒற்றை வரிசையாக மாற்றலாம். பழைய பதிப்புகள். இந்த தீர்வுகள் மிகவும் சிக்கலானவை, ஆனால் அவை வேலை செய்கின்றன.

வரம்பைக் கிடைமட்டமாக ஸ்கேன் செய்ய, பொதுவான சூத்திரம்:

INDEX( range , QUOTIENT(COLUMN (A1)-1, COLUMNS( range ))+1, MOD(COLUMN(A1)-1, COLUMNS( range ))+1)

வரம்பை செங்குத்தாக ஸ்கேன் செய்ய, பொதுவான சூத்திரம் :

INDEX( range , MOD(colUMN(A1)-1, COLUMNS( range ))+1, QUOTIENT(colUMN (A1)-1, COLUMNS( வரம்பு ))+1)

A3:C5 இல் உள்ள எங்கள் மாதிரி தரவுத்தொகுப்புக்கு, சூத்திரங்கள் இந்த வடிவத்தை எடுக்கும்:

வரிசையின்படி வரம்பை ஸ்கேன் செய்ய:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

இந்த சூத்திரம் TOROW செயல்பாட்டிற்கு மாற்றாக உள்ளது column:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

இந்த சூத்திரம் TOROW செயல்பாட்டிற்குச் சமமானது, 3வது வாதம் அமைக்கப்பட்டதுஉண்மை:

=TOROW(A3:C5, ,TRUE)

டைனமிக் வரிசை TOROW செயல்பாட்டைப் போலல்லாமல், இந்த பாரம்பரிய சூத்திரங்கள் முடிவுகள் தோன்ற விரும்பும் ஒவ்வொரு கலத்திலும் உள்ளிடப்பட வேண்டும். எங்கள் விஷயத்தில், முதல் சூத்திரம் (வரிசை மூலம்) E3 க்கு சென்று M3 மூலம் நகலெடுக்கப்படுகிறது. இரண்டாவது சூத்திரம் (நெடுவரிசை மூலம்) E8 இல் இறங்குகிறது மற்றும் M8 மூலம் இழுக்கப்படுகிறது.

சூத்திரங்கள் சரியாக நகலெடுக்க, முழுமையான குறிப்புகளைப் பயன்படுத்தி வரம்பைப் பூட்டுகிறோம் ($A$3:$C$5). பெயரிடப்பட்ட வரம்பும் செயல்படும்.

தேவையை விட அதிகமான கலங்களுக்கு நீங்கள் சூத்திரங்களை நகலெடுத்திருந்தால், #REF! "கூடுதல்" கலங்களில் பிழை தோன்றும். இதைச் சரிசெய்ய, உங்கள் ஃபார்முலாவை IFERROR செயல்பாட்டில் மடிக்கவும்:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

இந்தச் சூத்திரங்கள் எப்படிச் செயல்படுகின்றன

கீழே விரிவான முறிவு உள்ளது வரிசையின்படி மதிப்புகளை வரிசைப்படுத்தும் முதல் சூத்திரம்:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

சூத்திரத்தின் மையத்தில், கலத்தின் மதிப்பைப் பெற INDEX செயல்பாட்டைப் பயன்படுத்துகிறோம். வரம்பு.

வரிசை எண் இந்த சூத்திரத்தால் கணக்கிடப்படுகிறது:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

1,1 போன்ற மீண்டும் மீண்டும் வரும் எண் வரிசையை உருவாக்குவதே யோசனை. ,1,2,2,2,3,3,3, … ஒவ்வொரு எண்ணும் மூல வரம்பில் உள்ள நெடுவரிசைகள் எத்தனை முறை மீண்டும் மீண்டும் வரும். இதை எப்படி செய்வது என்பது இங்கே:

QUOTIENT ஒரு பிரிவின் முழு எண் பகுதியை வழங்குகிறது.

நியூமரேட்டருக்கு , நாங்கள் COLUMN(A1)-1 ஐப் பயன்படுத்துகிறோம், இது ஒரு வரிசையை வழங்குகிறது. சூத்திரம் உள்ளிடப்பட்ட முதல் கலத்தில் 0 முதல் n (வரம்பில் உள்ள மதிப்புகளின் மொத்த எண்ணிக்கைகழித்தல் 1) சூத்திரம் உள்ளிடப்பட்ட கடைசி கலத்தில். இந்த எடுத்துக்காட்டில், எங்களிடம் E2 இல் 0 மற்றும் M3 இல் 8 உள்ளது.

டினோமினேட்டருக்கு , நாங்கள் COLUMNS($A$3:$C$5)) ஐப் பயன்படுத்துகிறோம். இது உங்கள் வரம்பில் உள்ள நெடுவரிசைகளின் எண்ணிக்கைக்கு சமமான நிலையான எண்ணை வழங்கும் (எங்கள் விஷயத்தில் 3).

இதன் விளைவாக, QUOTIENT செயல்பாடு முதல் 3 கலங்களில் (E3:G3) 0 ஐ வழங்குகிறது. 1ஐச் சேர், அதனால் வரிசை எண் 1 ஆகும்.

அடுத்த 3 கலங்களுக்கு (H3:J3), QUOTIENT 1ஐத் தருகிறது, +1 ஆனது வரிசை எண் 2ஐக் கொடுக்கிறது. மேலும்.

நெடுவரிசை எண்ணைக் கணக்கிடுவதற்கு, நீங்கள் MOD செயல்பாட்டைப் பயன்படுத்தி பொருத்தமான எண் வரிசையை உருவாக்குகிறீர்கள்:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

எங்கள் வரம்பில் 3 நெடுவரிசைகள் இருப்பதால், வரிசை இப்படி இருக்க வேண்டும் : 1,2,3,1,2,3,…

MOD செயல்பாடானது பிரிவுக்குப் பிறகு மீதியை வழங்குகிறது.

E3 இல், MOD(COLUMN(A1)-1, COLUMNS($) A$3:$C$5))+

ஆக

MOD(1-1, 3)+1)

1.

இல் F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

ஆக

MOD(2-1, 3)+1)

மற்றும் 2ஐ வழங்குகிறது.

வரிசை மற்றும் நெடுவரிசை எண்கள் நிறுவப்பட்டதும், அந்த வரிசை மற்றும் நெடுவரிசையின் குறுக்குவெட்டில் உள்ள மதிப்பை INDEX எளிதாகப் பெறும்.

E3 இல், INDEX($A$3 :$C$5, 1, 1) 1வது வரிசை மற்றும் 1வது நெடுவரிசையில் இருந்து ஒரு மதிப்பை வழங்குகிறது குறிப்பிடப்பட்ட வரம்பில், அதாவது செல் A3 இலிருந்து.

F3 இல், INDEX($A$3:$C$5, 1, 2) ஆனது 1வது வரிசை மற்றும் 2வது நெடுவரிசையில் இருந்து, அதாவது செல் B3 இலிருந்து ஒரு மதிப்பை வழங்குகிறது.

மற்றும் முன்னும் பின்னும்.

நெடுவரிசை வாரியாக வரம்பை ஸ்கேன் செய்யும் இரண்டாவது சூத்திரம், ஒருஇதே வழியில். வித்தியாசம் என்னவென்றால், வரிசை எண்ணைக் கணக்கிடுவதற்கு MODஐயும், நெடுவரிசை எண்ணைக் கண்டறிய QUOTIENTஐயும் பயன்படுத்துகிறோம்.

TOROW செயல்பாடு வேலை செய்யவில்லை

TOROW செயல்பாட்டில் பிழை ஏற்பட்டால், அது பெரும்பாலும் இந்த காரணங்களில் ஒன்றாக இருக்கலாம்:

#NAME? பிழை

பெரும்பாலான எக்செல் செயல்பாடுகளுடன், #NAME? பிழை என்பது செயல்பாட்டின் பெயர் தவறாக எழுதப்பட்டிருப்பதற்கான தெளிவான அறிகுறியாகும். TOROW உடன், உங்கள் எக்செல் இல் செயல்பாடு கிடைக்கவில்லை என்பதையும் இது குறிக்கலாம். உங்கள் எக்செல் பதிப்பு 365 இல் இருந்தால், TOROW மாற்றீட்டைப் பயன்படுத்த முயற்சிக்கவும்.

#NUM பிழை

#NUM பிழையானது, திரும்பிய அணிவரிசை ஒரு வரிசையில் பொருந்தாது என்பதைக் குறிக்கிறது. ஒரு சிறிய வரம்பிற்குப் பதிலாக முழு நெடுவரிசைகள் மற்றும்/அல்லது வரிசைகளைக் குறிப்பிடும்போது இது பெரும்பாலும் நிகழ்கிறது.

#SPILL பிழை

பெரும்பாலான சந்தர்ப்பங்களில், #SPILL பிழையானது வரிசையைக் குறிக்கிறது நீங்கள் சூத்திரத்தை உள்ளிட்டுள்ளீர்கள், முடிவுகளைக் கொட்டுவதற்கு போதுமான வெற்று செல்கள் இல்லை. அண்டை செல்கள் பார்வைக்கு காலியாக இருந்தால், அவற்றில் இடைவெளிகள் அல்லது பிற அச்சிடப்படாத எழுத்துக்கள் இல்லை என்பதை உறுதிப்படுத்தவும். மேலும் தகவலுக்கு, எக்செல் இல் #SPILL பிழை என்றால் என்ன என்பதைப் பார்க்கவும்.

எக்செல் இல் TOROW செயல்பாட்டைப் பயன்படுத்தி 2 பரிமாண வரிசை அல்லது வரம்பை ஒற்றை வரிசையாக மாற்றலாம். படித்ததற்கு நன்றி, அடுத்த வாரம் எங்கள் வலைப்பதிவில் உங்களைப் பார்ப்பேன் என்று நம்புகிறேன்!

பதிவிறக்கப் பயிற்சிப் புத்தகம்

Excel TOROW செயல்பாடு - சூத்திர எடுத்துக்காட்டுகள் (.xlsx கோப்பு)

>