TOROW فنکشن کی مدد سے سیلز کی رینج کو ایک قطار میں تبدیل کرنے کا ایک تیز طریقہ۔

Microsoft Excel 365 نے کئی نئے فنکشنز متعارف کرائے ہیں۔ صفوں کے ساتھ مختلف ہیرا پھیری کرنے کے لیے۔ TOROW کے ساتھ، آپ بغیر کسی وقت کے رینج سے قطار کی تبدیلیاں انجام دے سکتے ہیں۔ یہاں ان کاموں کی فہرست ہے جو یہ نیا فنکشن انجام دے سکتا ہے:

Excel TOROW فنکشن

ایکسل میں TOROW فنکشن کا استعمال سیلز کی ایک صف یا رینج میں تبدیل کرنے کے لیے کیا جاتا ہے۔ ایک قطار۔

فنکشن کل تین آرگومینٹس لیتا ہے، جن میں سے صرف پہلی کی ضرورت ہے۔

TOROW(array, [ignore], [scan_by_column])

کہاں:

Array (ضروری) - ایک صف یا رینج جس کو ایک قطار میں تبدیل کرنا ہے۔

نظر انداز کریں (اختیاری) - یہ طے کرتا ہے کہ آیا خالی جگہوں کو نظر انداز کرنا ہے یا/اور غلطیاں ان میں سے ایک قدر لے سکتے ہیں:

• 0 یا چھوڑ دیا گیا (پہلے سے طے شدہ) - تمام اقدار کو رکھیں
• 1 - خالی جگہوں کو نظر انداز کریں
• 2 - غلطیوں کو نظر انداز کریں
• 3 - خالی جگہوں اور غلطیوں کو نظر انداز کریں

Scan_by_column (اختیاری) - وضاحت کرتا ہے کہ سرنی کو کیسے اسکین کیا جائے:

• غلط یا چھوڑ دیا گیا (پہلے سے طے شدہ) - قطار کو افقی طور پر اسکین کریں ایک کالم میں، TOCOL فنکشن کا استعمال کریں۔
• روورس قطار سے صف کی تبدیلی کو پہلے سے ترتیب دینے کے لیے، کالموں میں لپیٹنے کے لیے WRAPCOLS فنکشن یا لپیٹنے کے لیے WRAPROWS فنکشن کا استعمال کریں۔قطاروں میں صف بنائیں۔
• قطاروں کو کالموں میں تبدیل کرنے کے لیے، TRANSPOSE فنکشن استعمال کریں۔

TOROW availability

TOROW ایک نیا فنکشن ہے، جو صرف Excel میں سپورٹ کرتا ہے۔ مائیکروسافٹ 365 (ونڈوز اور میک کے لیے) اور ویب کے لیے ایکسل۔

ایکسل میں بنیادی TOROW فارمولہ

ایک سادہ رینج سے قطار میں تبدیلی کرنے کے لیے، TOROW فارمولہ استعمال کریں۔ اس کی بنیادی شکل میں. اس کے لیے، آپ کو صرف پہلی دلیل ( array ) کی وضاحت کرنی ہوگی۔

مثال کے طور پر، 3 کالموں اور 3 قطاروں پر مشتمل دو جہتی صف کو ایک قطار میں تبدیل کرنے کے لیے، فارمولا یہ ہے:

=TOROW(A3:C6)

آپ فارمولے کو صرف ایک سیل میں داخل کرتے ہیں (ہمارے معاملے میں A10)، اور یہ خود بخود تمام نتائج کو رکھنے کے لیے ضرورت کے مطابق زیادہ سے زیادہ سیل میں پھیل جاتا ہے۔ ایکسل کی شرائط میں، ایک پتلی نیلی سرحد سے گھری ہوئی آؤٹ پٹ رینج کو اسپل رینج کہا جاتا ہے۔

یہ فارمولہ کیسے کام کرتا ہے:

سب سے پہلے، خلیات کی فراہم کردہ رینج کو دو جہتی صف میں تبدیل کیا جاتا ہے۔ براہ کرم کوما سے الگ کردہ کالمز اور سیمکولن سے الگ کردہ قطاروں کو دیکھیں:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

پھر، TOROW فنکشن ارے کو بائیں سے دائیں پڑھتا ہے اور اسے ایک جہتی افقی صف میں تبدیل کرتا ہے:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

نتیجہ سیل A10 میں جاتا ہے، جہاں سے یہ دائیں جانب پڑوسی سیل میں پھیلتا ہے۔

خلا اور خامیوں کو نظر انداز کرتے ہوئے رینج کو قطار میں تبدیل کریں

پہلے سے طے شدہ طور پر، TOROW فنکشن سورس اری سے تمام اقدار کو رکھتا ہے، بشمول خالی سیل اورغلطیاں آؤٹ پٹ میں، خالی خلیات کی جگہ صفر کی قدریں ظاہر ہوتی ہیں، جو کافی مبہم ہوسکتی ہیں۔

خالی جگہوں کو خارج کرنے کے لیے، نظر انداز کریں دلیل کو 1:<پر سیٹ کریں۔ 3>

=TOROW(A3:C5, 1)

غلطیوں کو نظر انداز کرنے کے لیے ، نظر انداز کریں دلیل کو 2 پر سیٹ کریں:

=TOROW(A3:C5, 2)

چھوڑنے کے لیے دونوں، خالی جگہ اور غلطیاں ، نظر انداز کریں دلیل کے لیے 3 کا استعمال کریں:

=TOROW(A3:C5, 3)

نیچے دی گئی تصویر تینوں منظرناموں کو عملی شکل میں دکھاتی ہے: <18

سرنی کو افقی یا عمودی طور پر پڑھیں

پہلے سے طے شدہ رویے کے ساتھ، TOROW فنکشن ارے کو بائیں سے دائیں افقی طور پر پروسیس کرتا ہے۔ کالم کے لحاظ سے اوپر سے نیچے تک اقدار کو اسکین کرنے کے لیے، آپ تیسری دلیل ( scan_by_column ) کو TRUE یا 1 پر سیٹ کرتے ہیں۔

مثال کے طور پر، ماخذ کی حد کو قطار کے لحاظ سے پڑھنے کے لیے، فارمولا E3 ہے:

=TOROW(A3:C5)

کالم کے لحاظ سے رینج کو اسکین کرنے کے لیے، E8 میں فارمولہ ہے:

=TOROW(A3:C5, ,TRUE)

دونوں صورتوں میں، نتیجے میں آرے ہیں ایک ہی سائز، لیکن اقدار کو مختلف ترتیب میں ترتیب دیا گیا ہے۔

متعدد رینجز کو ایک قطار میں ضم کریں

متعدد غیر ملحقہ رینجز کو ایک قطار میں جوڑنے کے لیے، آپ بالترتیب HSTACK یا VSTACK کی مدد سے انہیں افقی یا عمودی طور پر ایک ہی صف میں اسٹیک کریں۔ ، اور پھر مشترکہ صف کو ایک قطار میں تبدیل کرنے کے لیے TOROW فنکشن کا استعمال کریں۔

آپ کی کاروباری منطق پر منحصر ہے، درج ذیل فارمولوں میں سے کوئی ایک یہ کام انجام دے گا۔

اروں کو افقی طور پر اسٹیک کریں اور اس کے ذریعے تبدیل کریں قطار

پہلے کے ساتھA3:C4 میں رینج اور A8:C9 میں دوسری رینج، نیچے والا فارمولا افقی طور پر دو رینجز کو ایک ہی صف میں کھڑا کر دے گا، اور پھر اسے بائیں سے دائیں قدروں کو پڑھنے والی قطار میں تبدیل کر دے گا۔ نتیجہ نیچے دی گئی تصویر میں E3 میں ہے۔

=TOROW(HSTACK(A3:C4, A8:C9))

اروں کو افقی طور پر اسٹیک کریں اور کالم کے لحاظ سے تبدیل کریں

اوپر سے نیچے تک عمودی طور پر اسٹیک شدہ صف کو پڑھنے کے لیے، آپ نے TOROW کی تیسری دلیل کو TRUE پر سیٹ کیا جیسا کہ ذیل کی تصویر میں E5 میں دکھایا گیا ہے:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

عمودی طور پر صفوں کو اسٹیک کریں اور قطار سے تبدیل کریں

ہر ایک کو شامل کرنے کے لیے بعد والی صف کو پچھلی صف کے نیچے تک لے جائیں اور مشترکہ صف کو افقی طور پر پڑھیں، E12 میں فارمولہ ہے:

=TOROW(VSTACK(A3:C4, A8:C9))

عمودی طور پر صفوں کو اسٹیک کریں اور کالم کے ذریعے تبدیل کریں

ہر بعد والی صف کو پچھلے ایک کے نچلے حصے میں شامل کرنے اور مشترکہ صف کو عمودی طور پر اسکین کرنے کے لیے، فارمولا یہ ہے:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

منطق کو بہتر طور پر سمجھنے کے لیے، قدروں کی مختلف ترتیب کا مشاہدہ کریں نتیجے میں آنے والی صفیں:

ایک رینج سے ایک قطار میں منفرد قدریں نکالیں

Microsoft Excel 2016 کے ساتھ شروع کرتے ہوئے، ہمارے پاس ایک شاندار فنکشن ہے، جس کا نام UNIQUE ہے، جو آسانی سے ایک کالم سے منفرد اقدار حاصل کرسکتا ہے۔ یا قطار. تاہم، یہ کثیر کالم صفوں کو نہیں سنبھال سکتا۔ اس حد کو دور کرنے کے لیے، UNIQUE اور TOROW فنکشنز کو ایک ساتھ استعمال کریں۔

مثال کے طور پر، رینج A2:C7 سے تمام مختلف (مختلف) قدروں کو نکالنے اور نتائج کو ایک قطار میں رکھنے کے لیے،فارمولا یہ ہے:

=UNIQUE(TOROW(A2:C7), TRUE)

جیسا کہ TOROW ایک جہتی افقی صف کو لوٹاتا ہے، ہم نے ہر کالم کا موازنہ کرنے کے لیے UNIQUE کی دوسری ( by_col ) دلیل کو TRUE پر سیٹ کیا۔ دیگر۔

اگر آپ چاہتے ہیں کہ نتائج کو حروف تہجی کی ترتیب میں ترتیب دیا جائے تو اوپر والے فارمولے کو SORT فنکشن میں لپیٹیں:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

UNIQUE کی طرح، by_col SORT کی دلیل بھی TRUE پر سیٹ ہے۔

ایکسل 365 - 2010 کے لیے TOROW متبادل

ایکسل ورژن میں جہاں TOROW فنکشن دستیاب نہیں ہے، آپ کچھ مختلف فنکشنز کے امتزاج کا استعمال کرکے ایک رینج کو ایک قطار میں تبدیل کرسکتے ہیں جو پرانے ورژن. یہ حل زیادہ پیچیدہ ہیں، لیکن یہ کام کرتے ہیں۔

رینج کو افقی طور پر اسکین کرنے کے لیے، عام فارمولہ ہے:

INDEX( range ، QuoTIENT(COLUMN (A1)-1، COLUMNS( range ))+1, MOD(COLUMN(A1)-1, COLUMNS( range ))+1)

رینج کو عمودی طور پر اسکین کرنے کے لیے، عام فارمولہ ہے :

INDEX( رینج ، MOD(COLUMN(A1)-1، COLUMNS( range ))+1، QUOTIENT(COLUMN (A1)-1، COLUMNS(<15)>range ))+1)

A3:C5 میں ہمارے نمونے کے ڈیٹاسیٹ کے لیے، فارمولے یہ شکل اختیار کرتے ہیں:

رینج کو قطار کے لحاظ سے اسکین کرنے کے لیے:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

یہ فارمولہ TOROW فنکشن کا متبادل ہے جس میں تیسری دلیل FALSE پر سیٹ کی گئی ہے یا چھوڑ دی گئی ہے:

=TOROW(A3:C5)

رینج کو اسکین کرنے کے لیے کالم:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

یہ فارمولہ TOROW فنکشن کے مساوی ہے جس میں تیسری دلیل سیٹ کی گئی ہےTRUE:

=TOROW(A3:C5, ,TRUE)

براہ کرم نوٹ کریں کہ ڈائنامک ارے TOROW فنکشن کے برعکس، یہ روایتی فارمولے ہر سیل میں داخل ہونے چاہئیں جہاں آپ چاہتے ہیں کہ نتائج ظاہر ہوں۔ ہمارے معاملے میں، پہلا فارمولا (قطار کے لحاظ سے) E3 پر جاتا ہے اور M3 کے ذریعے کاپی کیا جاتا ہے۔ دوسرا فارمولہ (کالم کے لحاظ سے) E8 میں آتا ہے اور اسے M8 کے ذریعے گھسیٹا جاتا ہے۔

فارمولوں کو صحیح طریقے سے کاپی کرنے کے لیے، ہم مطلق حوالہ جات ($A$3:$C$5) کا استعمال کرتے ہوئے رینج کو مقفل کرتے ہیں۔ ایک نامزد رینج بھی کرے گی۔

اگر آپ نے فارمولوں کو ضرورت سے زیادہ سیلز میں کاپی کیا ہے، تو #REF! غلطی "اضافی" خلیوں میں ظاہر ہوگی۔ اسے ٹھیک کرنے کے لیے، اپنے فارمولے کو IFERROR فنکشن میں اس طرح لپیٹیں:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

یہ فارمولے کیسے کام کرتے ہیں

ذیل میں ایک تفصیلی بریک ڈاؤن ہے۔ پہلے فارمولے کا جو قدروں کو قطار کے لحاظ سے ترتیب دیتا ہے:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

فارمولے کے مرکز میں، ہم سیل کی قدر حاصل کرنے کے لیے INDEX فنکشن کا استعمال کرتے ہیں رینج۔

قطار نمبر کا حساب اس فارمولے سے کیا جاتا ہے:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

خیال یہ ہے کہ دہرائے جانے والے نمبر کی ترتیب جیسے کہ 1,1 ,1,2,2,2,3,3,3, … جہاں ہر نمبر جتنی بار ماخذ کی حد میں کالم ہوتے ہیں دہرایا جاتا ہے۔ اور یہ ہے کہ ہم یہ کیسے کرتے ہیں:

QUOTIENT ایک تقسیم کا عددی حصہ لوٹاتا ہے۔

عدد کے لیے، ہم COLUMN(A1)-1 استعمال کرتے ہیں، جو ایک سیریل لوٹاتا ہے۔ پہلے سیل میں 0 سے نمبر جہاں فارمولہ n میں درج کیا جاتا ہے (رینج میں اقدار کی کل تعدادمائنس 1) آخری سیل میں جہاں فارمولہ درج ہوا ہے۔ اس مثال میں، ہمارے پاس E2 میں 0 اور M3 میں 8 ہے۔

Denominator کے لیے، ہم COLUMNS($A$3:$C$5)) استعمال کرتے ہیں۔ یہ آپ کی رینج میں کالموں کی تعداد کے برابر ایک مستقل نمبر لوٹاتا ہے (ہمارے معاملے میں 3)۔

نتیجتاً، QUOTIENT فنکشن پہلے 3 سیلز (E3:G3) میں 0 لوٹاتا ہے، جس پر ہم 1 شامل کریں، تو قطار نمبر 1 ہے۔

اگلے 3 سیلز (H3:J3) کے لیے، QUOTIENT 1 لوٹاتا ہے، اور +1 قطار نمبر 2 دیتا ہے۔ اور اسی طرح۔

کالم نمبر کا حساب لگانے کے لیے، آپ MOD فنکشن کا استعمال کرتے ہوئے ایک مناسب نمبر ترتیب بناتے ہیں:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

چونکہ ہماری رینج میں 3 کالم ہیں، اس لیے ترتیب کو ایسا نظر آنا چاہیے : 1,2,3,1,2,3,…

MOD فنکشن تقسیم کے بعد بقیہ کو لوٹاتا ہے۔

E3 میں، MOD(COLUMN(A1)-1، COLUMNS($ A$3:$C$5))+

بن جاتا ہے

MOD(1-1, 3)+1)

اور 1 لوٹتا ہے۔

میں F3، MOD(COLUMN(B1)-1، COLUMNS($A$3:$C$5))+

بن جاتا ہے

MOD(2-1, 3)+1)

اور 2 لوٹاتا ہے :$C$5, 1, 1) پہلی قطار اور پہلے کالم سے ایک قدر لوٹاتا ہے حوالہ شدہ رینج کا، یعنی سیل A3 سے۔

F3 میں، INDEX($A$3:$C$5, 1, 2) پہلی قطار اور دوسرے کالم سے ایک قدر لوٹاتا ہے، یعنی سیل B3 سے۔

اور اسی طرح آگے۔

دوسرا فارمولا جو کالم کے لحاظ سے رینج کو اسکین کرتا ہے، ایک میں کام کرتا ہے۔اسی طرح. فرق یہ ہے کہ ہم قطار نمبر کا حساب لگانے کے لیے MOD کا استعمال کرتے ہیں اور کالم نمبر کا پتہ لگانے کے لیے QUOTIENT۔

TOROW فنکشن کام نہیں کر رہا ہے

اگر TOROW فنکشن کے نتیجے میں غلطی ہوتی ہے، تو یہ ہے ان وجوہات میں سے ایک ہونے کا امکان ہے:

#NAME؟ خرابی

زیادہ تر ایکسل فنکشنز کے ساتھ، ایک #NAME؟ غلطی ایک واضح اشارہ ہے کہ فنکشن کا نام غلط لکھا گیا ہے۔ TOROW کے ساتھ، اس کا مطلب یہ بھی ہو سکتا ہے کہ فنکشن آپ کے ایکسل میں دستیاب نہیں ہے۔ اگر آپ کا ایکسل ورژن 365 کے علاوہ ہے، تو TOROW متبادل استعمال کرنے کی کوشش کریں۔

#NUM ایرر

#NUM ایرر اس بات کی نشاندہی کرتا ہے کہ لوٹی ہوئی صف ایک قطار میں فٹ نہیں ہوسکتی ہے۔ اکثر ایسا اس وقت ہوتا ہے جب آپ چھوٹی رینج کے بجائے پورے کالم اور/یا قطاروں کا حوالہ دیتے ہیں۔

#SPILL ایرر

زیادہ تر معاملات میں، ایک #SPILL غلطی بتاتی ہے کہ قطار جہاں آپ نے جو فارمولہ درج کیا ہے اس میں نتائج کو پھیلانے کے لیے کافی خالی سیل نہیں ہیں۔ اگر ہمسایہ خلیات بصری طور پر خالی ہیں، تو یقینی بنائیں کہ ان میں کوئی خالی جگہ یا دیگر غیر پرنٹنگ حروف موجود نہیں ہیں۔ مزید معلومات کے لیے، دیکھیں کہ ایکسل میں #SPILL کی خرابی کا کیا مطلب ہے۔

اس طرح آپ ایکسل میں TOROW فنکشن کو 2-جہتی صف یا رینج کو ایک قطار میں تبدیل کرنے کے لیے استعمال کرتے ہیں۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور امید کرتا ہوں کہ آپ کو اگلے ہفتے ہمارے بلاگ پر ملوں گا!

ڈاؤن لوڈ کے لیے پریکٹس ورک بک

Excel TOROW فنکشن - فارمولے کی مثالیں (.xlsx فائل)