TOROW ফাংশনের সাহায্যে একটি একক সারিতে ঘরের পরিসরে পরিণত করার একটি দ্রুত উপায়।

Microsoft Excel 365 বেশ কিছু নতুন ফাংশন চালু করেছে অ্যারে সহ বিভিন্ন ম্যানিপুলেশন করতে। TOROW-এর সাহায্যে, আপনি কোনো সময়ের মধ্যেই রেঞ্জ-টু-সারি রূপান্তর করতে পারবেন। এই নতুন ফাংশনটি যে কাজগুলি সম্পাদন করতে পারে তার একটি তালিকা এখানে রয়েছে:

এক্সেল টরো ফাংশন

এক্সেলের TOROW ফাংশনটি একটি অ্যারে বা সেলগুলির পরিসরকে রূপান্তর করতে ব্যবহৃত হয় একটি সারি।

ফাংশনটি মোট তিনটি আর্গুমেন্ট নেয়, যার মধ্যে শুধুমাত্র প্রথমটির প্রয়োজন হয়।

TOROW(অ্যারে, [ignore], [scan_by_column])

কোথায়:

অ্যারে (প্রয়োজনীয়) - একটি অ্যারে বা ব্যাপ্তি যা একটি একক সারিতে রূপান্তরিত হয়৷

উপেক্ষা করুন (ঐচ্ছিক) - ফাঁকা স্থানগুলিকে উপেক্ষা করা বা/এবং নির্ধারণ করে ত্রুটি এই মানগুলির একটি নিতে পারেন:

• 0 বা বাদ দেওয়া (ডিফল্ট) - সমস্ত মান রাখুন
• 1 - ফাঁকাগুলি উপেক্ষা করুন
• 2 - ত্রুটিগুলি উপেক্ষা করুন
• 3 - ফাঁকা এবং ত্রুটিগুলি উপেক্ষা করুন

Scan_by_column (ঐচ্ছিক) - কীভাবে অ্যারে স্ক্যান করবেন তা সংজ্ঞায়িত করে:

• মিথ্যা বা বাদ দেওয়া (ডিফল্ট) - সারি দ্বারা অনুভূমিকভাবে অ্যারে স্ক্যান করুন৷
• সত্য - কলাম দ্বারা উল্লম্বভাবে অ্যারেটি স্ক্যান করুন৷

টিপস:

• একটি অ্যারে রূপান্তর করতে একটি একক কলামে, TOCOL ফাংশনটি ব্যবহার করুন৷
• বিপরীত সারি-থেকে-অ্যারে রূপান্তরটি প্রিফর্ম করতে, হয় WRAPCOLS ফাংশনটি কলামগুলিতে মোড়ানোর জন্য বা মোড়ানোর জন্য WRAPROWS ফাংশনটি ব্যবহার করুন৷সারিতে বিন্যাস করুন।
• সারিগুলিকে কলামে পরিণত করতে, TRANSPOSE ফাংশনটি ব্যবহার করুন।

TOROW উপলব্ধতা

TOROW হল একটি নতুন ফাংশন, যা শুধুমাত্র Excel এ সমর্থিত মাইক্রোসফট 365 (উইন্ডোজ এবং ম্যাকের জন্য) এবং ওয়েবের জন্য এক্সেল।

এক্সেলের বেসিক TOROW সূত্র

একটি সাধারণ রেঞ্জ-টু-সারি রূপান্তর করতে, TOROW সূত্রটি ব্যবহার করুন তার মৌলিক আকারে। এর জন্য, আপনাকে শুধুমাত্র প্রথম আর্গুমেন্ট ( অ্যারে ) সংজ্ঞায়িত করতে হবে।

উদাহরণস্বরূপ, ৩টি কলাম এবং ৩টি সারি সমন্বিত একটি দ্বি-মাত্রিক অ্যারেকে একটি একক সারিতে পরিণত করতে, সূত্র হল:

=TOROW(A3:C6)

আপনি সূত্রটি শুধুমাত্র একটি ঘরে প্রবেশ করুন (আমাদের ক্ষেত্রে A10), এবং এটি স্বয়ংক্রিয়ভাবে সমস্ত ফলাফল ধরে রাখার জন্য যতগুলি প্রয়োজন ততগুলি কোষে ছড়িয়ে পড়ে। এক্সেলের পরিভাষায়, একটি পাতলা নীল বর্ডার দ্বারা বেষ্টিত আউটপুট পরিসরকে স্পিল রেঞ্জ বলা হয়।

এই সূত্রটি কীভাবে কাজ করে:

প্রথমে, সরবরাহকৃত কোষের পরিসর একটি দ্বি-মাত্রিক অ্যারেতে রূপান্তরিত হয়। অনুগ্রহ করে কমা-ডিলিমিটেড কলাম এবং সেমিকোলন-বিচ্ছিন্ন সারিগুলি লক্ষ্য করুন:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

তারপর, TOROW ফাংশন অ্যারেটিকে বাম থেকে ডানে পড়ে এবং এটিকে এক-মাত্রিক অনুভূমিক অ্যারেতে রূপান্তর করে:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

ফলাফলটি A10 কক্ষে যায়, যেখান থেকে এটি ডানদিকের প্রতিবেশী কক্ষে ছড়িয়ে পড়ে৷

খালি স্থান এবং ত্রুটি উপেক্ষা করে পরিসরকে সারিতে রূপান্তর করুন

ডিফল্টরূপে, TOROW ফাংশনটি সোর্স অ্যারে থেকে খালি ঘর সহ সমস্ত মান রাখে এবংত্রুটি আউটপুটে, ফাঁকা কক্ষের জায়গায় শূন্য মানগুলি উপস্থিত হয়, যা বেশ বিভ্রান্তিকর হতে পারে৷

খালি স্থানগুলি বাদ দিতে , ignore আর্গুমেন্টটিকে 1:<এ সেট করুন 3>

=TOROW(A3:C5, 1)

ত্রুটি উপেক্ষা করতে , উপেক্ষা করুন আর্গুমেন্টটি 2 এ সেট করুন:

=TOROW(A3:C5, 2)

এড়িয়ে যেতে উভয়, ফাঁকা এবং ত্রুটি , উপেক্ষা করুন যুক্তির জন্য 3 ব্যবহার করুন:

=TOROW(A3:C5, 3)

নীচের চিত্রটি কার্যত তিনটি পরিস্থিতি দেখায়: <18

অ্যারে অনুভূমিকভাবে বা উল্লম্বভাবে পড়ুন

ডিফল্ট আচরণের সাথে, TOROW ফাংশন অ্যারেটিকে বাম থেকে ডানে অনুভূমিকভাবে প্রক্রিয়া করে। উপরে থেকে নীচে কলাম দ্বারা মানগুলি স্ক্যান করতে, আপনি 3য় আর্গুমেন্ট ( scan_by_column ) TRUE বা 1 তে সেট করুন।

উদাহরণস্বরূপ, সারি অনুসারে উত্স পরিসর পড়তে, সূত্রটি E3 হল:

=TOROW(A3:C5)

কলাম দ্বারা পরিসীমা স্ক্যান করতে, E8-এর সূত্র হল:

=TOROW(A3:C5, ,TRUE)

উভয় ক্ষেত্রেই, ফলস্বরূপ অ্যারেগুলি হল একই আকার, কিন্তু মান একটি ভিন্ন ক্রমে সাজানো হয়.

এক সারিতে একাধিক রেঞ্জ একত্রিত করুন

একটি সারিতে একাধিক অ-সংলগ্ন রেঞ্জকে একত্রিত করতে, আপনি প্রথমে যথাক্রমে HSTACK বা VSTACCK এর সাহায্যে অনুভূমিকভাবে বা উল্লম্বভাবে একটি একক অ্যারেতে স্ট্যাক করুন , এবং তারপর সম্মিলিত অ্যারেকে একটি সারিতে রূপান্তর করতে TOROW ফাংশন ব্যবহার করুন৷

আপনার ব্যবসার যুক্তির উপর নির্ভর করে, নিম্নলিখিত সূত্রগুলির মধ্যে একটি কাজটি সম্পাদন করবে৷

অনুভূমিকভাবে অ্যারেগুলিকে স্ট্যাক করুন এবং রূপান্তর করুন সারি

প্রথমটির সাথেA3:C4-এ পরিসীমা এবং A8:C9-এ দ্বিতীয় পরিসর, নীচের সূত্রটি অনুভূমিকভাবে দুটি রেঞ্জকে একটি একক অ্যারেতে স্ট্যাক করবে এবং তারপরে এটিকে বাম থেকে ডানে মান পড়ার জন্য একটি সারিতে রূপান্তরিত করবে। ফলাফলটি নীচের চিত্রে E3 তে রয়েছে।

=TOROW(HSTACK(A3:C4, A8:C9))

অ্যারেগুলিকে অনুভূমিকভাবে স্ট্যাক করুন এবং কলাম দ্বারা রূপান্তর করুন

স্ট্যাক করা অ্যারেটিকে উপরের থেকে নীচের দিকে উল্লম্বভাবে পড়তে, আপনি নীচের ছবিতে E5 তে দেখানো হিসাবে TOROW-এর 3য় আর্গুমেন্ট TRUE সেট করেছেন:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

অ্যারেগুলিকে উল্লম্বভাবে স্ট্যাক করুন এবং সারি দ্বারা রূপান্তর করুন

প্রতিটি যুক্ত করতে পরবর্তী অ্যারেটি পূর্ববর্তী অ্যারের নীচে এবং অনুভূমিকভাবে সম্মিলিত অ্যারেটি পড়ুন, E12 এর সূত্রটি হল:

=TOROW(VSTACK(A3:C4, A8:C9))

অ্যারেগুলিকে উল্লম্বভাবে স্ট্যাক করুন এবং কলাম দ্বারা রূপান্তর করুন

পূর্ববর্তীটির নীচে প্রতিটি পরবর্তী অ্যারে যুক্ত করতে এবং সম্মিলিত অ্যারেটিকে উল্লম্বভাবে স্ক্যান করতে, সূত্রটি হল:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

যুক্তিটি আরও ভালভাবে বোঝার জন্য, মানগুলির বিভিন্ন ক্রম পর্যবেক্ষণ করুন ফলস্বরূপ অ্যারেগুলি:

একটি রেঞ্জ থেকে একটি সারিতে অনন্য মানগুলি বের করুন

মাইক্রোসফ্ট এক্সেল 2016 দিয়ে শুরু করে, আমাদের কাছে একটি দুর্দান্ত ফাংশন রয়েছে, যার নাম ইউনিক, যা সহজেই একটি একক কলাম থেকে অনন্য মান পেতে পারে বা সারি। যাইহোক, এটি মাল্টি-কলাম অ্যারেগুলি পরিচালনা করতে পারে না। এই সীমাবদ্ধতা অতিক্রম করতে, ইউনিক এবং টোরো ফাংশন একসাথে ব্যবহার করুন।

উদাহরণস্বরূপ, A2:C7 পরিসর থেকে সমস্ত ভিন্ন (স্বতন্ত্র) মান বের করতে এবং ফলাফলগুলিকে একটি সারিতে রাখতে,সূত্র হল:

=UNIQUE(TOROW(A2:C7), TRUE)

যেহেতু TOROW একটি এক-মাত্রিক অনুভূমিক অ্যারে প্রদান করে, আমরা প্রতিটি কলামের সাথে তুলনা করার জন্য UNIQUE-এর 2য় ( by_col ) আর্গুমেন্ট সেট করি। অন্যান্য।

যদি আপনি ফলাফলগুলিকে বর্ণানুক্রমিক ক্রমে সাজাতে চান, উপরের সূত্রটি SORT ফাংশনে মোড়ানো:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

UNIQUE এর মত, by_col SORT-এর আর্গুমেন্টও TRUE সেট করা আছে।

এক্সেল 365 - 2010 এর জন্য TOROW বিকল্প

এক্সেল সংস্করণে যেখানে TOROW ফাংশন উপলব্ধ নয়, আপনি কাজ করে এমন কয়েকটি ভিন্ন ফাংশনের সংমিশ্রণ ব্যবহার করে একটি রেঞ্জকে একটি একক সারিতে রূপান্তর করতে পারেন পুরানো সংস্করণ। এই সমাধানগুলি আরও জটিল, কিন্তু এগুলি কাজ করে৷

অনুভূমিকভাবে পরিসরটি স্ক্যান করতে, জেনেরিক সূত্রটি হল:

INDEX( পরিসীমা , QUOTIENT(COLUMN (A1)-1), COLUMNS( পরিসীমা ))+1, MOD(COLUMN(A1)-1, COLUMNS( পরিসীমা ))+1)

পরিসীমাটি উল্লম্বভাবে স্ক্যান করতে, জেনেরিক সূত্র হল :

INDEX( পরিসীমা , MOD(COLUMN(A1)-1, COLUMNS( range ))+1, QuotiENT(COLUMN (A1)-1, COLUMNS(<15)>পরিসীমা ))+1)

আমাদের নমুনা ডেটাসেটের জন্য A3:C5, সূত্রগুলি এই আকার ধারণ করে:

সারি অনুসারে পরিসীমা স্ক্যান করতে:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

এই সূত্রটি TOROW ফাংশনের একটি বিকল্প যার সাথে 3য় আর্গুমেন্ট FALSE এ সেট করা হয়েছে বা বাদ দেওয়া হয়েছে:

=TOROW(A3:C5)

এর দ্বারা পরিসরটি স্ক্যান করতে কলাম:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

এই সূত্রটি TOROW ফাংশনের সমতুল্য যার 3য় আর্গুমেন্ট সেট করা হয়েছেTRUE:

=TOROW(A3:C5, ,TRUE)

অনুগ্রহ করে লক্ষ্য করুন যে ডায়নামিক অ্যারে TOROW ফাংশনের বিপরীতে, এই প্রথাগত সূত্রগুলি প্রতিটি ঘরে প্রবেশ করা উচিত যেখানে আপনি ফলাফলগুলি দেখতে চান৷ আমাদের ক্ষেত্রে, প্রথম সূত্র (সারি দ্বারা) E3 এ যায় এবং M3 এর মাধ্যমে অনুলিপি করা হয়। দ্বিতীয় সূত্রটি (কলাম দ্বারা) E8 এ অবতরণ করে এবং M8 এর মাধ্যমে টেনে আনা হয়।

সূত্রগুলো সঠিকভাবে অনুলিপি করার জন্য, আমরা পরম রেফারেন্স ($A$3:$C$5) ব্যবহার করে পরিসরটি লক করি। একটি নামযুক্ত পরিসরও করবে৷

যদি আপনি প্রয়োজনের চেয়ে বেশি কক্ষে সূত্রগুলি অনুলিপি করে থাকেন, একটি #REF! ত্রুটি "অতিরিক্ত" কক্ষে প্রদর্শিত হবে। এটি ঠিক করতে, আপনার সূত্রটি IFERROR ফাংশনে এইভাবে মুড়ে দিন:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

এই সূত্রগুলি কীভাবে কাজ করে

নীচে একটি বিশদ ব্রেক-ডাউন রয়েছে প্রথম সূত্রের যেটি সারি অনুসারে মানগুলিকে সাজায়:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

সূত্রের কেন্দ্রস্থলে, আমরা INDEX ফাংশনটি ব্যবহার করি একটি ঘরের মান পেতে তার আপেক্ষিক অবস্থানের উপর ভিত্তি করে পরিসীমা।

সারি সংখ্যা এই সূত্র দ্বারা গণনা করা হয়:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

ধারণাটি হল 1,1 এর মতো একটি পুনরাবৃত্তি সংখ্যার ক্রম তৈরি করা ,1,2,2,2,3,3,3, … যেখানে প্রতিটি সংখ্যা উৎস পরিসরে যতবার কলাম আছে ততবার পুনরাবৃত্তি হয়। এবং এখানে আমরা কীভাবে এটি করি:

গুণফল একটি বিভাগের পূর্ণসংখ্যা অংশ প্রদান করে।

অঙ্কের জন্য, আমরা COLUMN(A1)-1 ব্যবহার করি, যা একটি সিরিয়াল প্রদান করে প্রথম কক্ষে 0 থেকে সংখ্যা যেখানে সূত্রটি n এ প্রবেশ করানো হয় (ব্যাপ্তিতে মোট মানের সংখ্যাবিয়োগ 1) শেষ কক্ষে যেখানে সূত্রটি প্রবেশ করানো হয়েছে৷ এই উদাহরণে, আমাদের E2 তে 0 এবং M3 তে 8 আছে।

ডিনোমিনেটর -এর জন্য, আমরা COLUMNS($A$3:$C$5)) ব্যবহার করি। এটি আপনার পরিসরের কলামের সংখ্যার সমান একটি ধ্রুবক সংখ্যা প্রদান করে (আমাদের ক্ষেত্রে 3)।

ফলে, QUOTIENT ফাংশনটি প্রথম 3টি ঘরে (E3:G3) 0 প্রদান করে, যেখানে আমরা 1 যোগ করুন, তাই সারি সংখ্যা হল 1।

পরবর্তী 3টি ঘরের জন্য (H3:J3), QUOTIENT 1 প্রদান করে এবং +1 সারি নম্বর 2 প্রদান করে।

কলাম নম্বর গণনা করতে, আপনি MOD ফাংশন ব্যবহার করে একটি উপযুক্ত সংখ্যার ক্রম তৈরি করুন:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

যেহেতু আমাদের পরিসরে 3টি কলাম রয়েছে, ক্রমটি অবশ্যই দেখতে হবে : 1,2,3,1,2,3,…

MOD ফাংশনটি বিভাজনের পরে অবশিষ্টাংশ প্রদান করে৷

E3-এ, MOD(COLUMN(A1)-1, COLUMNS($ A$3:$C$5))+

হয়ে যায়

MOD(1-1, 3)+1)

এবং 1 ফেরত দেয়।

এ F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

হয়েছে

MOD(2-1, 3)+1)

এবং 2 রিটার্ন করে।

একবার সারি এবং কলামের সংখ্যা প্রতিষ্ঠিত হয়ে গেলে, INDEX সহজেই সেই সারি এবং কলামের সংযোগস্থলে মান আনে।

E3-এ, INDEX($A$3 :$C$5, 1, 1) ১ম সারি এবং ১ম কলাম থেকে একটি মান প্রদান করে উল্লেখিত পরিসরের, যেমন সেল A3 থেকে।

F3-এ, INDEX($A$3:$C$5, 1, 2) ১ম সারি এবং ২য় কলাম থেকে একটি মান প্রদান করে, যেমন B3 সেল থেকে।

এবং আরও অনেক কিছু।

দ্বিতীয় সূত্র যা কলাম দ্বারা পরিসীমা স্ক্যান করে, একটিতে কাজ করেএকই ভাবে. পার্থক্য হল যে আমরা সারি সংখ্যা গণনা করতে MOD ব্যবহার করি এবং কলাম নম্বর বের করতে QUOTIENT ব্যবহার করি।

TOROW ফাংশন কাজ করছে না

যদি TOROW ফাংশনটি একটি ত্রুটিতে পরিণত হয়, এটি সম্ভবত এই কারণগুলির মধ্যে একটি হতে পারে:

#NAME? ত্রুটি

অধিকাংশ এক্সেল ফাংশন সহ, একটি #NAME? error একটি স্পষ্ট ইঙ্গিত যে ফাংশনের নামের বানান ভুল। TOROW এর সাথে, এর অর্থ হতে পারে যে ফাংশনটি আপনার এক্সেলে উপলব্ধ নেই। যদি আপনার এক্সেল সংস্করণ 365 ব্যতীত অন্য কোনো টোরো বিকল্প ব্যবহার করে দেখুন৷

#NUM ত্রুটি

একটি #NUM ত্রুটি নির্দেশ করে যে প্রত্যাবর্তিত অ্যারেটি একটি সারিতে ফিট করতে পারে না৷ প্রায়শই এটি ঘটে যখন আপনি একটি ছোট পরিসরের পরিবর্তে সম্পূর্ণ কলাম এবং/অথবা সারিগুলি উল্লেখ করেন৷

#SPILL ত্রুটি

বেশিরভাগ ক্ষেত্রে, একটি #SPILL ত্রুটি নির্দেশ করে যে সারিটি যেখানে আপনি সূত্রটি প্রবেশ করেছেন ফলাফলগুলি ছড়িয়ে দেওয়ার জন্য পর্যাপ্ত ফাঁকা ঘর নেই। যদি প্রতিবেশী কক্ষগুলি দৃশ্যত খালি থাকে, তবে নিশ্চিত করুন যে সেগুলিতে কোনও স্পেস বা অন্যান্য অমুদ্রিত অক্ষর নেই। আরও তথ্যের জন্য, এক্সেলে #SPILL ত্রুটির অর্থ কী তা দেখুন৷

এভাবে আপনি একটি 2-মাত্রিক অ্যারে বা পরিসরকে একটি একক সারিতে রূপান্তর করতে এক্সেলের TOROW ফাংশনটি ব্যবহার করেন৷ আমি পড়ার জন্য আপনাকে ধন্যবাদ এবং আশা করি আগামী সপ্তাহে আমাদের ব্লগে আপনাকে দেখতে পাব!

ডাউনলোডের জন্য অনুশীলন ওয়ার্কবুক

এক্সেল টরো ফাংশন - সূত্র উদাহরণ (.xlsx ফাইল)