TOROW फंक्शनच्या मदतीने सेलची श्रेणी एका पंक्तीमध्ये बदलण्याचा एक द्रुत मार्ग.

Microsoft Excel 365 ने अनेक नवीन कार्ये सादर केली आहेत. अॅरेसह विविध हाताळणी करण्यासाठी. TOROW सह, तुम्ही काही वेळात रेंज-टू-रो ट्रान्सफॉर्मेशन करू शकता. हे नवीन फंक्शन पूर्ण करू शकणार्‍या कार्यांची यादी येथे आहे:

Excel TOROW फंक्शन

Excel मधील TOROW फंक्शन अॅरे किंवा सेलच्या श्रेणीमध्ये रूपांतरित करण्यासाठी वापरले जाते एक पंक्ती.

फंक्शन एकूण तीन वितर्क घेते, ज्यापैकी फक्त पहिला एक आवश्यक आहे.

TOROW(अॅरे, [ दुर्लक्ष], [scan_by_column])

कुठे:

अॅरे (आवश्यक) - एका पंक्तीमध्ये रूपांतरित करण्यासाठी अॅरे किंवा श्रेणी.

दुर्लक्ष करा (पर्यायी) - रिक्त स्थानांकडे दुर्लक्ष करायचे की नाही हे ठरवते किंवा/आणि चुका यापैकी एक मूल्य घेऊ शकता:

• 0 किंवा वगळलेले (डीफॉल्ट) - सर्व मूल्ये ठेवा
• 1 - रिक्त स्थानांकडे दुर्लक्ष करा
• 2 - त्रुटींकडे दुर्लक्ष करा
• 3 - रिक्त जागा आणि त्रुटींकडे दुर्लक्ष करा

Scan_by_column (पर्यायी) - अॅरे कसे स्कॅन करायचे ते परिभाषित करते:

• असत्य किंवा वगळलेले (डीफॉल्ट) - पंक्तीनुसार अॅरे क्षैतिजरित्या स्कॅन करा.
• TRUE - स्तंभानुसार अॅरे अनुलंब स्कॅन करा.

टिपा:

• अॅरेचे रूपांतर करण्यासाठी एका कॉलममध्ये, TOCOL फंक्शन वापरा.
• रिव्हर्स रो-टू-अॅरे ट्रान्सफॉर्मेशन प्रीफॉर्म करण्यासाठी, कॉलममध्ये रॅप करण्यासाठी WRAPCOLS फंक्शन किंवा रॅप करण्यासाठी WRAPROWS फंक्शन वापरापंक्तींमध्ये अ‍ॅरे.
• पंक्ती स्तंभांमध्ये बदलण्यासाठी, TRANSPOSE फंक्शन वापरा.

TOROW उपलब्धता

TOROW हे नवीन फंक्शन आहे, जे फक्त Excel मध्ये समर्थित आहे Microsoft 365 (Windows आणि Mac साठी) आणि वेबसाठी Excel.

Excel मधील बेसिक TOROW फॉर्म्युला

साधे रेंज-टू-रो ट्रान्सफॉर्मेशन करण्यासाठी, TOROW फॉर्म्युला वापरा त्याच्या मूळ स्वरूपात. यासाठी, तुम्हाला फक्त पहिला युक्तिवाद ( अॅरे ) परिभाषित करावा लागेल.

उदाहरणार्थ, 3 स्तंभ आणि 3 पंक्ती असलेल्या द्विमितीय अ‍ॅरेला एका रांगेत बदलण्यासाठी, सूत्र आहे:

=TOROW(A3:C6)

तुम्ही सूत्र फक्त एका सेलमध्ये प्रविष्ट करा (आमच्या बाबतीत A10), आणि ते सर्व परिणाम ठेवण्यासाठी आवश्यक तितक्या सेलमध्ये आपोआप पसरते. एक्सेलच्या भाषेत, पातळ निळ्या बॉर्डरने वेढलेल्या आउटपुट रेंजला स्पिल रेंज म्हणतात.

हे सूत्र कसे कार्य करते:

प्रथम, सेलची पुरवलेली श्रेणी द्विमितीय अॅरेमध्ये रूपांतरित केली जाते. कृपया स्वल्पविरामाने सीमांकित स्तंभ आणि अर्धविरामाने विभक्त केलेल्या पंक्तीकडे लक्ष द्या:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

नंतर, TOROW फंक्शन डावीकडून उजवीकडे अॅरे वाचते आणि एका-आयामी क्षैतिज अॅरेमध्ये रूपांतरित करते:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

परिणाम सेल A10 वर जातो, जिथून तो उजवीकडील शेजारच्या सेलमध्ये पसरतो.

रिक्त आणि त्रुटींकडे दुर्लक्ष करून श्रेणीचे पंक्तीमध्ये रूपांतर करा

डीफॉल्टनुसार, TOROW फंक्शन रिकाम्या सेलसह स्त्रोत अॅरेमधील सर्व मूल्ये ठेवते आणिचुका आउटपुटमध्ये, रिकाम्या सेलच्या जागी शून्य मूल्ये दिसतात, जी खूप गोंधळात टाकणारी असू शकते.

रिक्त जागा वगळण्यासाठी , दुर्लक्ष करा वितर्क 1:<वर सेट करा. 3>

=TOROW(A3:C5, 1)

त्रुटी दुर्लक्षित करण्यासाठी , वगळण्यासाठी दुर्लक्ष करा वितर्क 2:

=TOROW(A3:C5, 2)

वर सेट करा दोन्ही, रिक्त आणि त्रुटी , दुर्लक्ष करा युक्तिवादासाठी 3 वापरा:

=TOROW(A3:C5, 3)

खालील प्रतिमा कृतीत सर्व तीन परिस्थिती दर्शवते: <18

अरे क्षैतिज किंवा अनुलंब वाचा

डीफॉल्ट वर्तनासह, TOROW फंक्शन अॅरेवर डावीकडून उजवीकडे क्षैतिजरित्या प्रक्रिया करते. स्तंभानुसार मूल्ये वरपासून खालपर्यंत स्कॅन करण्यासाठी, तुम्ही 3रा वितर्क ( scan_by_column ) TRUE किंवा 1 वर सेट करा.

उदाहरणार्थ, स्त्रोत श्रेणी पंक्तीनुसार वाचण्यासाठी, सूत्र E3 आहे:

=TOROW(A3:C5)

स्तंभानुसार श्रेणी स्कॅन करण्यासाठी, E8 मधील सूत्र आहे:

=TOROW(A3:C5, ,TRUE)

दोन्ही प्रकरणांमध्ये, परिणामी अॅरे आहेत समान आकार, परंतु मूल्ये वेगळ्या क्रमाने मांडली आहेत.

एकाहून अधिक रेंज एका ओळीत विलीन करा

एकाच पंक्तीमध्ये अनेक नॉन-लग्न रेंज एकत्र करण्यासाठी, तुम्ही प्रथम अनुक्रमे HSTACK किंवा VSTACCK च्या मदतीने एकाच अॅरेमध्ये क्षैतिज किंवा अनुलंब स्टॅक करा. , आणि नंतर एकत्रित अॅरेला एका ओळीत रूपांतरित करण्यासाठी TOROW फंक्शन वापरा.

तुमच्या व्यवसाय तर्कानुसार, खालीलपैकी एक सूत्र कार्य करेल.

अ‍ॅरे क्षैतिजरित्या स्टॅक करा आणि द्वारे रूपांतरित करा पंक्ती

पहिल्यासहA3:C4 मधील श्रेणी आणि A8:C9 मधील दुसरी श्रेणी, खालील सूत्र दोन श्रेणी क्षैतिजरित्या एकाच अॅरेमध्ये स्टॅक करेल, आणि नंतर डावीकडून उजवीकडे मूल्ये वाचून एका ओळीत रूपांतरित करेल. खालील प्रतिमेत परिणाम E3 मध्ये आहे.

=TOROW(HSTACK(A3:C4, A8:C9))

अ‍ॅरे क्षैतिजरित्या स्टॅक करा आणि स्तंभानुसार रूपांतरित करा

स्टॅक केलेला अॅरे वरपासून खालपर्यंत अनुलंब वाचण्यासाठी, तुम्ही खालील इमेजमध्ये E5 मध्ये दाखवल्याप्रमाणे TOROW चा तिसरा युक्तिवाद TRUE वर सेट केला आहे:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

अॅरे उभ्या स्टॅक करा आणि पंक्तीनुसार रुपांतरित करा

प्रत्येक जोडण्यासाठी मागील अॅरेच्या तळाशी पुढील अॅरे आणि एकत्रित अॅरे क्षैतिजरित्या वाचा, E12 मधील सूत्र आहे:

=TOROW(VSTACK(A3:C4, A8:C9))

अॅरे उभ्या स्टॅक करा आणि स्तंभानुसार रुपांतरित करा

मागील एकाच्या तळाशी प्रत्येक पुढील अॅरे जोडण्यासाठी आणि एकत्रित अॅरे अनुलंब स्कॅन करण्यासाठी, सूत्र आहे:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

तर्कशास्त्र अधिक चांगल्या प्रकारे समजून घेण्यासाठी, मधील मूल्यांचा भिन्न क्रम पहा परिणामी अॅरे:

श्रेणीमधून एका ओळीत अनन्य मूल्ये काढा

मायक्रोसॉफ्ट एक्सेल 2016 पासून सुरुवात करून, आमच्याकडे UNIQUE नावाचे एक अद्भुत कार्य आहे, जे एका स्तंभातून सहजपणे अद्वितीय मूल्ये मिळवू शकते. किंवा पंक्ती. तथापि, ते मल्टी-कॉलम अॅरे हाताळू शकत नाही. या मर्यादेवर मात करण्यासाठी, UNIQUE आणि TOROW फंक्शन्सचा एकत्र वापर करा.

उदाहरणार्थ, रेंज A2:C7 मधून सर्व भिन्न (भिन्न) मूल्ये काढण्यासाठी आणि परिणाम एका ओळीत ठेवण्यासाठी,सूत्र आहे:

=UNIQUE(TOROW(A2:C7), TRUE)

TOROW एक-आयामी क्षैतिज अ‍ॅरे देतो म्हणून, आम्ही प्रत्येकाशी स्तंभांची तुलना करण्यासाठी UNIQUE चा 2रा ( by_col ) वितर्क सेट करतो. इतर.

जर तुम्हाला निकाल वर्णक्रमानुसार लावायचे असतील तर, वरील सूत्र SORT फंक्शनमध्ये गुंडाळा:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

UNIQUE प्रमाणे, by_col SORT चा युक्तिवाद देखील TRUE वर सेट केला आहे.

Excel 365 - 2010 साठी TOROW पर्यायी

एक्सेल आवृत्त्यांमध्ये जेथे TOROW फंक्शन उपलब्ध नाही, तेथे कार्य करणार्‍या काही भिन्न फंक्शन्सच्या संयोजनाचा वापर करून तुम्ही श्रेणीचे एका पंक्तीमध्ये रूपांतर करू शकता. जुन्या आवृत्त्या. हे उपाय अधिक क्लिष्ट आहेत, परंतु ते कार्य करतात.

श्रेणी क्षैतिजरित्या स्कॅन करण्यासाठी, जेनेरिक सूत्र आहे:

INDEX( श्रेणी , QUOTIENT(COLUMN (A1)-1), COLUMNS( श्रेणी ))+1, MOD(COLUMN(A1)-1, COLUMNS( श्रेणी ))+1)

श्रेणी अनुलंब स्कॅन करण्यासाठी, जेनेरिक सूत्र आहे :

INDEX( श्रेणी , MOD(COLUMN(A1)-1, COLUMNS( श्रेणी ))+1, QuoTIENT(COLUMN (A1)-1, COLUMNS( श्रेणी ))+1)

A3:C5 मधील आमच्या नमुना डेटासेटसाठी, सूत्रे हा आकार घेतात:

पंक्तीनुसार श्रेणी स्कॅन करण्यासाठी:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

हे सूत्र TOROW फंक्शनसाठी पर्यायी आहे ज्यामध्ये 3रा वितर्क FALSE वर सेट केला आहे किंवा वगळला आहे:

=TOROW(A3:C5)

श्रेणी स्कॅन करण्यासाठी स्तंभ:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

हे सूत्र TOROW फंक्शनच्या समतुल्य आहे ज्यावर 3रा आर्ग्युमेंट सेट केला आहेTRUE:

=TOROW(A3:C5, ,TRUE)

कृपया लक्षात घ्या की डायनॅमिक अॅरे TOROW फंक्शनच्या विपरीत, ही पारंपारिक सूत्रे प्रत्येक सेलमध्ये प्रविष्ट केली पाहिजेत जिथे तुम्हाला परिणाम दिसायला हवे आहेत. आमच्या बाबतीत, पहिला सूत्र (पंक्तीनुसार) E3 वर जातो आणि M3 द्वारे कॉपी केला जातो. दुसरा फॉर्म्युला (स्तंभानुसार) E8 मध्ये येतो आणि M8 द्वारे ड्रॅग केला जातो.

फॉर्म्युले योग्यरित्या कॉपी करण्यासाठी, आम्ही परिपूर्ण संदर्भ ($A$3:$C$5) वापरून श्रेणी लॉक करतो. एक नामित श्रेणी देखील करेल.

जर तुम्ही आवश्यकतेपेक्षा जास्त सेलमध्ये सूत्रे कॉपी केली असतील, तर #REF! त्रुटी "अतिरिक्त" सेलमध्ये दिसून येईल. याचे निराकरण करण्यासाठी, तुमचा फॉर्म्युला IFERROR फंक्शनमध्ये याप्रमाणे गुंडाळा:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

हे सूत्र कसे कार्य करतात

खाली तपशीलवार ब्रेक-डाउन आहे पंक्तीनुसार मूल्यांची मांडणी करणार्‍या पहिल्या सूत्रातील:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

सूत्राच्या केंद्रस्थानी, सेलमधील त्याच्या सापेक्ष स्थितीवर आधारित मूल्य मिळविण्यासाठी आम्ही INDEX फंक्शन वापरतो. श्रेणी.

पंक्ती क्रमांक ची गणना या सूत्रानुसार केली जाते:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

1,1 सारखी पुनरावृत्ती होणारी संख्या क्रम तयार करण्याची कल्पना आहे ,1,2,2,2,3,3,3, … जिथे प्रत्येक संख्या स्त्रोत श्रेणीमध्ये स्तंभ आहेत तितक्या वेळा पुनरावृत्ती होते. आणि आपण हे कसे करतो ते येथे आहे:

QUOTIENT भागाचा पूर्णांक भाग परत करतो.

अंक साठी, आम्ही COLUMN(A1)-1 वापरतो, जो अनुक्रमांक मिळवतो. पहिल्या सेलमधील 0 मधील संख्या जिथे सूत्र n (श्रेणीमधील एकूण मूल्यांची संख्याउणे 1) शेवटच्या सेलमध्ये जेथे सूत्र प्रविष्ट केले आहे. या उदाहरणात, आमच्याकडे E2 मध्ये 0 आणि M3 मध्ये 8 आहे.

भाजक साठी, आम्ही COLUMNS($A$3:$C$5)) वापरतो. हे तुमच्या श्रेणीतील स्तंभांच्या संख्येइतकी स्थिर संख्या मिळवते (आमच्या बाबतीत ३).

परिणामी, QUOTIENT फंक्शन पहिल्या ३ सेलमध्ये (E3:G3) 0 मिळवते, ज्यावर आम्ही 1 जोडा, म्हणजे पंक्ती क्रमांक 1 आहे.

पुढील 3 सेलसाठी (H3:J3), QUOTIENT 1 देते आणि +1 पंक्ती क्रमांक 2 देते. आणि असेच.

स्तंभ क्रमांक ची गणना करण्यासाठी, तुम्ही MOD फंक्शन वापरून योग्य क्रमांकाचा क्रम तयार करा:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

आमच्या श्रेणीमध्ये 3 स्तंभ असल्यामुळे, क्रम असा दिसला पाहिजे : 1,2,3,1,2,3,…

MOD फंक्शन भागाकारानंतर उर्वरित परत करते.

E3 मध्ये, MOD(COLUMN(A1)-1, COLUMNS($ A$3:$C$5))+

बनते

MOD(1-1, 3)+1)

आणि 1 परत करते.

मध्ये F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

बनते

MOD(2-1, 3)+1)

आणि 2 परत करतो.

एकदा पंक्ती आणि स्तंभ क्रमांक स्थापित झाल्यावर, INDEX त्या पंक्ती आणि स्तंभाच्या छेदनबिंदूवर सहजपणे मूल्य मिळवते.

E3 मध्ये, INDEX($A$3 :$C$5, 1, 1) 1ली पंक्ती आणि 1ल्या स्तंभातून मूल्य मिळवते संदर्भित श्रेणीचे, उदा. सेल A3 वरून.

F3 मध्ये, INDEX($A$3:$C$5, 1, 2) 1ली पंक्ती आणि 2रा स्तंभ, म्हणजे सेल B3 मधून मूल्य मिळवते.

आणि पुढे.

स्तंभानुसार श्रेणी स्कॅन करणारे दुसरे सूत्रतत्सम मार्ग. फरक हा आहे की आम्ही पंक्ती क्रमांक मोजण्यासाठी MOD वापरतो आणि स्तंभ क्रमांक काढण्यासाठी QUOTIENT.

TOROW फंक्शन काम करत नाही

टोरो फंक्शनमध्ये त्रुटी आढळल्यास, ते यापैकी एक कारण असण्याची शक्यता आहे:

#NAME? त्रुटी

बहुतांश एक्सेल फंक्शन्ससह, #NAME? त्रुटी हे स्पष्ट संकेत आहे की फंक्शनचे नाव चुकीचे आहे. TOROW सह, याचा अर्थ असाही होऊ शकतो की हे कार्य तुमच्या Excel मध्ये उपलब्ध नाही. तुमची एक्सेल आवृत्ती 365 पेक्षा वेगळी असल्यास, TOROW पर्यायी वापरून पहा.

#NUM त्रुटी

#NUM त्रुटी दर्शवते की परत केलेला अॅरे एका ओळीत बसू शकत नाही. बहुतेकदा असे घडते जेव्हा तुम्ही लहान श्रेणीऐवजी संपूर्ण स्तंभ आणि/किंवा पंक्ती संदर्भित करता.

#SPILL त्रुटी

बहुतेक प्रकरणांमध्ये, #SPILL त्रुटी सूचित करते की पंक्ती जेथे तुम्ही फॉर्म्युला प्रविष्ट केला आहे ज्यामध्ये परिणाम पसरवण्यासाठी पुरेसे रिक्त सेल नाहीत. शेजारील सेल दृष्यदृष्ट्या रिकामे असल्यास, त्यामध्ये कोणतीही मोकळी जागा किंवा इतर नॉन-प्रिंटिंग वर्ण नाहीत याची खात्री करा. अधिक माहितीसाठी, Excel मध्ये #SPILL त्रुटी म्हणजे काय ते पहा.

अशा प्रकारे तुम्ही द्विमितीय अ‍ॅरे किंवा श्रेणी एका पंक्तीमध्ये रूपांतरित करण्यासाठी Excel मध्ये TOROW फंक्शन वापरता. वाचल्याबद्दल मी तुमचे आभारी आहे आणि पुढच्या आठवड्यात तुम्हाला आमच्या ब्लॉगवर भेटण्याची आशा आहे!

डाउनलोडसाठी सराव वर्कबुक

एक्सेल TOROW फंक्शन - सूत्र उदाहरणे (.xlsx फाइल)