Kiire viis muuta rakkude vahemik üheks reaks, kasutades selleks funktsiooni TOROW funktsioon.

Microsoft Excel 365 on kasutusele võtnud mitu uut funktsiooni, et teha erinevaid manipulatsioone massiividega. TOROW abil saate teha vahemiku rea ümberkujundamist hetkega. Siin on loetelu ülesannetest, mida see uus funktsioon suudab täita:

Exceli TOROW funktsioon

Exceli funktsiooni TOROW kasutatakse massiivi või rakkude vahemiku muutmiseks üheks reaks.

Funktsioon võtab kokku kolm argumenti, millest ainult esimene on vajalik.

Kus:

Array (nõutav) - massiivi või vahemik, mis teisendatakse üheks reaks.

Ignoreeri (valikuline) - määrab, kas ignoreerida tühikuid ja/või vigu. Võib võtta ühe järgmistest väärtustest:

• 0 või jäetakse välja (vaikimisi) - kõik väärtused jäävad alles.
• 1 - ignoreeri tühikuid
• 2 - ignoreeri vigu
• 3 - ignoreeri tühikuid ja vigu

Scan_by_column (valikuline) - määrab, kuidas massiivi skaneerida:

• FALSE või jäetakse välja (vaikimisi) - skaneerib massiivi horisontaalselt rea kaupa.
• TRUE - skaneerib massiivi vertikaalselt veergude kaupa.

Näpunäited:

• Massiivi muutmiseks üheks veeruks kasutage funktsiooni TOCOL.
• Tagurpidi rea-massiivi ümberkujundamiseks kasutage kas funktsiooni WRAPCOLS veerudeks pakkimiseks või funktsiooni WRAPROWS massiivi ridadeks pakkimiseks.
• Ridade muutmiseks veergudeks kasutage funktsiooni TRANSPOSE.

TOROW kättesaadavus

TOROW on uus funktsioon, mida toetavad ainult Excel for Microsoft 365 (Windows ja Mac) ja Excel for the web.

Põhiline TOROW valem Excelis

Lihtsa vahemiku reaks muutmise tegemiseks kasutage valemit TOROW selle põhivormis. Selleks peate määratlema ainult esimese argumendi ( massiivi ).

Näiteks selleks, et muuta kolmest veerust ja kolmest reast koosnevat kahemõõtmelist massiivi üheks reaks, on valem järgmine:

=TOROW(A3:C6)

Sa sisestad valemi vaid ühte lahtrisse (meie puhul A10) ja see valgub automaatselt nii paljudesse lahtritesse, kui on vaja kõigi tulemuste hoidmiseks. Exceli mõistes nimetatakse väljundvahemikku, mis on ümbritsetud õhukese sinise raamiga, valgumisvahemikuks.

Kuidas see valem töötab:

Esmalt muudetakse esitatud lahtrite vahemik kahemõõtmeliseks massiiviks. Pange tähele komadega eraldatud veerge ja semikooloniga eraldatud ridu:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

Seejärel loeb funktsioon TOROW massiivi vasakult paremale ja teisendab selle ühemõõtmeliseks horisontaalseks massiiviks:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

Tulemus läheb lahtrisse A10, kust see valgub paremal asuvasse naaberlahtrisse.

Muuda vahemik reaks, ignoreerides tühikuid ja vigu

Vaikimisi säilitab funktsioon TOROW kõik väärtused lähtemassiivist, sealhulgas tühjad lahtrid ja vead. Väljundis ilmuvad tühjade lahtrite asemel nullväärtused, mis võib olla üsna segadusttekitav.

aadressile jätta välja tühjad kohad , seada ignoreeri argument 1:

=TOROW(A3:C5, 1)

aadressile ignoreerida vigu , seada ignoreeri argument 2:

=TOROW(A3:C5, 2)

Mõlemad vahele jätta, tühikud ja vead , kasutage 3 jaoks ignoreeri argument:

=TOROW(A3:C5, 3)

Allpool olev pilt näitab kõiki kolme stsenaariumi toimimist:

Loe massiivi horisontaalselt või vertikaalselt

Vaikimisi käitumise korral töötleb funktsioon TOROW massiivi horisontaalselt vasakult paremale. Et skaneerida väärtusi veergude kaupa ülevalt alla, seadistate 3. argumendi ( scan_by_column ) väärtuseks TRUE või 1.

Näiteks, et lugeda allikas vahemik rea kaupa, on valem E3:

=TOROW(A3:C5)

Vahemiku skaneerimiseks veeru kaupa on valem E8:

=TOROW(A3:C5, ,TRUE)

Mõlemal juhul on saadud massiivid sama suured, kuid väärtused on paigutatud erinevas järjekorras.

Mitme vahemiku ühendamine üheks reaks

Mitme mittekohalduva vahemiku ühendamiseks üheks reaks tuleb need kõigepealt vastavalt HSTACK või VSTACK abil horisontaalselt või vertikaalselt üheks massiiviks virnastada ja seejärel kasutada funktsiooni TOROW, et muuta kombineeritud massiivi reaks.

Sõltuvalt teie äriloogikast täidab ülesande üks järgmistest valemitest.

Massiivide horisontaalne virnastamine ja teisendamine rea kaupa

Kui esimene vahemik on A3:C4 ja teine vahemik on A8:C9, siis alljärgnev valem paneb need kaks vahemikku horisontaalselt ühte massiivi ja muudab selle seejärel reaks, kus väärtused loetakse vasakult paremale. Tulemus on alljärgneval pildil E3.

=TOROW(HSTACK(A3:C4, A8:C9))

Mahtude virnastamine horisontaalselt ja teisendamine veergude kaupa

Et lugeda virnastatud massiivi vertikaalselt ülevalt alla, seate TOROW 3. argumendi väärtuseks TRUE, nagu on näidatud E5 alloleval pildil:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

Massiivide vertikaalne virnastamine ja konverteerimine rea kaupa

Iga järgneva massiivi lisamiseks eelmise massiivi põhja ja kombineeritud massiivi lugemiseks horisontaalselt on valem E12:

=TOROW(VSTACK(A3:C4, A8:C9))

Stack massiivid vertikaalselt ja teisendada veergude kaupa

Iga järgneva massiivi lisamiseks eelmise massiivi põhja ja kombineeritud massiivi vertikaalseks skaneerimiseks on valem järgmine:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

Loogika paremaks mõistmiseks vaadake väärtuste erinevat järjestust saadud massiividel:

Väljavõte unikaalsed väärtused vahemikust reale

Alates Microsoft Excel 2016-st on meil suurepärane funktsioon nimega UNIQUE, millega saab hõlpsasti saada unikaalseid väärtusi ühest veerust või reast. See ei saa aga hakkama mitme veeru massiividega. Selle piirangu ületamiseks kasutage funktsioone UNIQUE ja TOROW koos.

Näiteks, et eraldada kõik erinevad (erinevad) väärtused vahemikust A2:C7 ja paigutada tulemused ühte rea, on valem järgmine:

=UNIQUE(TOROW(A2:C7), TRUE)

Kuna TOROW tagastab ühemõõtmelise horisontaalse massiivi, seame 2. ( by_col ) argumendi UNIQUE väärtuseks TRUE, et võrrelda veerge omavahel.

Kui soovite, et tulemused oleksid järjestatud tähestikulises järjekorras, mähkige ülaltoodud valem funktsiooniga SORT:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

Nagu UNIQUE puhul, on ka by_col argument SORT on samuti määratud TRUE.

TOROW alternatiiv Exceli 365 jaoks - 2010

Exceli versioonides, kus TOROW-funktsioon ei ole saadaval, saab vahemiku muuta üheks reaks, kasutades mõne erineva funktsiooni kombinatsiooni, mis töötab vanemates versioonides. Need lahendused on keerulisemad, kuid nad töötavad.

Horisontaalse vahemiku skaneerimiseks on üldine valem järgmine:

Vertikaalse vahemiku skaneerimiseks on üldine valem järgmine:

Meie näidisandmestiku A3:C5 puhul on valemid järgmised:

Vahemiku skaneerimine rea kaupa:

=INDEX($A$3:$C$5, QUOTIENT(VEERG(A1)-1, VEERUD($A$3:$C$5))+1, MOD(VEERG(A1)-1, VEERUD($A$3:$C$5))+1)

See valem on alternatiiv funktsioonile TOROW, mille kolmas argument on FALSE või jäetakse välja:

=TOROW(A3:C5)

Vahemiku skaneerimine veergude kaupa:

=INDEX($A$3:$C$5, MOD(VEERG(A1)-1, VEERUD($A$3:$C$5))+1, QUOTIENT(VEERG(A1)-1, VEERUD($A$3:$C$5))+1)

See valem on samaväärne funktsiooniga TOROW, mille kolmandaks argumendiks on seatud TRUE:

=TOROW(A3:C5, ,TRUE)

Pange tähele, et erinevalt dünaamilise massiivi TOROW funktsioonist tuleb need traditsioonilised valemid sisestada igasse lahtrisse, kus soovite tulemusi näha. Meie puhul läheb esimene valem (rea kaupa) E3 ja kopeeritakse läbi M3. Teine valem (veeru kaupa) maandub E8 ja lohistatakse läbi M8.

Et valemid kopeeriksid korrektselt, lukustame vahemiku, kasutades absoluutseid viiteid ($A$3:$C$5). Ka nimeline vahemik sobib.

Kui olete kopeerinud valemid rohkemasse lahtrisse kui vaja, ilmub "lisarakkudes" viga #REF! Selle parandamiseks mähkige oma valem IFERROR funktsiooniga järgmiselt:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(VEERG(A1)-1, VEERUD($A$3:$C$5))+1, MOD(VEERG(A1)-1, VEERUD($A$3:$C$5))+1), "")

Kuidas need valemid toimivad

Allpool on üksikasjalikult kirjeldatud esimene valem, mis järjestab väärtused ridade kaupa:

=INDEX($A$3:$C$5, QUOTIENT(VEERG(A1)-1, VEERUD($A$3:$C$5))+1, MOD(VEERG(A1)-1, VEERUD($A$3:$C$5))+1)

Valemi keskmes kasutame funktsiooni INDEX, et saada lahtri väärtus selle suhtelise positsiooni alusel vahemikus.

The rea number arvutatakse järgmise valemiga:

QUOTIENT(VEERG(A1)-1, VEERUD($A$3:$C$5))+1

Idee on toota korduv numbrite jada, näiteks 1,1,1,2,2,2,3,3,3, ..., kus iga number kordub nii mitu korda, kui palju on tulpasid lähtepiirkonnas. Ja nii me seda teeme:

QUOTIENT tagastab jagamise täisarvulise osa.

Sest lugeja , kasutame COLUMN(A1)-1, mis tagastab järjekorranumbri alates 0-st esimeses lahtris, kuhu valem on sisestatud, kuni n (vahemikus olevate väärtuste koguarv miinus 1) viimases lahtris, kuhu valem on sisestatud. Selles näites on meil E2-s 0 ja M3-s 8.

Sest nimetaja , kasutame COLUMNS($A$3:$C$5)). See tagastab konstantse arvu, mis on võrdne teie vahemiku veergude arvuga (meie puhul 3).

Selle tulemusena tagastab funktsioon QUOTIENT esimese 3 lahtri (E3:G3) puhul 0, millele lisame 1, nii et rea number on 1.

Järgmise 3 lahtri (H3:J3) puhul annab QUOTIENT 1 ja +1 annab rea numbri 2. Ja nii edasi.

Arvutada veeru number , koostate sobiva numbrite jada, kasutades MOD-funktsiooni:

MOD(VEERG(A1)-1, VEERUD($A$3:$C$5))+1

Kuna meie vahemikus on 3 veergu, peab järjestus välja nägema: 1,2,3,1,2,3,....

Funktsioon MOD tagastab pärast jagamist jäägi.

E3-s MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+

muutub

MOD(1-1, 3)+1)

ja tagastab 1.

F3-s MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

muutub

MOD(2-1, 3)+1)

ja tagastab 2.

Kui rea ja veeru numbrid on kindlaks määratud, saab INDEX hõlpsasti kätte selle rea ja veeru ristumiskohas oleva väärtuse.

E3-s INDEX($A$3:$C$5, 1, 1) tagastab väärtuse viidatud vahemiku esimesest reast ja esimesest veerust, st lahtrist A3.

INDEX($A$3:$C$5, 1, 2) tagastab väärtuse 1. reast ja 2. veerust, st lahtrist B3.

Ja nii edasi.

Teine valem, mis skaneerib vahemikku veergude kaupa, töötab sarnaselt. Erinevus seisneb selles, et me kasutame MODi rea numbri arvutamiseks ja QUOTIENTi veergude numbri leidmiseks.

TOROW funktsioon ei tööta

Kui TOROW-funktsioon annab vea, on see tõenäoliselt üks neist põhjustest:

#NAME? error

Enamiku Exceli funktsioonide puhul on #NAME? viga selge märk sellest, et funktsiooni nimi on valesti kirjutatud. TOROW puhul võib see tähendada ka seda, et funktsioon ei ole teie Excelis saadaval. Kui teie Exceli versioon on muu kui 365, proovige kasutada TOROWi alternatiivi.

#NUM viga

Viga #NUM näitab, et tagastatav massiiv ei mahu reale. Enamasti juhtub see siis, kui viitate väiksema vahemiku asemel tervetele veergudele ja/või ridadele.

#SPILL viga

Enamikul juhtudel viitab #SPILL-viga sellele, et real, kuhu olete valemi sisestanud, ei ole piisavalt tühje lahtreid, kuhu tulemusi üle valada. Kui naaberrakud on visuaalselt tühjad, veenduge, et neis ei ole tühikuid ega muid mittetähtsaid märke. Lisateavet leiate jaotisest Mida tähendab #SPILL-viga Excelis.

Nii kasutate Excelis funktsiooni TOROW, et teisendada 2-mõõtmeline massiivi või vahemik üheks reaks. Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!

Praktiline töövihik allalaadimiseks

Exceli TOROW funktsioon - valemite näited (.xlsx fail)