TOROW функцын тусламжтайгаар олон нүдийг нэг эгнээ болгон хувиргах хурдан арга.

Microsoft Excel 365 нь хэд хэдэн шинэ функцийг нэвтрүүлсэн. массиваар янз бүрийн манипуляци хийх. TOROW-ийн тусламжтайгаар та богино хугацаанд мөр хоорондын өөрчлөлтийг хийх боломжтой. Энэ шинэ функцийн гүйцэтгэж чадах ажлуудын жагсаалт энд байна:

Excel-ийн TOROW функц

Excel-ийн TOROW функц нь массив эсвэл нүдний мужийг хөрвүүлэхэд ашиглагддаг. нэг мөр.

Функц нь нийт гурван аргумент авдаг бөгөөд үүнээс зөвхөн эхнийх нь л шаардлагатай.

TOROW(массив, [үл тоох], [баганаар_скан хийх])

Энд:

Масив (шаардлагатай) - нэг мөр болгон хувиргах массив эсвэл муж.

Үл тоох (заавал биш) - хоосон орон зайг үл тоомсорлох эсэхийг тодорхойлно. алдаа. Эдгээр утгуудын аль нэгийг авч болно:

• 0 эсвэл орхигдсон (өгөгдмөл) - бүх утгыг хадгалах
• 1 - хоосон зайг үл тоомсорлох
• 2 - алдааг үл тоомсорлох
• 3 - хоосон зай, алдааг үл тоомсорлох

баганаар_скан хийх (заавал биш) - массивыг хэрхэн скан хийхийг тодорхойлно:

• ХУДАЛ эсвэл орхигдсон (өгөгдмөл) - массивыг хэвтээ байдлаар мөрөөр скан хийх.
• ҮНЭН - массивыг босоогоор баганагаар скан хийх.

Зөвлөмж:

• Масивыг хувиргах Нэг баганад TOCOL функцийг ашиглана уу.
• Урвуу мөрийг массив болгон хувиргахын тулд WRAPCOLS функцийг ашиглан багана руу оруулах эсвэл WRAPROWS функцийг ашиглана уу.массивыг мөр болгон хувиргана.
• Мөрүүдийг багана болгохын тулд TRANSPOSE функцийг ашиглана уу.

TOROW ашиглах боломжтой

TOROW нь зөвхөн Excel-д дэмжигдэх шинэ функц юм. Microsoft 365 (Windows болон Mac-д зориулсан) болон вэбэд зориулсан Excel-д зориулагдсан.

Excel-ийн үндсэн TOROW томьёо

Энгийн мужаас мөр рүү шилжүүлэхийн тулд TOROW томьёог ашиглана уу. үндсэн хэлбэрээрээ. Үүний тулд та зөвхөн эхний аргументыг ( массив ) тодорхойлох хэрэгтэй.

Жишээлбэл, 3 багана, 3 мөрөөс бүрдэх хоёр хэмжээст массивыг нэг мөр болгохын тулд томьёо нь:

=TOROW(A3:C6)

Та томьёог зөвхөн нэг нүдэнд (манай тохиолдолд A10) оруулах ба бүх үр дүнг хадгалахын тулд шаардлагатай тооны нүд рүү автоматаар асгардаг. Excel-ийн нэр томьёогоор нимгэн цэнхэр хүрээгээр хүрээлэгдсэн гаралтын мужийг асгаралтын муж гэж нэрлэдэг.

Энэ томъёо хэрхэн ажилладаг вэ:

Эхлээд нийлүүлсэн нүднүүдийг хоёр хэмжээст массив болгон хувиргадаг. Таслалаар тусгаарлагдсан баганууд болон цэг таслалаар тусгаарлагдсан мөрүүдийг анхаарна уу:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

Дараа нь TOROW функц нь массивыг зүүнээс баруун тийш уншиж, нэг хэмжээст хэвтээ массив болгон хувиргана:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

Үр дүн нь A10 нүд рүү очих бөгөөд энэ нь баруун талын зэргэлдээх нүд рүү асгарна.

Хоосон зай, алдааг үл тоомсорлон муж болгон хувиргах

Анхдагчаар TOROW функц нь эх массиваас хоосон нүднүүд болон бүх утгыг хадгалдагалдаа. Гаралт дээр хоосон нүднүүдийн оронд тэг утгууд гарч ирэх бөгөөд энэ нь нэлээд төөрөгдүүлж магадгүй юм.

хоосон зайг хасах бол үл тоох аргументыг 1 болгож тохируулна уу:

=TOROW(A3:C5, 1)

алдааг үл тоомсорлох бол үл тоохгүй аргументыг 2 болгож тохируулна уу:

=TOROW(A3:C5, 2)

Алгасахын тулд аль аль нь хоосон болон алдаа , үл тоомсорлох аргументийн хувьд 3-ыг ашиглана уу:

=TOROW(A3:C5, 3)

Доорх зураг нь бүх гурван хувилбарыг ажиллаж байгаа харуулж байна:

Масивыг хэвтээ эсвэл босоо байдлаар унших

Өгөгдмөл горимоор TOROW функц нь массивыг зүүнээс баруун тийш хэвтээ байдлаар боловсруулдаг. Утгыг дээрээс доош баганаар скан хийхийн тулд та 3-р аргументыг ( баганаар_скан ) ҮНЭН эсвэл 1 болгож тохируулна уу.

Жишээлбэл, эх сурвалжийн мужийг мөрөөр унших бол томьёог E3 нь:

=TOROW(A3:C5)

Мужийг баганаар нь сканнердахын тулд E8 дахь томьёо нь:

=TOROW(A3:C5, ,TRUE)

Аль ч тохиолдолд үүссэн массивууд нь байна. ижил хэмжээтэй, гэхдээ утгуудыг өөр дарааллаар байрлуулсан.

Олон мужийг нэг мөрөнд нэгтгэх

Хэд хэдэн зэргэлдээх бус мужуудыг нэг мөрөнд нэгтгэхийн тулд та эхлээд тэдгээрийг HSTACK эсвэл VSTACK-ийн тусламжтайгаар нэг массив болгон хэвтээ эсвэл босоо байдлаар давхарлана. , дараа нь нэгтгэсэн массивыг эгнээ болгон хөрвүүлэхийн тулд TOROW функцийг ашиглана уу.

Таны бизнесийн логикоос хамааран дараах томъёонуудын аль нэг нь даалгаврыг гүйцэтгэнэ.

Масивыг хэвтээ байдлаар стек болгон хувиргана. эгнээ

ЭхнийхтэйA3:C4-ийн муж, A8:C9-ийн хоёр дахь муж бол доорх томьёо нь хоёр мужийг хэвтээ байдлаар нэг массив болгон овоолж, дараа нь зүүнээс баруун тийш утгуудыг унших эгнээ болгон хувиргана. Үр дүн нь доорх зурган дээрх E3 дээр байна.

=TOROW(HSTACK(A3:C4, A8:C9))

Масивыг хэвтээ байдлаар стек ба баганаар хөрвүүлнэ

Савласан массивыг дээрээс доош босоо байдлаар уншихын тулд, Та доорх зурган дээрх E5-д үзүүлсэн шиг TOROW-ийн 3-р аргументыг ҮНЭН болгож тохируулна уу:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

Масивуудыг босоо байдлаар байрлуулж, мөрөөр хөрвүүлнэ

Тус бүрийг нэмэхийн тулд дараагийн массивыг өмнөх массивын доод талд байрлуулж, нэгтгэсэн массивыг хэвтээ байдлаар уншвал E12 дахь томьёо нь:

=TOROW(VSTACK(A3:C4, A8:C9))

Масивыг босоо байдлаар стек болон баганаар хөрвүүлнэ

Дараагийн массив бүрийг өмнөх массивын доод талд нэмж, хосолсон массивыг босоогоор нь сканнердахын тулд дараах томъёог авна:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

Логикийг илүү сайн ойлгохын тулд утгын өөр дарааллыг ажигла. үүссэн массивууд:

Мужаас давтагдашгүй утгуудыг мөр болгон задлах

Microsoft Excel 2016 программаас эхлэн бид нэг баганаас өвөрмөц утгыг хялбархан авах боломжтой UNIQUE нэртэй гайхалтай функцтэй болсон. эсвэл эгнээ. Гэсэн хэдий ч, энэ нь олон баганын массивыг зохицуулах боломжгүй юм. Энэ хязгаарлалтыг даван туулахын тулд UNIQUE болон TOROW функцийг хамтад нь ашиглаарай.

Жишээ нь, A2:C7 мужаас бүх өөр (ялгаатай) утгуудыг гаргаж аваад үр дүнг нэг мөрөнд байрлуулахын тулдтомьёо нь:

=UNIQUE(TOROW(A2:C7), TRUE)

TOROW нь нэг хэмжээст хэвтээ массивыг буцаадаг тул бид баганыг тус бүртэй харьцуулахын тулд UNIQUE-ийн 2 дахь ( хэвтээ ) аргументыг ҮНЭН гэж тохируулсан. бусад.

Хэрэв та үр дүнг цагаан толгойн үсгийн дарааллаар байрлуулахыг хүсвэл дээрх томьёог SORT функцэд ороорой:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

UNIQUE-ийн адил by_col SORT-ын аргументыг мөн ҮНЭН гэж тохируулсан.

Excel 365 - 2010-д зориулсан TOROW хувилбар

TOROW функц байхгүй Excel-ийн хувилбаруудад та хэд хэдэн өөр функцийн хослолыг ашиглан мужийг нэг мөр болгон хувиргаж болно. хуучин хувилбарууд. Эдгээр шийдлүүд нь илүү төвөгтэй боловч ажилладаг.

Мужийг хэвтээ байдлаар сканнердахын тулд ерөнхий томъёо нь:

INDEX( муж , QUOTIENT(COLUMN (A1)-1, COLUMNS( муж ))+1, MOD(COLUMN(A1)-1, COLUMNS( муж ))+1)

Мужийг босоо байдлаар сканнердахын тулд ерөнхий томьёо нь: :

INDEX( муж , MOD(COLUMN(A1)-1, COLUMNS( муж ))+1, QUOTIENT(COLUMN (A1)-1, COLUMNS(<15)>муж ))+1)

Манай A3:C5 дээрх түүвэр өгөгдлийн багцын хувьд томьёо нь дараах хэлбэртэй байна:

Мужийг мөр мөрөөр скан хийхийн тулд:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Энэ томьёо нь 3-р аргументыг ХУДАЛ гэж тохируулсан эсвэл орхигдуулсан TOROW функцийн өөр хувилбар юм:

=TOROW(A3:C5)

Мужийг скан хийх: багана:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Энэ томьёо нь 3-р аргументыг тохируулсан TOROW функцтэй тэнцүү байна.ҮНЭН:

=TOROW(A3:C5, ,TRUE)

Динамик массив TOROW функцээс ялгаатай нь эдгээр уламжлалт томъёог үр дүнг харуулахыг хүссэн нүд бүрт оруулах ёстойг анхаарна уу. Манай тохиолдолд эхний томьёо (мөрөөр) E3 руу орж, M3-ээр хуулж авдаг. Хоёрдахь томьёо (баганаар) E8-д бууж, M8-д чирсэн байна.

Томьёог зөв хуулахын тулд бид үнэмлэхүй лавлагаа ($A$3:$C$5) ашиглан мужийг түгждэг. Нэрлэсэн муж мөн адил үйлчилнэ.

Хэрэв та томьёог шаардлагатай хэмжээнээс олон нүдэнд хуулсан бол #REF! алдаа "нэмэлт" нүднүүдэд гарч ирнэ. Үүнийг засахын тулд IFERROR функцэд томъёогоо дараах байдлаар боож өгнө үү:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

Эдгээр томьёо хэрхэн ажилладагийг

Доорх нь нарийвчилсан задаргаа юм. утгуудыг мөрөөр нь эрэмбэлсэн эхний томьёоны:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Томъёоны гол хэсэгт бид INDEX функцийг ашиглан нүдн дэх харьцангуй байрлалд үндэслэн утгыг авдаг. муж.

мөрийн дугаар -ийг дараах томъёогоор тооцоолно:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

1,1 гэх мэт давтагдах тооны дарааллыг гаргах санаа юм. ,1,2,2,2,3,3,3, … энд тоо бүр эх мужид багана байгаатай адил олон удаа давтагдана. Үүнийг бид дараах байдлаар хийдэг:

QUOTIENT нь хуваалтын бүхэл тоог буцаана.

тоологч -д бид цуваа буцаадаг COLUMN(A1)-1-ийг ашигладаг. Томьёог оруулсан эхний нүдний 0-ээс n хүртэлх тоо (муж дахь утгын нийт тоо)хасах 1) томъёог оруулсан сүүлчийн нүдэнд. Энэ жишээнд бид E2-д 0, M3-д 8 байна.

хүлээн авагчийн -д бид COLUMNS($A$3:$C$5)) ашигладаг. Энэ нь таны муж дахь баганын тоотой тэнцүү тогтмол тоог буцаана (манай тохиолдолд 3).

Үүний үр дүнд QUOTIENT функц нь эхний 3 нүдэнд (E3:G3) 0-г буцаана. 1-ийг нэмнэ, тэгэхээр мөрийн дугаар 1 байна.

Дараагийн 3 нүдэнд (H3:J3) QUOTIENT нь 1-ийг буцаана, +1 нь мөрийн дугаар 2-ыг өгнө. Гэх мэт.

баганын дугаар -г тооцоолохын тулд та MOD функцийг ашиглан тохирох тооны дарааллыг бүтээнэ:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Манай мужид 3 багана байгаа тул дараалал нь дараах байдалтай байх ёстой. : 1,2,3,1,2,3,...

MOD функц нь хуваагдсаны дараа үлдэгдлийг буцаана.

E3-д MOD(COLUMN(A1)-1, COLUMNS($) A$3:$C$5))+

MOD(1-1, 3)+1)

болж 1-ийг буцаана.

Д F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

болно

MOD(2-1, 3)+1)

болон 2-г буцаана.

Мөр, баганын дугаар тогтоогдсоны дараа INDEX тухайн мөр, баганын огтлолцол дээрх утгыг хялбархан татаж авдаг.

E3-д INDEX($A$3) :$C$5, 1, 1) 1-р мөр ба 1-р баганаас утгыг буцаана иш татсан мужаас, өөрөөр хэлбэл A3 нүднээс.

F3-д INDEX($A$3:$C$5, 1, 2) нь 1-р мөр ба 2-р баганаас, өөрөөр хэлбэл B3 нүднээс утгыг буцаана.

Гэх мэт.

Мужийг баганаар нь сканнердах хоёр дахь томьёо нь дараах байдлаар ажилладаг.ижил төстэй арга. Ялгаа нь бид MOD ашиглан мөрийн дугаарыг, QUOTIENT-ийг баганын дугаарыг гаргана.

TOROW функц ажиллахгүй байна

Хэрэв TOROW функц алдаа гарвал энэ нь Эдгээр шалтгаануудын нэг байж магадгүй:

#NAME? алдаа

Ихэнх Excel функцтэй #NAME? алдаа нь функцийн нэрийг алдаатай бичсэний тод илрэл юм. TOROW-ийн хувьд энэ нь таны Excel-д ажиллах боломжгүй гэсэн үг юм. Хэрэв таны Excel хувилбар 365-аас өөр бол TOROW хувилбарыг ашиглаж үзнэ үү.

#NUM алдаа

#NUM алдаа нь буцаасан массив нэг мөрөнд багтахгүй байгааг харуулж байна. Энэ нь ихэвчлэн жижиг муж биш багана ба/эсвэл мөрүүдийг бүхэлд нь иш татсан үед тохиолддог.

#SPILL алдаа

Ихэнх тохиолдолд #SPILL алдаа нь мөрийг хаана байгааг харуулж байна. Таны оруулсан томъёонд үр дүнг оруулах хангалттай хоосон нүд байхгүй байна. Хэрэв хөрш зэргэлдээх нүднүүд хоосон байвал тэдгээрийн дотор хоосон зай эсвэл хэвлэхгүй бусад тэмдэгт байхгүй эсэхийг шалгаарай. Дэлгэрэнгүй мэдээллийг Excel дээрх #SPILL алдаа гэж юу гэсэн үг вэ гэсэн хэсгээс үзнэ үү.

Ингэж та Excel-ийн TOROW функцийг ашиглан 2 хэмжээст массив эсвэл мужийг нэг мөр болгон хувиргадаг. Уншсан танд баярлалаа, дараа долоо хоногт манай блог дээр уулзана гэж найдаж байна!

Татаж авах дасгалын ном

Excel TOROW функц - томъёоны жишээ (.xlsx файл)