Clàr-innse
Dòigh sgiobalta air raon cheallan a thionndadh gu aon sreath le cuideachadh bhon ghnìomh TOROW .
Tha Microsoft Excel 365 air grunn ghnìomhan ùra a thoirt a-steach gus diofar làimhseachadh a dhèanamh le arrays. Le TOROW, faodaidh tu cruth-atharrachaidhean raon-gu-sreath a dhèanamh ann an ùine sam bith. Seo liosta de ghnìomhan as urrainn don ghnìomh ùr seo a choileanadh:
Tha an gnìomh TOROW ann an Excel air a chleachdadh gus sreath no raon de cheallan a thionndadh gu aon sreath.
Gabhaidh an gnìomh trì argamaidean uile gu lèir, agus chan eil a dhìth ach a' chiad tè dhiubh.
TOROW(eagar, [sainig], [scan_by_column])Càite:
Array (riatanach) - sreath no raon airson a thionndadh gu aon sreath.
Leig seachad (roghainneil) - a’ dearbhadh am bu chòir dhut beàrnan a leigeil seachad no/agus mearachdan. Gabhaidh tu aon dhe na luachan seo:
- 0 no air fhàgail a-mach (bunaiteach) - cùm a h-uile luach
- 1 - leig seachad beàrnan
- 2 - leig seachad mearachdan
- 3 - leig seachad beàrnan is mearachdan
Scan_by_column (roghainneil) - a’ mìneachadh mar a nì thu sganadh air an t-sreath:
- FALSE no air a fàgail às (bunaiteach) - scan an t-sreath gu còmhnard le sreath.
- TRUE - scan an t-sreath gu dìreach a rèir colbh.
Molaidhean:
- Gus cruth-atharrachadh a dhèanamh air rèite a-steach do aon cholbh, cleachd an gnìomh TOCOL.
- Gus an cruth-atharrachadh sreath-gu-sreath a thionndadh air ais, cleachd an dàrna cuid an gnìomh WRAPCOLS gus a dhol a-steach do cholbhan no an gnìomh WRAPROWS airson pasgadhsreath ann an sreathan.
- Gus sreathan a thionndadh gu colbhan, cleachd an gnìomh TRANSPOSE.
Torow ri fhaighinn
'S e gnìomh ùr a th' ann an TOROW, nach fhaighear taic ach ann an Excel airson Microsoft 365 (airson Windows agus Mac) agus Excel airson an lìon.
Foirmle bunaiteach TOROW ann an Excel
Gus cruth-atharrachadh sìmplidh raon-gu-sreath a dhèanamh, cleachd am foirmle TOROW anns a chruth bunaiteach. Airson seo, chan fheum thu ach a’ chiad argamaid a mhìneachadh ( eagar ).
Mar eisimpleir, gus sreath dà-thaobhach anns a bheil 3 colbhan is 3 sreathan a thionndadh gu aon sreath, an is e am foirmle:
=TOROW(A3:C6)
Cuiridh tu a-steach am foirmle a-steach do dìreach aon chealla (A10 sa chùis againn), agus bidh e gu fèin-obrachail a’ dòrtadh a-steach do na h-uimhir de chealla a dh’ fheumar gus na toraidhean gu lèir a chumail. Ann an teirmean Excel, canar raon dòrtadh ris an raon toraidh a tha air a chuairteachadh le crìoch tana gorm. 
Mar a tha am foirmle seo ag obair:
An toiseach, tha raon de cheallan a chaidh a sholarachadh air atharrachadh gu bhith na raon dà-thaobhach. Feuch an toir thu an aire do na colbhan le cromag agus na sreathan air an sgaradh le leth-choloin:
{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}
An uairsin, bidh an gnìomh TOROW a’ leughadh an t-sreath bho chlì gu deas agus ga thionndadh gu bhith na raon còmhnard aon-thaobhach:
{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}
Tha an toradh a’ dol gu ceal A10, às a bheil e a’ dòrtadh a-steach don chill ri thaobh air an taobh cheart.
Cruth-atharraich an raon gu sreath gun mhothachadh air beàrnan is mhearachdan
Gu gnàthach, bidh an gnìomh TOROW a ’cumail a h-uile luach bhon raon stòr, a’ toirt a-steach ceallan falamh agusmearachdan. San toradh, nochdaidh luachan neoni an àite cheallan bàn, a dh’ fhaodadh a bhith gu math troimh-a-chèile.
Gus beàrnan a thoirmeasg , suidhich an argamaid dearmad gu 1:
=TOROW(A3:C5, 1)
Gus dearmad a dhèanamh air mearachdan , suidhich an argamaid Leig seachad gu 2:
=TOROW(A3:C5, 2)
Airson leum an dà chuid, beàrnan is mearachdan , cleachd 3 airson an argamaid dearmad :
=TOROW(A3:C5, 3)
Tha an dealbh gu h-ìosal a’ sealltainn na trì suidheachaidhean a tha an gnìomh: <18
Leugh sreath gu còmhnard no gu dìreach
Leis a’ ghiùlan àbhaisteach, bidh an gnìomh TOROW a’ pròiseasadh an t-sreath gu còmhnard bho chlì gu deas. Gus na luachan a sganadh le colbh bho mhullach gu bonn, shuidhich thu an 3mh argamaid ( scan_by_column ) gu TRUE no 1.
Mar eisimpleir, airson an raon tùsail a leughadh le sreath, tha am foirmle ann an Is e E3:
=TOROW(A3:C5)
Gus an raon a sganadh le colbh, is e am foirmle ann an E8:
=TOROW(A3:C5, ,TRUE)
Anns gach suidheachadh, tha na h-arrays a thig às an aon mheud, ach tha na luachan air an rèiteachadh ann an òrdugh eadar-dhealaichte. 
Cuir grunn raointean còmhla ann an aon sreath
Gus grunn raointean nach eil faisg air làimh a chur còmhla ann an aon sreath, bidh thu gan càrnadh gu còmhnard no gu dìreach ann an aon sreath le cuideachadh bho HSTACK no VSTACK, fa leth. , agus an uair sin cleachd an gnìomh TOROW gus an t-sreath aonaichte a thionndadh gu sreath.
A-rèir reusanachaidh a' ghnìomhachais agad, nì aon dhe na foirmlean a leanas an obair.
Stack arrays gu còmhnard is tionndaidh le sreath
Leis a' chiad fhearraon ann an A3: C4 agus an dàrna raon ann an A8: C9, bidh am foirmle gu h-ìosal a’ cruachadh an dà raon gu còmhnard ann an aon sreath, agus an uairsin ga thionndadh gu sreath a’ leughadh na luachan bho chlì gu deas. Tha an toradh ann an E3 san dealbh gu h-ìosal.
=TOROW(HSTACK(A3:C4, A8:C9))
Stack arrays gu còmhnard is tionndaidh le colbh
Gus an t-sreath chruach a leughadh gu dìreach bho mhullach gu bonn, shuidhich thu an treas argamaid TOROW gu TRUE mar a chithear ann an E5 san dealbh gu h-ìosal:
=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)
Stack arrays gu dìreach agus tionndaidh le sreath
Gus gach fear a chur ris sreath às deidh sin gu bonn an t-sreath roimhe agus leugh an t-sreath aonaichte gu còmhnard, is e am foirmle ann an E12:
=TOROW(VSTACK(A3:C4, A8:C9))
Stack arrays gu dìreach agus tionndaidh le colbh
Gus gach sreath às deidh sin a chur ri bonn an tè roimhe agus sganadh an t-sreath aonaichte gu dìreach, is e am foirmle:
=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)
Gus an loidsig a thuigsinn nas fheàrr, cùm sùil air an òrdugh luachan eadar-dhealaichte ann an na rèilichean a thig às: 
Thoir a-mach luachan gun samhail bho raon gu sreath
A’ tòiseachadh le Microsoft Excel 2016, tha gnìomh iongantach againn, leis an t-ainm UNIQUE, a gheibh luachan gun samhail bho aon cholbh gu furasta no sreath. Ach, chan urrainn dha arrays ioma-colbh a làimhseachadh. Airson faighinn seachad air a' chuingealachadh seo, cleachd na gnìomhan UNIQUE agus TOROW còmhla.
Mar eisimpleir, gus na diofar luachan (sònraichte) a thoirt a-mach às an raon A2:C7 agus na toraidhean a chur ann an aon sreath, bidh anis e am foirmle:
=UNIQUE(TOROW(A2:C7), TRUE)
Mar a thilleas TOROW sreath chòmhnard aon-thaobhach, shuidhich sinn an 2na argamaid ( by_col ) de UNIQUE gu TRUE gus coimeas a dhèanamh eadar na colbhan mu choinneamh gach eile.
Air eagal 's gu bheil thu ag iarraidh na toraidhean ann an òrdugh na h-aibideil, cuir a-steach am foirmle gu h-àrd san ghnìomh SORT:
=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )
Coltach ri UNIQUE, an by_col Tha argamaid SORT cuideachd air a shuidheachadh gu TRUE. 
Rogha eile TOROW airson Excel 365 - 2010
Ann an dreachan Excel far nach eil an gnìomh TOROW ri fhaighinn, faodaidh tu raon atharrachadh gu aon sreath a’ cleachdadh measgachadh de ghrunn ghnìomhan eadar-dhealaichte a tha ag obair ann. tionndaidhean nas sine. Tha na fuasglaidhean seo nas toinnte, ach obraichidh iad.
Gus an raon a sganadh gu còmhnard, is e am foirmle coitcheann:
INDEX( raon , QUOTIENT(COLUMN (A1)-1, COLUMNS( raon ))+1, MOD(COLUMN(A1)-1,COLUMNS( raon ))+1)Gus an raon a sganadh gu dìreach, is e am foirmle coitcheann :
INDEX( raon , MOD(COLUMN(A1)-1,COLUMNS( raon ))+1,QUOTIENT(COLUMN(A1)-1,COLUMNS(<15)>raon ))+1)Airson an t-sampall dàta againn ann an A3:C5, gabhaidh na foirmlean an cumadh seo:
Gus an raon a sganadh le sreath:
=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)
'S e roghainn eile a tha san fhoirmle seo seach a' ghnìomh TOROW leis an 3mh argamaid air a suidheachadh gu FALSE no air a fàgail a-mach:
=TOROW(A3:C5)
Gus an raon a sganadh le colbh:
=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)
Tha am foirmle seo co-ionann ris a’ ghnìomh TOROW leis an treas argamaid air a suidheachadh guTRUE:
=TOROW(A3:C5, ,TRUE)
Thoir an aire, eu-coltach ris a’ ghnìomh TOROW array fiùghantach, gum bu chòir na foirmlean traidiseanta seo a chur a-steach anns gach cealla far a bheil thu airson gun nochd na toraidhean. Anns a 'chùis againn, tha a' chiad fhoirmle (le sreath) a 'dol gu E3 agus air a lethbhreacadh tro M3. Tha an dàrna foirmle (le colbh) a' tighinn gu tìr ann an E8 agus ga shlaodadh tro M8.
Airson lethbhreac ceart a dhèanamh de na foirmlean, glasaidh sinn an raon a' cleachdadh iomraidhean iomlan ($A$3:$C$5). Nì raon ainmichte cuideachd.
Ma tha thu air na foirmlean a chopaigeadh gu barrachd cheallan na bha a dhìth, bidh #REF! nochdaidh mearachd ann an ceallan “a bharrachd”. Gus seo a chàradh, paisg am foirmle agad san ghnìomh IFERROR mar seo:
=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "") 
Mar a tha na foirmlean seo ag obair
Gu h-ìosal tha briseadh-sìos mionaideach den chiad fhoirmle a tha a' rèiteachadh nan luachan a-rèir sreath:
=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)
Aig cridhe na foirmle, bidh sinn a' cleachdadh an gnìomh INDEX gus luach cealla fhaighinn stèidhichte air a shuidheachadh co-cheangailte anns an raon.
Tha an àireamh sreatha air a thomhas leis an fhoirmle seo:
QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1
Is e am beachd sreath àireamhan ath-aithris a dhèanamh leithid 1,1 ,1,2,2,2,3,3,3, …far a bheil gach àireamh ag ath-aithris cho tric 's a tha colbhan san raon thùsail. Agus seo mar a nì sinn seo:
Tillidh QUOTIENT a’ chuibhreann iomlan de roinn.
Airson àireamhair , bidh sinn a’ cleachdadh COLUMN(A1)-1, a thilleas sreathach àireamh bho 0 sa chiad chill far a bheil am foirmle air a chur a-steach gu n (àireamh iomlan de luachan san raonàs aonais 1) anns a’ chill mu dheireadh far an deach am foirmle a-steach. San eisimpleir seo, tha 0 againn ann an E2 agus 8 ann am M3.
Airson ainmichear , cleachdaidh sinn COLUMNS($A$3:$C$5)). Bidh seo a’ tilleadh àireamh sheasmhach co-ionann ris an àireamh de cholbhan san raon agad (3 sa chùis againn).
Mar thoradh air an sin, bidh an gnìomh QUOTIENT a’ tilleadh 0 anns a’ chiad 3 ceallan (E3: G3), ris am bi sinn cuir 1 ris, mar sin 's e 1 àireamh na loidhne.
Airson na 3 ceallan a leanas (H3:J3), tillidh QUOTIENT 1, agus bheir +1 àireamh na loidhne 2. Agus mar sin air adhart.
Gus an àireamh colbh obrachadh a-mach, togaidh tu sreath àireimh iomchaidh a’ cleachdadh gnìomh MOD:
MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1
Leis gu bheil 3 colbhan nar raon, feumaidh an t-sreath a bhith coltach : 1,2,3,1,2,3,…
Tillidh gnìomh MOD an còrr an dèidh sgaradh.
Ann an E3, MOD(COLUMN(A1)-1, COLUMNS($ A$3:$C$5))+
gu bhith
MOD(1-1, 3)+1)
agus a' tilleadh 1.
In F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+
a’ fàs
MOD(2-1, 3)+1)
agus tillidh e 2.
Aon uair 's gu bheil na h-àireamhan loidhne agus colbh stèidhichte, gheibh INDEX an luach gu furasta aig crois-rathaid na loidhne agus a' cholbh sin.
Ann an E3, INDEX($A$3 : $C$5, 1, 1) a’ tilleadh luach bhon 1d sreath agus bhon 1d colbh den raon air a bheil iomradh, i.e. bho chill A3.
Ann an F3, tha INDEX ($A$3:$C$5, 1, 2) a’ tilleadh luach bhon 1d sreath agus an 2na colbh, ie bho cheal B3.
Agus mar sin air adhart.
Tha an dàrna foirmle a sgrobhas an raon le colbh, ag obair ann an adòigh coltach ris. Is e an diofar gu bheil sinn a’ cleachdadh MOD gus àireamh na loidhne obrachadh a-mach agus QUOTIENT gus àireamh a’ cholbh obrachadh a-mach.
Factaraidh TOROW nach eil ag obair
Ma dh’ adhbhraicheas an gnìomh TOROW mearachd, ’s e 'S dòcha gur e seo aon de na h-adhbharan seo:
#NAME? mearachd
Leis a’ mhòr-chuid de ghnìomhan Excel, a #NAME? tha mearachd na chomharra soilleir gu bheil ainm a’ ghnìomh air a litreachadh ceàrr. Le TOROW, is dòcha gu bheil e cuideachd a’ ciallachadh nach eil an gnìomh ri fhaighinn san Excel agad. Ma tha an tionndadh Excel agad ann an seach 365, feuch ri roghainn eile TOROW a chleachdadh.
#NUM error
Tha mearachd #NUM a' nochdadh nach urrainn dhan t-sreath a th' air a thilleadh a dhol a-steach do shreath. Mar as trice bidh sin a’ tachairt nuair a bheir thu iomradh air colbhan slàn agus/no sreathan an àite raon nas lugha.
Mearachd #SPILL
Mar as trice, tha mearachd #SPILL a’ nochdadh gu bheil an loidhne far a bheil chan eil ceallan bàn gu leòr agad airson na toraidhean a dhòrtadh a-steach. Ma tha na ceallan faisg air làimh falamh gu fradharcach, dèan cinnteach nach eil beàrnan no caractaran neo-chlò-bhualaidh eile annta. Airson tuilleadh fiosrachaidh, faic Dè tha mearachd #SPILL a’ ciallachadh ann an Excel.
Sin mar a chleachdas tu gnìomh TOROW ann an Excel gus raon no raon 2-mheudach a thionndadh gu sreath shingilte. Tha mi a’ toirt taing dhut airson an leughadh agus an dòchas ur faicinn air ar blog an ath sheachdain!
Leabhar-obrach cleachdaidh airson a luchdachadh sìos
Gnìomh Excel TOROW - eisimpleirean foirmle (faidhle .xlsx)
3, 2012, 2011
