Cara pantas untuk menukar julat sel menjadi satu baris dengan bantuan fungsi TOROW .

Microsoft Excel 365 telah memperkenalkan beberapa fungsi baharu untuk melakukan pelbagai manipulasi dengan tatasusunan. Dengan TOROW, anda boleh melakukan transformasi julat ke baris dalam masa yang singkat. Berikut ialah senarai tugas yang boleh dicapai oleh fungsi baharu ini:

Fungsi TOROW Excel

Fungsi TOROW dalam Excel digunakan untuk menukar tatasusunan atau julat sel kepada satu baris.

Fungsi ini mengambil sejumlah tiga argumen, yang mana hanya yang pertama diperlukan.

TOROW(array, [ignore], [scan_by_column])

Di mana:

Array (diperlukan) - tatasusunan atau julat untuk diubah menjadi satu baris.

Abaikan (pilihan) - menentukan sama ada untuk mengabaikan kosong atau/dan kesilapan. Boleh mengambil salah satu daripada nilai ini:

• 0 atau ditinggalkan (lalai) - simpan semua nilai
• 1 - abaikan kosong
• 2 - abaikan ralat
• 3 - abaikan tempat kosong dan ralat

Scan_by_column (pilihan) - mentakrifkan cara mengimbas tatasusunan:

• SALAH atau ditinggalkan (lalai) - imbas tatasusunan secara mendatar mengikut baris.
• BENAR - imbas tatasusunan secara menegak mengikut lajur.

Petua:

• Untuk mengubah tatasusunan ke dalam satu lajur, gunakan fungsi TOCOL.
• Untuk membentuk pra-penjelmaan baris-ke-tatasusunan terbalik, gunakan sama ada fungsi WRAPCOLS untuk membalut ke dalam lajur atau fungsi WRAPROWS untuk membaluttatasusunan menjadi baris.
• Untuk menukar baris menjadi lajur, gunakan fungsi TRANSPOSE.

Ketersediaan TOROW

TOROW ialah fungsi baharu, yang hanya disokong dalam Excel untuk Microsoft 365 (untuk Windows dan Mac) dan Excel untuk web.

Formula asas TOROW dalam Excel

Untuk melakukan transformasi julat ke baris yang mudah, gunakan formula TOROW dalam bentuk asasnya. Untuk ini, anda perlu mentakrifkan hanya argumen pertama ( tatasusunan ).

Contohnya, untuk menukar tatasusunan dua dimensi yang terdiri daripada 3 lajur dan 3 baris menjadi satu baris, formula ialah:

=TOROW(A3:C6)

Anda memasukkan formula ke dalam satu sel sahaja (A10 dalam kes kami), dan ia secara automatik tumpah ke dalam seberapa banyak sel yang diperlukan untuk menyimpan semua hasil. Dalam istilah Excel, julat keluaran yang dikelilingi oleh sempadan biru nipis dipanggil julat tumpahan.

Cara formula ini berfungsi:

Mula-mula, julat sel yang dibekalkan diubah menjadi tatasusunan dua dimensi. Sila perhatikan lajur dipisahkan koma dan baris dipisahkan koma bertitik:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

Kemudian, fungsi TOROW membaca tatasusunan dari kiri ke kanan dan menukarnya menjadi tatasusunan mendatar satu dimensi:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

Hasilnya pergi ke sel A10, yang daripadanya ia tumpah ke dalam sel jiran di sebelah kanan.

Ubah julat kepada baris mengabaikan tempat kosong dan ralat

Secara lalai, fungsi TOROW menyimpan semua nilai daripada tatasusunan sumber, termasuk sel kosong dankesilapan. Dalam output, nilai sifar muncul di tempat sel kosong, yang mungkin agak mengelirukan.

Untuk tidak termasuk kosong , tetapkan argumen abaikan kepada 1:

=TOROW(A3:C5, 1)

Untuk mengabaikan ralat , tetapkan argumen abaikan kepada 2:

=TOROW(A3:C5, 2)

Untuk melangkau kedua-duanya, kosong dan ralat , gunakan 3 untuk hujah abaikan :

=TOROW(A3:C5, 3)

Imej di bawah menunjukkan ketiga-tiga senario dalam tindakan:

Baca tatasusunan secara mendatar atau menegak

Dengan gelagat lalai, fungsi TOROW memproses tatasusunan secara mendatar dari kiri ke kanan. Untuk mengimbas nilai mengikut lajur dari atas ke bawah, anda menetapkan argumen ke-3 ( scan_by_column ) kepada TRUE atau 1.

Contohnya, untuk membaca julat sumber mengikut baris, formula dalam E3 ialah:

=TOROW(A3:C5)

Untuk mengimbas julat mengikut lajur, formula dalam E8 ialah:

=TOROW(A3:C5, ,TRUE)

Dalam kedua-dua kes, tatasusunan yang terhasil ialah saiz yang sama, tetapi nilainya disusun dalam susunan yang berbeza.

Gabungkan berbilang julat ke dalam satu baris

Untuk menggabungkan beberapa julat bukan bersebelahan menjadi satu baris, anda mula-mula menyusunnya secara mendatar atau menegak ke dalam tatasusunan tunggal dengan bantuan HSTACK atau VSTACK, masing-masing , dan kemudian gunakan fungsi TOROW untuk menukar tatasusunan gabungan ke dalam baris.

Bergantung pada logik perniagaan anda, salah satu daripada formula berikut akan melaksanakan tugas.

Tindan tatasusunan secara mendatar dan tukar mengikut baris

Dengan yang pertamajulat dalam A3:C4 dan julat kedua dalam A8:C9, formula di bawah akan menyusun dua julat secara mendatar ke dalam tatasusunan tunggal, dan kemudian mengubahnya kepada satu baris membaca nilai dari kiri ke kanan. Hasilnya adalah dalam E3 dalam imej di bawah.

=TOROW(HSTACK(A3:C4, A8:C9))

Tindan tatasusunan secara mendatar dan tukar mengikut lajur

Untuk membaca tatasusunan bertindan secara menegak dari atas ke bawah, anda menetapkan hujah ke-3 TOROW kepada TRUE seperti yang ditunjukkan dalam E5 dalam imej di bawah:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

Tindan tatasusunan secara menegak dan tukar mengikut baris

Untuk menambahkan setiap tatasusunan seterusnya ke bahagian bawah tatasusunan sebelumnya dan baca tatasusunan gabungan secara mendatar, formula dalam E12 ialah:

=TOROW(VSTACK(A3:C4, A8:C9))

Tindan tatasusunan secara menegak dan tukar mengikut lajur

Untuk menambah setiap tatasusunan berikutnya ke bahagian bawah tatasusunan sebelumnya dan mengimbas tatasusunan gabungan secara menegak, formulanya ialah:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

Untuk lebih memahami logik, perhatikan susunan nilai yang berbeza dalam tatasusunan yang terhasil:

Ekstrak nilai unik daripada julat ke dalam baris

Bermula dengan Microsoft Excel 2016, kami mempunyai fungsi hebat, bernama UNIQUE, yang boleh mendapatkan nilai unik dengan mudah daripada satu lajur atau baris. Walau bagaimanapun, ia tidak boleh mengendalikan tatasusunan berbilang lajur. Untuk mengatasi had ini, gunakan fungsi UNIQUE dan TOROW bersama-sama.

Contohnya, untuk mengekstrak semua nilai yang berbeza (berbeza) daripada julat A2:C7 dan meletakkan keputusan dalam satu baris,formula ialah:

=UNIQUE(TOROW(A2:C7), TRUE)

Apabila TOROW mengembalikan tatasusunan mendatar satu dimensi, kami menetapkan argumen ke-2 ( by_col ) UNIQUE kepada TRUE untuk membandingkan lajur dengan setiap lain.

Sekiranya anda mahu hasil disusun dalam susunan abjad, bungkus formula di atas dalam fungsi SORT:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

Seperti UNIQUE, by_col hujah SORT juga ditetapkan kepada TRUE.

Alternatif TOROW untuk Excel 365 - 2010

Dalam versi Excel yang fungsi TOROW tidak tersedia, anda boleh mengubah julat menjadi satu baris menggunakan gabungan beberapa fungsi berbeza yang berfungsi dalam versi lama. Penyelesaian ini lebih kompleks, tetapi ia berfungsi.

Untuk mengimbas julat secara mendatar, formula generik ialah:

INDEX( julat , QUOTIENT(COLUMN (A1)-1, COLUMNS( julat ))+1, MOD(COLUMN(A1)-1, COLUMNS( julat ))+1)

Untuk mengimbas julat secara menegak, formula generik ialah :

INDEX( julat , MOD(COLUMN(A1)-1, COLUMNS( julat ))+1, QUOTIENT(COLUMN (A1)-1, COLUMNS( julat ))+1)

Untuk set data sampel kami dalam A3:C5, formula mengambil bentuk ini:

Untuk mengimbas julat mengikut baris:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Formula ini ialah alternatif kepada fungsi TOROW dengan argumen ke-3 ditetapkan kepada FALSE atau ditinggalkan:

=TOROW(A3:C5)

Untuk mengimbas julat dengan lajur:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Formula ini bersamaan dengan fungsi TOROW dengan argumen ke-3 ditetapkan kepadaBENAR:

=TOROW(A3:C5, ,TRUE)

Sila ambil perhatian bahawa tidak seperti fungsi TOROW tatasusunan dinamik, formula tradisional ini harus dimasukkan dalam setiap sel yang anda mahukan hasilnya dipaparkan. Dalam kes kami, formula pertama (mengikut baris) pergi ke E3 dan disalin melalui M3. Formula kedua (mengikut lajur) mendarat di E8 dan diseret melalui M8.

Untuk menyalin formula dengan betul, kami mengunci julat menggunakan rujukan mutlak ($A$3:$C$5). Julat bernama juga akan berfungsi.

Jika anda telah menyalin formula ke lebih banyak sel daripada yang diperlukan, #REF! ralat akan muncul dalam sel "tambahan". Untuk membetulkannya, bungkus formula anda dalam fungsi IFERROR seperti ini:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

Cara formula ini berfungsi

Di bawah ialah pecahan terperinci daripada formula pertama yang menyusun nilai mengikut baris:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Di tengah-tengah formula, kami menggunakan fungsi INDEX untuk mendapatkan nilai sel berdasarkan kedudukan relatifnya dalam julat.

nombor baris dikira dengan formula ini:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Ideanya adalah untuk menghasilkan urutan nombor berulang seperti 1,1 ,1,2,2,2,3,3,3, … di mana setiap nombor berulang seberapa banyak kali terdapat lajur dalam julat sumber. Begini cara kami melakukan ini:

QUOTIENT mengembalikan bahagian integer pembahagian.

Untuk penumerator , kami menggunakan COLUMN(A1)-1, yang mengembalikan siri nombor daripada 0 dalam sel pertama di mana formula dimasukkan ke n (jumlah bilangan nilai dalam julattolak 1) dalam sel terakhir di mana formula masuk dimasukkan. Dalam contoh ini, kami mempunyai 0 dalam E2 dan 8 dalam M3.

Untuk penyebut , kami menggunakan COLUMNS($A$3:$C$5)). Ini mengembalikan nombor malar yang sama dengan bilangan lajur dalam julat anda (3 dalam kes kami).

Akibatnya, fungsi QUOTIENT mengembalikan 0 dalam 3 sel pertama (E3:G3), yang mana kami tambah 1, jadi nombor baris ialah 1.

Untuk 3 sel seterusnya (H3:J3), QUOTIENT mengembalikan 1 dan +1 memberikan nombor baris 2. Dan seterusnya.

Untuk mengira nombor lajur , anda membina jujukan nombor yang sesuai menggunakan fungsi MOD:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Memandangkan terdapat 3 lajur dalam julat kami, jujukan mesti kelihatan seperti : 1,2,3,1,2,3,…

Fungsi MOD mengembalikan baki selepas pembahagian.

Dalam E3, MOD(COLUMN(A1)-1, COLUMNS($ A$3:$C$5))+

menjadi

MOD(1-1, 3)+1)

dan mengembalikan 1.

Dalam F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

menjadi

MOD(2-1, 3)+1)

dan mengembalikan 2.

Setelah nombor baris dan lajur ditubuhkan, INDEX mengambil nilai dengan mudah di persimpangan baris dan lajur itu.

Dalam E3, INDEX($A$3 :$C$5, 1, 1) mengembalikan nilai dari baris pertama dan lajur pertama daripada julat yang dirujuk, iaitu dari sel A3.

Dalam F3, INDEX($A$3:$C$5, 1, 2) mengembalikan nilai daripada baris pertama dan lajur ke-2, iaitu daripada sel B3.

Dan seterusnya.

Formula kedua yang mengimbas julat mengikut lajur, berfungsi dalamcara yang serupa. Perbezaannya ialah kami menggunakan MOD untuk mengira nombor baris dan QUOTIENT untuk memikirkan nombor lajur.

Fungsi TOROW tidak berfungsi

Jika fungsi TOROW mengakibatkan ralat, ia adalah kemungkinan besar adalah salah satu sebab berikut:

#NAME? ralat

Dengan kebanyakan fungsi Excel, #NAME? ralat adalah petunjuk yang jelas bahawa nama fungsi itu salah eja. Dengan TOROW, ini juga mungkin bermakna fungsi itu tidak tersedia dalam Excel anda. Jika versi Excel anda selain daripada 365, cuba gunakan alternatif TOROW.

#NUM ralat

Ralat #NUM menunjukkan bahawa tatasusunan yang dikembalikan tidak boleh dimuatkan ke dalam satu baris. Selalunya ia berlaku apabila anda merujuk keseluruhan lajur dan/atau baris dan bukannya julat yang lebih kecil.

Ralat #SPILL

Dalam kebanyakan kes, ralat #SPILL mencadangkan bahawa baris di mana anda telah memasukkan formula tidak mempunyai sel kosong yang mencukupi untuk menumpahkan hasilnya. Jika sel jiran kosong secara visual, pastikan tiada ruang atau aksara bukan cetakan lain di dalamnya. Untuk mendapatkan maklumat lanjut, lihat Maksud ralat #SPILL dalam Excel.

Begitulah anda menggunakan fungsi TOROW dalam Excel untuk menukar tatasusunan atau julat 2 dimensi kepada satu baris. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Berlatih buku kerja untuk muat turun

Fungsi Excel TOROW - contoh formula (fail.xlsx)