yardımıyla bir hücre aralığını tek bir satıra dönüştürmenin hızlı bir yolu TOROW fonksiyon.

Microsoft Excel 365, dizilerle çeşitli manipülasyonlar gerçekleştirmek için birkaç yeni işlev sundu. TOROW ile aralıktan satıra dönüşümleri anında gerçekleştirebilirsiniz. İşte bu yeni işlevin gerçekleştirebileceği görevlerin bir listesi:

Excel TOROW işlevi

Excel'deki TOROW işlevi, bir diziyi veya hücre aralığını tek bir satıra dönüştürmek için kullanılır.

Fonksiyon toplam üç argüman alır ve bunlardan sadece ilki gereklidir.

Nerede?

Dizi (gerekli) - tek bir satıra dönüştürülecek bir dizi veya aralık.

Görmezden gel (isteğe bağlı) - boşlukların ve/veya hataların göz ardı edilip edilmeyeceğini belirler. Bu değerlerden birini alabilir:

• 0 veya atlanmış (varsayılan) - tüm değerleri koru
• 1 - boşlukları yoksay
• 2 - hataları görmezden gelin
• 3 - boşlukları ve hataları göz ardı edin

Scan_by_column (isteğe bağlı) - dizinin nasıl taranacağını tanımlar:

• FALSE veya atlanmış (varsayılan) - diziyi satıra göre yatay olarak tarar.
• TRUE - diziyi sütuna göre dikey olarak tarar.

İpuçları:

• Bir diziyi tek bir sütuna dönüştürmek için TOCOL işlevini kullanın.
• Ters satır-dizi dönüşümünü önceden gerçekleştirmek için, sütunlara sarmak üzere WRAPCOLS işlevini veya diziyi satırlara sarmak üzere WRAPROWS işlevini kullanın.
• Satırları sütunlara dönüştürmek için TRANSPOSE işlevini kullanın.

TOROW kullanılabilirliği

TOROW, yalnızca Microsoft 365 için Excel (Windows ve Mac için) ve Web için Excel'de desteklenen yeni bir işlevdir.

Excel'de temel TOROW formülü

Basit bir aralıktan satıra dönüşüm yapmak için TOROW formülünü temel biçiminde kullanın. Bunun için yalnızca ilk bağımsız değişkeni tanımlamanız gerekir ( dizi ).

Örneğin, 3 sütun ve 3 satırdan oluşan iki boyutlu bir diziyi tek bir satıra dönüştürmek için formül şöyledir:

=TOROW(A3:C6)

Formülü yalnızca bir hücreye (bizim durumumuzda A10) girersiniz ve formül otomatik olarak tüm sonuçları tutmak için gereken sayıda hücreye dökülür. Excel terimlerinde, ince mavi bir kenarlıkla çevrili çıktı aralığına dökülme aralığı denir.

Bu formül nasıl çalışır?

İlk olarak, verilen bir hücre aralığı iki boyutlu bir diziye dönüştürülür. Lütfen virgülle ayrılmış sütunlara ve noktalı virgülle ayrılmış satırlara dikkat edin:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

Ardından, TOROW işlevi diziyi soldan sağa okur ve tek boyutlu yatay bir diziye dönüştürür:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

Sonuç A10 hücresine gider ve buradan sağdaki komşu hücreye dökülür.

Boşlukları ve hataları yok sayarak aralığı satıra dönüştürme

Varsayılan olarak, TOROW işlevi boş hücreler ve hatalar da dahil olmak üzere kaynak dizideki tüm değerleri tutar. Çıktıda, boş hücrelerin yerine sıfır değerleri görünür ve bu oldukça kafa karıştırıcı olabilir.

için boşlukları hariç tut , ayarla görmezden gel argümanı 1'e:

=TOROW(A3:C5, 1)

için hataları görmezden gel , ayarla görmezden gel argümanı 2'ye:

=TOROW(A3:C5, 2)

İkisini de atlamak için, boşluklar ve hatalar için 3 kullanın. görmezden gel Tartışma:

=TOROW(A3:C5, 3)

Aşağıdaki resim her üç senaryoyu da iş başında göstermektedir:

Diziyi yatay veya dikey olarak okuma

Varsayılan davranışta, TOROW işlevi diziyi soldan sağa yatay olarak işler. Değerleri yukarıdan aşağıya doğru sütuna göre taramak için, 3. bağımsız değişkeni ( scan_by_column ) değerini TRUE veya 1 olarak ayarlayın.

Örneğin, kaynak aralığını satıra göre okumak için E3'teki formül şöyledir:

=TOROW(A3:C5)

Aralığı sütuna göre taramak için E8'deki formül şöyledir:

=TOROW(A3:C5, ,TRUE)

Her iki durumda da ortaya çıkan diziler aynı boyuttadır, ancak değerler farklı bir sırada düzenlenmiştir.

Birden fazla aralığı tek bir satırda birleştirme

Bitişik olmayan birkaç aralığı tek bir satırda birleştirmek için, önce bunları sırasıyla HSTACK veya VSTACK yardımıyla yatay veya dikey olarak tek bir dizide istiflersiniz ve ardından birleştirilmiş diziyi bir satıra dönüştürmek için TOROW işlevini kullanırsınız.

İş mantığınıza bağlı olarak, aşağıdaki formüllerden biri görevi yerine getirecektir.

Dizileri yatay olarak yığınlayın ve satıra göre dönüştürün

İlk aralık A3:C4 ve ikinci aralık A8:C9 iken, aşağıdaki formül iki aralığı yatay olarak tek bir diziye yığacak ve ardından değerleri soldan sağa okuyan bir satıra dönüştürecektir. Sonuç aşağıdaki resimde E3'tedir.

=TOROW(HSTACK(A3:C4, A8:C9))

Dizileri yatay olarak yığınlayın ve sütuna göre dönüştürün

Yığılmış diziyi yukarıdan aşağıya doğru dikey olarak okumak için, aşağıdaki resimde E5'te gösterildiği gibi TOROW'un 3. argümanını TRUE olarak ayarlarsınız:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

Dizileri dikey olarak yığınlama ve satıra göre dönüştürme

Sonraki her diziyi bir önceki dizinin altına eklemek ve birleştirilmiş diziyi yatay olarak okumak için E12'deki formül kullanılır:

=TOROW(VSTACK(A3:C4, A8:C9))

Dizileri dikey olarak yığınlayın ve sütuna göre dönüştürün

Sonraki her diziyi bir öncekinin altına eklemek ve birleştirilmiş diziyi dikey olarak taramak için formül şöyledir:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

Mantığı daha iyi anlamak için, ortaya çıkan dizilerdeki farklı değer sıralarını gözlemleyin:

Bir aralıktaki benzersiz değerleri bir satıra çıkarma

Microsoft Excel 2016'dan itibaren, tek bir sütun veya satırdan benzersiz değerleri kolayca alabilen UNIQUE adlı harika bir işleve sahibiz. Ancak, çok sütunlu dizileri işleyemez. Bu sınırlamanın üstesinden gelmek için UNIQUE ve TOROW işlevlerini birlikte kullanın.

Örneğin, A2:C7 aralığındaki tüm farklı (belirgin) değerleri ayıklamak ve sonuçları tek bir satıra yerleştirmek için formül şöyledir:

=UNIQUE(TOROW(A2:C7), TRUE)

TOROW tek boyutlu yatay bir dizi döndürdüğünden, 2. ( by_col ) argümanının UNIQUE değerini TRUE olarak değiştirerek sütunları birbirleriyle karşılaştırın.

Sonuçların alfabetik sıraya göre düzenlenmesini istemeniz durumunda, yukarıdaki formülü SORT işlevine sarın:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

UNIQUE'de olduğu gibi by_col argümanı da TRUE olarak ayarlanır.

Excel 365 - 2010 için TOROW alternatifi

TOROW işlevinin kullanılamadığı Excel sürümlerinde, eski sürümlerde çalışan birkaç farklı işlevin birleşimini kullanarak bir aralığı tek bir satıra dönüştürebilirsiniz. Bu çözümler daha karmaşıktır, ancak işe yararlar.

Aralığı yatay olarak taramak için genel formül şöyledir:

Aralığı dikey olarak taramak için genel formül şöyledir:

A3:C5'teki örnek veri setimiz için formüller bu şekli alır:

Aralığı satır bazında taramak için:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Bu formül, 3. bağımsız değişkenin FALSE olarak ayarlandığı veya atlandığı TOROW işlevine bir alternatiftir:

=TOROW(A3:C5)

Aralığı sütuna göre taramak için:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Bu formül, 3. bağımsız değişken TRUE olarak ayarlanmış TOROW işlevine eşdeğerdir:

=TOROW(A3:C5, ,TRUE)

Dinamik dizi TOROW işlevinin aksine, bu geleneksel formüllerin sonuçların görünmesini istediğiniz her hücreye girilmesi gerektiğini lütfen unutmayın. Bizim durumumuzda, ilk formül (satıra göre) E3'e gider ve M3 üzerinden kopyalanır. İkinci formül (sütuna göre) E8'e gelir ve M8 üzerinden sürüklenir.

Formüllerin doğru şekilde kopyalanması için aralığı mutlak referanslar kullanarak kilitliyoruz ($A$3:$C$5). Adlandırılmış bir aralık da iş görür.

Formülleri gereğinden fazla hücreye kopyaladıysanız, "fazladan" hücrelerde bir #REF! hatası görünecektir. Bunu düzeltmek için, formülünüzü IFERROR işlevine aşağıdaki gibi sarın:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

Bu formüller nasıl çalışır?

Aşağıda, değerleri satıra göre düzenleyen ilk formülün ayrıntılı bir dökümü yer almaktadır:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Formülün merkezinde, aralıktaki göreli konumuna göre bir hücrenin değerini almak için INDEX işlevini kullanırız.

Bu sıra numarası bu formül ile hesaplanır:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Buradaki fikir, 1,1,1,2,2,2,3,3,3, ... gibi tekrar eden bir sayı dizisi üretmektir; burada her sayı, kaynak aralığındaki sütun sayısı kadar tekrar eder. Bunu nasıl yapacağımız aşağıda açıklanmıştır:

QUOTIENT, bir bölümün tamsayı kısmını döndürür.

İçin pay formülünün girildiği ilk hücrede 0'dan başlayarak aşağıdakilere kadar bir seri numarası döndüren COLUMN(A1)-1 öğesini kullanırız n (aralıktaki toplam değer sayısı eksi 1) formülün girildiği son hücrede. Bu örnekte, E2'de 0 ve M3'te 8 değerimiz var.

İçin payda COLUMNS($A$3:$C$5)) kullanırız. Bu, aralığınızdaki sütun sayısına eşit sabit bir sayı döndürür (bizim durumumuzda 3).

Sonuç olarak, QUOTIENT işlevi ilk 3 hücrede (E3:G3) 0 döndürür, buna 1 ekleriz, böylece satır numarası 1 olur.

Sonraki 3 hücre için (H3:J3), QUOTIENT 1 döndürür ve +1 satır numarasını 2 verir.

Hesaplamak için sütun numarası MOD işlevini kullanarak uygun bir sayı dizisi oluşturursunuz:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Aralığımızda 3 sütun olduğundan, sıra şu şekilde görünmelidir: 1,2,3,1,2,3,...

MOD fonksiyonu bölme işleminden sonra kalanı döndürür.

E3'te, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+

olur

MOD(1-1, 3)+1)

ve 1 döndürür.

F3'te, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

olur

MOD(2-1, 3)+1)

ve 2 döndürür.

Satır ve sütun numaraları belirlendikten sonra, INDEX bu satır ve sütunun kesişimindeki değeri kolayca getirir.

E3'te, INDEX($A$3:$C$5, 1, 1) başvurulan aralığın 1. satırından ve 1. sütunundan, yani A3 hücresinden bir değer döndürür.

F3'te, INDEX($A$3:$C$5, 1, 2) 1. satır ve 2. sütundan, yani B3 hücresinden bir değer döndürür.

Ve bunun gibi şeyler.

Aralığı sütuna göre tarayan ikinci formül de benzer şekilde çalışır. Aradaki fark, satır numarasını hesaplamak için MOD ve sütun numarasını bulmak için QUOTIENT kullanmamızdır.

TOROW işlevi çalışmıyor

TOROW işlevi bir hatayla sonuçlanırsa, büyük olasılıkla bu nedenlerden biri olabilir:

#İSİM? hata

Çoğu Excel işlevinde, #ADI? hatası, işlevin adının yanlış yazıldığının açık bir göstergesidir. TOROW ile, işlevin Excel'inizde bulunmadığı anlamına da gelebilir. Excel sürümünüz 365'ten farklıysa, bir TOROW alternatifi kullanmayı deneyin.

#NUM hatası

NUM hatası, döndürülen dizinin bir satıra sığmadığını gösterir. Bu durum genellikle daha küçük bir aralık yerine tüm sütunlara ve/veya satırlara başvurduğunuzda ortaya çıkar.

#SPILL hatası

Çoğu durumda, #SPILL hatası, formülü girdiğiniz satırda sonuçları dökmek için yeterince boş hücre olmadığını gösterir. Komşu hücreler görsel olarak boşsa, içlerinde boşluk veya yazdırılmayan başka karakterler olmadığından emin olun. Daha fazla bilgi için Excel'de #SPILL hatasının anlamı bölümüne bakın.

Excel'de 2 boyutlu bir diziyi veya aralığı tek bir satıra dönüştürmek için TOROW işlevini bu şekilde kullanırsınız. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmek dileğiyle!

İndirmek için pratik çalışma kitabı

Excel TOROW işlevi - formül örnekleri (.xlsx dosyası)