უჯრედების დიაპაზონის ერთ მწკრივად გადაქცევის სწრაფი გზა TOROW ფუნქციის დახმარებით.

Microsoft Excel 365-მა შემოიტანა რამდენიმე ახალი ფუნქცია სხვადასხვა მანიპულაციების შესრულება მასივებით. TOROW-ით თქვენ შეგიძლიათ შეასრულოთ დიაპაზონიდან მწკრივში ტრანსფორმაციები უმოკლეს დროში. აქ მოცემულია ამოცანების სია, რომელთა შესრულებაც ამ ახალ ფუნქციას შეუძლია:

Excel TOROW ფუნქცია

TOROW ფუნქცია Excel-ში გამოიყენება მასივის ან უჯრედების დიაპაზონის გადასაყვანად. ერთი მწკრივი.

ფუნქცია იღებს სულ სამ არგუმენტს, რომელთაგან მხოლოდ პირველია საჭირო.

TOROW(მასივი, [იგნორირება], [სკანირება_სვეტის მიხედვით])

სად:

მასივი (აუცილებელია) - მასივი ან დიაპაზონი, რომელიც გარდაიქმნება ერთ მწკრივად.

იგნორირება (სურვილისამებრ) - განსაზღვრავს თუ არა იგნორირებას ბლანკები ან/და შეცდომები. შეუძლია მიიღოს ერთ-ერთი ასეთი მნიშვნელობა:

• 0 ან გამოტოვებული (ნაგულისხმევი) - ყველა მნიშვნელობის შენარჩუნება
• 1 - ცარიელი ადგილების იგნორირება
• 2 - შეცდომების იგნორირება
• 3 - ბლანკების და შეცდომების იგნორირება

Scan_by_column (სურვილისამებრ) - განსაზღვრავს, თუ როგორ უნდა სკანირდეს მასივი:

• FALSE ან გამოტოვებული (ნაგულისხმევი) - დაასკანირეთ მასივი ჰორიზონტალურად მწკრივის მიხედვით.
• TRUE - დაასკანირეთ მასივი ვერტიკალურად სვეტების მიხედვით.

რჩევები:

• მაივის გარდაქმნა ერთ სვეტად, გამოიყენეთ TOCOL ფუნქცია.
• შებრუნებული მწკრივი მასივის ტრანსფორმაციისთვის გამოიყენეთ ან WRAPCOLS ფუნქცია სვეტებად გადასახვევად ან WRAPROWS ფუნქცია გადასახვევადმასივი მწკრივად.
• მწკრივების სვეტებად გადაქცევისთვის გამოიყენეთ TRANSPOSE ფუნქცია.

TOROW ხელმისაწვდომობა

TOROW არის ახალი ფუნქცია, რომელიც მხარდაჭერილია მხოლოდ Excel-ში. Microsoft 365-ისთვის (Windows და Mac-ისთვის) და Excel-ისთვის ვებისთვის.

ძირითადი TOROW ფორმულა Excel-ში

მარტივი დიაპაზონიდან მწკრივის ტრანსფორმაციისთვის გამოიყენეთ TOROW ფორმულა თავის ძირითად ფორმაში. ამისათვის თქვენ უნდა განსაზღვროთ მხოლოდ პირველი არგუმენტი ( მასივი ).

მაგალითად, 3 სვეტისა და 3 მწკრივისაგან შემდგარი ორგანზომილებიანი მასივი გადააქციოთ ერთ მწკრივად, ფორმულა არის:

=TOROW(A3:C6)

თქვენ შეიყვანთ ფორმულას მხოლოდ ერთ უჯრედში (ჩვენს შემთხვევაში A10) და ის ავტომატურად იღვრება იმდენ უჯრედში, რამდენიც საჭიროა ყველა შედეგის შესანახად. Excel-ის თვალსაზრისით, გამომავალი დიაპაზონი, რომელიც გარშემორტყმულია თხელი ლურჯი საზღვრით, ეწოდება დაღვრის დიაპაზონს.

როგორ მუშაობს ეს ფორმულა:

პირველ რიგში, უჯრედების მიწოდებული დიაპაზონი გარდაიქმნება ორგანზომილებიან მასივად. გთხოვთ გაითვალისწინოთ მძიმით გამოყოფილი სვეტები და მძიმით გამოყოფილი რიგები:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

შემდეგ, TOROW ფუნქცია კითხულობს მასივს მარცხნიდან მარჯვნივ და გარდაქმნის მას ერთგანზომილებიან ჰორიზონტალურ მასივად:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

შედეგი გადადის A10 უჯრედში, საიდანაც ის იღვრება მეზობელ უჯრედში მარჯვნივ.

დიაპაზონის გადაყვანა მწკრივში, იგნორირებას უკეთებს ბლანკებს და შეცდომებს

ნაგულისხმევად, TOROW ფუნქცია ინახავს ყველა მნიშვნელობას წყაროს მასივიდან, ცარიელი უჯრედების ჩათვლით დაშეცდომები. გამომავალში ნულოვანი მნიშვნელობები გამოჩნდება ცარიელი უჯრედების ადგილას, რაც შეიძლება საკმაოდ დამაბნეველი იყოს.

ბლანკების გამოსარიცხად დააყენეთ არგუმენტი იგნორირება 1:

=TOROW(A3:C5, 1)

შეცდომების უგულებელყოფისთვის დააყენეთ არგუმენტი იგნორირება 2:

=TOROW(A3:C5, 2)

გამოტოვებისთვის ორივე, ცარიელები და შეცდომები გამოიყენეთ 3 იგნორირება არგუმენტისთვის:

=TOROW(A3:C5, 3)

ქვემოთ მოცემული სურათი აჩვენებს სამივე სცენარს მოქმედებაში:

კითხვა მასივის ჰორიზონტალურად ან ვერტიკალურად

ნაგულისხმევი ქცევით, TOROW ფუნქცია ამუშავებს მასივს ჰორიზონტალურად მარცხნიდან მარჯვნივ. მნიშვნელობების სვეტის მიხედვით ზემოდან ქვემოდან სკანირებისთვის, თქვენ დააყენეთ მე-3 არგუმენტი ( scan_by_column ) TRUE ან 1.

მაგალითად, წყაროს დიაპაზონის მწკრივის მიხედვით წასაკითხად, ფორმულა E3 არის:

=TOROW(A3:C5)

დიაპაზონის სვეტების მიხედვით სკანირებისთვის, E8-ში ფორმულა არის:

=TOROW(A3:C5, ,TRUE)

ორივე შემთხვევაში, მიღებული მასივები არის იგივე ზომა, მაგრამ მნიშვნელობები განლაგებულია განსხვავებული თანმიმდევრობით.

მრავალი დიაპაზონის შერწყმა ერთ მწკრივში

რამდენიმე არამიმდებარე დიაპაზონის ერთ მწკრივში გაერთიანებისთვის, თქვენ ჯერ ჰორიზონტალურად ან ვერტიკალურად აწყობთ ერთ მასივში HSTACK-ის ან VSTACK-ის დახმარებით, შესაბამისად. , და შემდეგ გამოიყენეთ TOROW ფუნქცია კომბინირებული მასივის მწკრივად გადასაყვანად.

თქვენი ბიზნეს ლოგიკის მიხედვით, ერთ-ერთი შემდეგი ფორმულა შეასრულებს დავალებას.

დაწყობა მასივები ჰორიზონტალურად და გადააკეთეთ რიგი

პირველთანდიაპაზონი A3:C4-ში და მეორე დიაპაზონი A8:C9-ში, ქვემოთ მოცემული ფორმულა დააწყობს ორ დიაპაზონს ჰორიზონტალურად ერთ მასივში და შემდეგ გარდაქმნის მას მწკრივად, რომელიც წაიკითხავს მნიშვნელობებს მარცხნიდან მარჯვნივ. შედეგი არის E3 ქვემოთ მოცემულ სურათზე.

=TOROW(HSTACK(A3:C4, A8:C9))

დაწყობა მასივები ჰორიზონტალურად და გადაიყვანეთ სვეტების მიხედვით

დაწყობილი მასივის ვერტიკალურად წასაკითხად ზემოდან ქვემოდან, თქვენ დააყენეთ TOROW-ის მე-3 არგუმენტი TRUE-ზე, როგორც ნაჩვენებია E5-ზე ქვემოთ მოცემულ სურათზე:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

დააწყვეთ მასივები ვერტიკალურად და გადააკეთეთ მწკრივით

თითოეულის დასამატებლად შემდეგი მასივი წინა მასივის ბოლოში და წაიკითხეთ კომბინირებული მასივი ჰორიზონტალურად, ფორმულა E12-ში არის:

=TOROW(VSTACK(A3:C4, A8:C9))

დააწყვეთ მასივები ვერტიკალურად და გადააკეთეთ სვეტების მიხედვით

ყოველი მომდევნო მასივის დასამატებლად წინა მასივის ბოლოში და კომბინირებული მასივის ვერტიკალურად სკანირებისთვის, ფორმულა არის:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

ლოგიკის უკეთ გასაგებად, დააკვირდით მნიშვნელობების სხვადასხვა წესრიგს შედეგად მიღებული მასივები:

გამოყავით უნიკალური მნიშვნელობები დიაპაზონიდან მწკრივში

Microsoft Excel 2016-ით დაწყებული, ჩვენ გვაქვს შესანიშნავი ფუნქცია, სახელად UNIQUE, რომელიც ადვილად იღებს უნიკალურ მნიშვნელობებს ერთი სვეტიდან ან რიგი. თუმცა, მას არ შეუძლია გაუმკლავდეს მრავალსვეტიან მასივებს. ამ შეზღუდვის დასაძლევად გამოიყენეთ UNIQUE და TOROW ფუნქციები ერთად.

მაგალითად, ამოიღოთ ყველა განსხვავებული (განსხვავებული) მნიშვნელობა A2:C7 დიაპაზონიდან და მოათავსოთ შედეგები ერთ რიგში,ფორმულა არის:

=UNIQUE(TOROW(A2:C7), TRUE)

რადგან TOROW აბრუნებს ერთგანზომილებიან ჰორიზონტალურ მასივს, ჩვენ დავაყენეთ მე-2 ( by_col ) არგუმენტი UNIQUE-ზე TRUE-ზე, რათა შევადაროთ სვეტები თითოეულს. სხვა.

თუ გსურთ შედეგები დალაგდეს ანბანური თანმიმდევრობით, გადაიტანეთ ზემოაღნიშნული ფორმულა SORT ფუნქციაში:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

ისევე როგორც UNIQUE, by_col SORT-ის არგუმენტი ასევე დაყენებულია TRUE-ზე.

TOROW ალტერნატივა Excel 365 - 2010

Excel-ის ვერსიებში, სადაც TOROW ფუნქცია მიუწვდომელია, შეგიძლიათ დიაპაზონი გადააქციოთ ერთ მწკრივად რამდენიმე სხვადასხვა ფუნქციის კომბინაციის გამოყენებით, რომლებიც მუშაობს ძველი ვერსიები. ეს გადაწყვეტილებები უფრო რთულია, მაგრამ ისინი მუშაობენ.

დიაპაზონის ჰორიზონტალურად სკანირებისთვის, ზოგადი ფორმულა არის:

INDEX( დიაპაზონი , QUOTIENT(COLUMN (A1)-1, COLUMNS( დიაპაზონი ))+1, MOD(COLUMN(A1)-1, COLUMNS( დიაპაზონი ))+1)

დიაპაზონის ვერტიკალურად სკანირებისთვის, ზოგადი ფორმულა არის :

INDEX( დიაპაზონი , MOD(COLUMN(A1)-1, COLUMNS( დიაპაზონი ))+1, QUOTIENT(COLUMN (A1)-1, COLUMNS( დიაპაზონი ))+1)

ჩვენი ნიმუშის მონაცემთა ნაკრებისთვის A3:C5, ფორმულები იღებენ ასეთ ფორმას:

დიაპაზონის სკანირებისთვის მწკრივის მიხედვით:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

ეს ფორმულა არის TOROW ფუნქციის ალტერნატივა მე-3 არგუმენტით დაყენებულია FALSE ან გამოტოვებული:

=TOROW(A3:C5)

დიაპაზონის სკანირება სვეტი:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

ეს ფორმულა ტოლია TOROW ფუნქციის მე-3 არგუმენტით დაყენებულიTRUE:

=TOROW(A3:C5, ,TRUE)

გთხოვთ, გაითვალისწინოთ, რომ განსხვავებით დინამიური მასივის TOROW ფუნქციისგან, ეს ტრადიციული ფორმულები უნდა შეიყვანოთ თითოეულ უჯრედში, სადაც გსურთ შედეგები გამოჩნდეს. ჩვენს შემთხვევაში, პირველი ფორმულა (მწკრივის მიხედვით) მიდის E3-ზე და კოპირებულია M3-ის საშუალებით. მეორე ფორმულა (სვეტის მიხედვით) ეშვება E8-ში და გადაათრიეს M8-ში.

ფორმულების სწორად კოპირებისთვის, ჩვენ ვბლოკავთ დიაპაზონს აბსოლუტური მითითებების გამოყენებით ($A$3:$C$5). დასახელებული დიაპაზონი ასევე მუშაობს.

თუ თქვენ დააკოპირეთ ფორმულები საჭიროზე მეტ უჯრედში, #REF! შეცდომა გამოჩნდება "ზედმეტ" უჯრედებში. ამის გამოსწორების მიზნით, ჩაალაგეთ თქვენი ფორმულა IFERROR ფუნქციაში ასე:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

როგორ მუშაობს ეს ფორმულები

ქვემოთ არის დეტალური განხილვა პირველი ფორმულის, რომელიც აწყობს მნიშვნელობებს მწკრივის მიხედვით:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

ფორმულის ცენტრში, ჩვენ ვიყენებთ INDEX ფუნქციას, რათა მივიღოთ უჯრედის მნიშვნელობა მისი ფარდობითი პოზიციიდან გამომდინარე. დიაპაზონი.

მწკრივის რიცხვი გამოითვლება ამ ფორმულით:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

იდეა წარმოიქმნას განმეორებადი რიცხვების თანმიმდევრობა, როგორიცაა 1,1 ,1,2,2,2,3,3,3, ... სადაც თითოეული რიცხვი იმდენჯერ მეორდება, რამდენჯერაც არის სვეტები წყაროს დიაპაზონში. და აი, როგორ ვაკეთებთ ამას:

QUOTIENT აბრუნებს გაყოფის მთელ ნაწილს.

მრიცხველისთვის , ჩვენ ვიყენებთ COLUMN(A1)-1, რომელიც აბრუნებს სერიებს. რიცხვი 0-დან პირველ უჯრედში, სადაც ფორმულა შეყვანილია n (მნიშვნელობების საერთო რაოდენობა დიაპაზონშიმინუს 1) ბოლო უჯრედში, სადაც ფორმულა შევიდა. ამ მაგალითში გვაქვს 0 E2-ში და 8 M3-ში.

მნიშვნელისთვის , ჩვენ ვიყენებთ COLUMNS($A$3:$C$5)). ეს აბრუნებს მუდმივ რიცხვს, რომელიც ტოლია თქვენს დიაპაზონში სვეტების რაოდენობას (ჩვენს შემთხვევაში 3).

შედეგად, QUOTIENT ფუნქცია აბრუნებს 0-ს პირველ 3 უჯრედში (E3:G3), რომელსაც ჩვენ დაამატეთ 1, ასე რომ, მწკრივის ნომერი არის 1.

შემდეგი 3 უჯრედისთვის (H3:J3), QUOTIENT აბრუნებს 1-ს და +1 აძლევს მწკრივის ნომერს 2. და ასე შემდეგ.

სვეტის ნომრის გამოსათვლელად , თქვენ ქმნით შესაბამის რიცხვთა თანმიმდევრობას MOD ფუნქციის გამოყენებით:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

რადგან ჩვენს დიაპაზონში 3 სვეტია, თანმიმდევრობა ასე უნდა გამოიყურებოდეს : 1,2,3,1,2,3,…

MOD ფუნქცია აბრუნებს დანარჩენს გაყოფის შემდეგ.

E3, MOD(COLUMN(A1)-1, COLUMNS($ A$3:$C$5))+

იქცევა

MOD(1-1, 3)+1)

და აბრუნებს 1.

ში F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

იქცევა

MOD(2-1, 3)+1)

და აბრუნებს 2-ს.

როდესაც მწკრივისა და სვეტის ნომრები დადგინდება, INDEX ადვილად იღებს მნიშვნელობას ამ მწკრივისა და სვეტის გადაკვეთაზე.

E3-ში, INDEX($A$3 :$C$5, 1, 1) აბრუნებს მნიშვნელობას 1 მწკრივიდან და 1 სვეტიდან მითითებული დიაპაზონის, ანუ A3 უჯრედიდან.

F3-ში, INDEX($A$3:$C$5, 1, 2) აბრუნებს მნიშვნელობას 1-ლი მწკრივიდან და მე-2 სვეტიდან, ანუ B3 უჯრედიდან.

და ასე შემდეგ.

მეორე ფორმულა, რომელიც სკანირებს დიაპაზონს სვეტის მიხედვით, მუშაობსმსგავსი გზით. განსხვავება ისაა, რომ ჩვენ ვიყენებთ MOD მწკრივის ნომრის გამოსათვლელად და QUOTIENT-ს სვეტის ნომრის გასარკვევად.

TOROW ფუნქცია არ მუშაობს

თუ TOROW ფუნქცია იწვევს შეცდომას, ეს არის სავარაუდოდ ეს არის ერთ-ერთი ასეთი მიზეზი:

#NAME? შეცდომა

Excel-ის უმეტესი ფუნქციების შემთხვევაში არის #NAME? შეცდომა აშკარად მიუთითებს, რომ ფუნქციის სახელი არასწორად არის დაწერილი. TOROW-ით, ეს შეიძლება ასევე ნიშნავს, რომ ფუნქცია მიუწვდომელია თქვენს Excel-ში. თუ თქვენი Excel ვერსია 365-ის გარდა, სცადეთ გამოიყენოთ TOROW ალტერნატივა.

#NUM შეცდომა

#NUM შეცდომა მიუთითებს, რომ დაბრუნებული მასივი ვერ ჯდება მწკრივში. ყველაზე ხშირად ეს ხდება მაშინ, როდესაც თქვენ მიმართავთ მთელ სვეტებს და/ან რიგებს მცირე დიაპაზონის ნაცვლად.

#SPILL შეცდომა

უმეტეს შემთხვევაში, #SPILL შეცდომა ვარაუდობს, რომ მწკრივი, სადაც თქვენ შეიყვანეთ ფორმულა არ აქვს საკმარისი ცარიელი უჯრედები შედეგების გამოსატანად. თუ მეზობელი უჯრედები ვიზუალურად ცარიელია, დარწმუნდით, რომ მათში არ არის სივრცეები ან სხვა არასაბეჭდი სიმბოლოები. დამატებითი ინფორმაციისთვის იხილეთ რას ნიშნავს #SPILL შეცდომა Excel-ში.

ასე იყენებთ TOROW ფუნქციას Excel-ში ორგანზომილებიანი მასივის ან დიაპაზონის ერთ მწკრივად გადასაყვანად. მადლობას გიხდით წაკითხვისთვის და იმედი მაქვს, რომ მომავალ კვირას გნახავთ ჩვენს ბლოგზე!

სავარჯიშო სამუშაო წიგნი ჩამოსატვირთად

Excel TOROW ფუნქცია - ფორმულის მაგალითები (ფაილი .xlsx)