TOROW funksiyasının köməyi ilə bir sıra xanaları bir sıraya çevirməyin sürətli yolu.

Microsoft Excel 365 bir neçə yeni funksiya təqdim etdi. massivlərlə müxtəlif manipulyasiyalar etmək. TOROW ilə siz heç vaxt sıradan sıraya çevrilmələr edə bilərsiniz. Bu yeni funksiyanın yerinə yetirə biləcəyi tapşırıqların siyahısı budur:

Excel TOROW funksiyası

Excel-də TOROW funksiyası massivi və ya xanalar diapazonunu çevirmək üçün istifadə olunur. bir sıra.

Funksiya cəmi üç arqument qəbul edir, onlardan yalnız birincisi tələb olunur.

TOROW(massiv, [iqnor], [sütun üzrə_skan])

Harada:

Array (tələb olunur) - tək cərgəyə çevrilmək üçün massiv və ya diapazon.

İqnor (isteğe bağlı) - boşluqlara məhəl qoymamaq və ya/və ya etməməyi müəyyən edir. səhvlər. Bu dəyərlərdən birini qəbul edə bilər:

• 0 və ya buraxılmış (defolt) - bütün dəyərləri saxlamaq
• 1 - boşluqlara məhəl qoyma
• 2 - səhvlərə məhəl qoyma
• 3 - boşluqlara və xətalara məhəl qoyma

Sütun üzrə_skan (isteğe bağlı) - massivin necə skan edilməsini müəyyənləşdirir:

• YANLIŞ və ya buraxılmış (defolt) - massivi sətir üzrə üfüqi skan edin.
• DOĞRU - massivi şaquli olaraq sütun üzrə skan edin.

Məsləhətlər:

• Massivi çevirmək üçün tək sütunda TOCOL funksiyasından istifadə edin.
• Əks cərgədən massivə çevrilməni əvvəlcədən hazırlamaq üçün sütunlara bükmək üçün WRAPCOLS funksiyasından və ya bükmək üçün WRAPROWS funksiyasından istifadə edin.massivi sətirlərə çevirin.
• Sətirləri sütunlara çevirmək üçün TRANSPOSE funksiyasından istifadə edin.

TOROW-un mövcudluğu

TOROW yalnız Excel-də dəstəklənən yeni funksiyadır. Microsoft 365 (Windows və Mac üçün) və veb üçün Excel.

Excel-də əsas TOROW düsturu

Sadə diapazondan sıraya çevrilmə etmək üçün TOROW düsturundan istifadə edin. əsas formasında. Bunun üçün yalnız birinci arqumenti təyin etməlisiniz ( massiv ).

Məsələn, 3 sütun və 3 cərgədən ibarət ikiölçülü massivi tək sıraya çevirmək üçün düstur belədir:

=TOROW(A3:C6)

Siz düsturu yalnız bir xanaya daxil edirsiniz (bizim vəziyyətimizdə A10) və o, avtomatik olaraq bütün nəticələri saxlamaq üçün lazım olan sayda xanaya tökülür. Excel baxımından, nazik mavi haşiyə ilə əhatə olunmuş çıxış diapazonu dağılma diapazonu adlanır.

Bu düstur necə işləyir:

Birincisi, təmin edilmiş hüceyrələr sırası ikiölçülü massiləyə çevrilir. Vergüllə ayrılmış sütunlara və nöqtəli vergüllə ayrılmış sətirlərə diqqət yetirin:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

Sonra TOROW funksiyası massivi soldan sağa oxuyur və onu birölçülü üfüqi massivə çevirir:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

Nəticə A10 xanasına gedir və oradan o, sağdakı qonşu xanaya tökülür.

Boşluqlara və xətalara məhəl qoymadan cərgəni cərgəyə çevirin

Defolt olaraq, TOROW funksiyası boş xanalar və daxil olmaqla mənbə massivindəki bütün dəyərləri saxlayırsəhvlər. Çıxışda boş xanaların yerində sıfır dəyərlər görünür ki, bu da kifayət qədər çaşdırıcı ola bilər.

boşluqları istisna etmək üçün iqnor arqumentini 1-ə təyin edin:

=TOROW(A3:C5, 1)

səhvlərə məhəl qoymamaq üçün iqnor etmə arqumentini 2-yə təyin edin:

=TOROW(A3:C5, 2)

Keçmək üçün hər ikisi, boşluqlar və səhvlər , iqnor etmə arqumenti üçün 3-dən istifadə edin:

=TOROW(A3:C5, 3)

Aşağıdakı şəkil hər üç ssenarini işləyir:

Massivi üfüqi və ya şaquli olaraq oxuyun

Standart davranışla TOROW funksiyası massivi soldan sağa üfüqi şəkildə emal edir. Dəyərləri yuxarıdan aşağıya sütun üzrə skan etmək üçün siz 3-cü arqumenti ( sütun_ilə_scan ) TRUE və ya 1-ə təyin edirsiniz.

Məsələn, mənbə diapazonunu sətir-sətir oxumaq üçün E3:

=TOROW(A3:C5)

Aralığı sütun üzrə skan etmək üçün E8-də düstur belədir:

=TOROW(A3:C5, ,TRUE)

Hər iki halda nəticədə yaranan massivlər eyni ölçüdə, lakin dəyərlər fərqli ardıcıllıqla düzülür.

Birdən çox diapazonu bir cərgədə birləşdirin

Bir neçə bitişik olmayan diapazonu bir cərgədə birləşdirmək üçün əvvəlcə onları HSTACK və ya VSTACK köməyi ilə ilk növbədə üfüqi və ya şaquli olaraq vahid massivdə yığın , və sonra birləşdirilmiş massivi cərgəyə çevirmək üçün TOROW funksiyasından istifadə edin.

Biznes məntiqinizdən asılı olaraq, aşağıdakı düsturlardan biri tapşırığı yerinə yetirəcək.

Masivləri üfüqi şəkildə yığın və çevir sıra

Birinci iləA3:C4-də diapazon və A8:C9-da ikinci diapazon, aşağıdakı düstur iki diapazonu üfüqi olaraq bir massivdə yığacaq və sonra onu dəyərləri soldan sağa oxuyan sıraya çevirəcək. Nəticə aşağıdakı şəkildəki E3-dədir.

=TOROW(HSTACK(A3:C4, A8:C9))

Massivləri üfüqi şəkildə yığın və sütun üzrə çevirin

Yığılmış massivi yuxarıdan aşağıya şaquli oxumaq üçün, siz aşağıdakı şəkildəki E5-də göstərildiyi kimi TOROW-un 3-cü arqumentini TRUE olaraq təyin etdiniz:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

Massivləri şaquli şəkildə yığın və sətir üzrə çevirin

Hər birinə əlavə etmək üçün sonrakı massivi əvvəlki massivin altına köçürün və birləşdirilmiş massivi üfüqi oxuyun, E12-də düstur belədir:

=TOROW(VSTACK(A3:C4, A8:C9))

Massivləri şaquli olaraq yığın və sütunla çevirin

Hər bir sonrakı massivi əvvəlkinin altına əlavə etmək və birləşmiş massivi şaquli olaraq skan etmək üçün düstur belədir:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

Məntiqi daha yaxşı başa düşmək üçün buradakı dəyərlərin müxtəlif sırasına riayət edin. yaranan massivlər:

Bir sıradan unikal dəyərləri çıxarın

Microsoft Excel 2016-dan başlayaraq biz bir sütundan unikal dəyərləri asanlıqla əldə edə bilən UNİKAL adlı gözəl funksiyaya sahibik. və ya sıra. Bununla belə, o, çox sütunlu massivləri idarə edə bilməz. Bu məhdudiyyəti aradan qaldırmaq üçün UNİKAL və TOROW funksiyalarından birlikdə istifadə edin.

Məsələn, A2:C7 diapazonundan bütün fərqli (fərqli) dəyərləri çıxarmaq və nəticələri bir sıraya yerləşdirmək üçündüstur belədir:

=UNIQUE(TOROW(A2:C7), TRUE)

TOROW birölçülü üfüqi massivi qaytardığı üçün biz sütunları hər biri ilə müqayisə etmək üçün UNİKAL-ın 2-ci ( by_col ) arqumentini TRUE olaraq təyin edirik. digər.

Nəticələrin əlifba sırası ilə düzülməsini istəyirsinizsə, yuxarıdakı düsturu SORT funksiyasına sarın:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

UNİKAL ilə olduğu kimi, by_col SORT-un arqumenti də TRUE olaraq təyin edilib.

Excel 365 - 2010 üçün TOROW alternativi

TOROW funksiyasının mövcud olmadığı Excel versiyalarında siz bir neçə fərqli funksiyanın birləşməsindən istifadə edərək diapazonu tək sıraya çevirə bilərsiniz. köhnə versiyalar. Bu həllər daha mürəkkəbdir, lakin işləyir.

Dəzili üfüqi skan etmək üçün ümumi düstur belədir:

INDEX( aralıq , QUOTIENT(COLUMN (A1)-1, SÜTUNLAR( aralıq ))+1, MOD(SÜTUN(A1)-1, SÜTUNLAR( aralıq ))+1)

Aralığı şaquli olaraq skan etmək üçün ümumi düstur belədir :

İNDEX( aralıq , MOD(SÜTUN(A1)-1, SÜTUNLAR( aralıq ))+1, QUOTIENT(SÜTUN (A1)-1, SÜTUNLAR(<15)>aralıq ))+1)

A3:C5-dəki nümunə verilənlər toplusumuz üçün düsturlar bu formanı alır:

Aralığı sətir-sətir skan etmək üçün:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Bu düstur 3-cü arqumenti YANLIŞ olaraq təyin edilmiş və ya buraxılmış TOROW funksiyasına alternativdir:

=TOROW(A3:C5)

Aralığı skan etmək üçün sütun:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Bu düstur 3-cü arqument təyin edilmiş TOROW funksiyasına ekvivalentdirDOĞRU:

=TOROW(A3:C5, ,TRUE)

Nəzərə alın ki, dinamik massiv TOROW funksiyasından fərqli olaraq, bu ənənəvi düsturlar nəticələrin görünməsini istədiyiniz hər bir xanaya daxil edilməlidir. Bizim vəziyyətimizdə birinci düstur (sətirlə) E3-ə gedir və M3 vasitəsilə kopyalanır. İkinci düstur (sütun üzrə) E8-ə düşür və M8 vasitəsilə sürüklənir.

Düsturların düzgün surətdə kopyalanması üçün biz mütləq istinadlardan ($A$3:$C$5) istifadə edərək aralığı kilidləyirik. Adlandırılmış diapazon da bunu edəcək.

Əgər düsturları lazım olduğundan daha çox xanaya köçürmüsünüzsə, #REF! xəta "əlavə" xanalarda görünəcək. Bunu düzəltmək üçün düsturunuzu IFERROR funksiyasına bu şəkildə sarın:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

Bu düsturların necə işlədiyi

Aşağıda ətraflı məlumat verilmişdir. dəyərləri sıra ilə düzən birinci düsturdan:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Düsturun mərkəzində biz xananın nisbi mövqeyinə görə dəyərini almaq üçün İNDEX funksiyasından istifadə edirik. diapazon.

sətir nömrəsi bu düsturla hesablanır:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

İdeya 1,1 kimi təkrarlanan ədəd ardıcıllığı yaratmaqdır. ,1,2,2,2,3,3,3, … burada hər nömrə mənbə diapazonunda sütunlar olduğu qədər təkrarlanır. Biz bunu belə edirik:

QUOTIENT bölmənin tam hissəsini qaytarır.

numerator üçün biz serialı qaytaran COLUMN(A1)-1-dən istifadə edirik. düsturun daxil edildiyi ilk xanada 0-dan n -a qədər (aralıqdakı dəyərlərin ümumi sayı)mənfi 1) formulun daxil olduğu sonuncu xanada. Bu misalda E2-də 0, M3-də 8 var.

məxrəc üçün biz SÜTUNLAR($A$3:$C$5)) istifadə edirik. Bu, diapazonunuzdakı sütunların sayına bərabər sabit ədədi qaytarır (bizim halda 3).

Nəticədə QUOTIENT funksiyası ilk 3 xanada (E3:G3) 0 qaytarır. 1 əlavə edin, buna görə də sıra nömrəsi 1-dir.

Növbəti 3 xana üçün (H3:J3) QUOTIENT 1-i qaytarır və +1 sətir nömrəsini 2 verir. Və s.

sütun nömrəsini hesablamaq üçün MOD funksiyasından istifadə edərək müvafiq ədəd ardıcıllığı qurursunuz:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Bizim diapazonda 3 sütun olduğu üçün ardıcıllıq belə görünməlidir. : 1,2,3,1,2,3,...

MOD funksiyası bölmədən sonra qalanı qaytarır.

E3-də MOD(COLUMN(A1)-1, COLUMNS($) A$3:$C$5))+

MOD(1-1, 3)+1)

olur və 1-i qaytarır.

İçində F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

olur

MOD(2-1, 3)+1)

və 2-ni qaytarır.

Sətir və sütun nömrələri qurulduqdan sonra INDEX asanlıqla həmin sətir və sütunun kəsişməsindəki dəyəri əldə edir.

E3-də INDEX($A$3) :$C$5, 1, 1) 1-ci sətirdən və 1-ci sütundan dəyər qaytarır istinad edilən diapazondan, yəni A3 xanasından.

F3-də INDEX($A$3:$C$5, 1, 2) 1-ci sətirdən və 2-ci sütundan, yəni B3 xanasından dəyər qaytarır.

Və s.

İkinci düstur diapazonu sütun üzrə skan edir.oxşar şəkildə. Fərq ondadır ki, biz sətir nömrəsini hesablamaq üçün MOD-dan, sütun nömrəsini tapmaq üçün isə QUOTIENT-dən istifadə edirik.

TOROW funksiyası işləmir

Əgər TOROW funksiyası xəta ilə nəticələnirsə, bu, çox güman ki, bu səbəblərdən biri ola bilər:

#NAME? xəta

Excel funksiyalarının çoxunda #NAME? xəta funksiyanın adının səhv yazıldığının aydın göstəricisidir. TOROW ilə bu, funksiyanın Excel-də mövcud olmadığını da ifadə edə bilər. Excel versiyanız 365-dən fərqlidirsə, TOROW alternativindən istifadə etməyə çalışın.

#NUM xətası

#NUM xətası, qaytarılmış massivin cərgəyə sığmadığını göstərir. Çox vaxt bu, daha kiçik diapazon əvəzinə bütün sütunlara və/yaxud sətirlərə istinad etdiyiniz zaman baş verir.

#SPILL xətası

Əksər hallarda #SPILL xətası sətirin daxil etdiyiniz düsturda nəticələri tökmək üçün kifayət qədər boş xana yoxdur. Qonşu xanalar vizual olaraq boşdursa, onlarda boşluq və ya çap olunmayan digər simvolların olmadığından əmin olun. Ətraflı məlumat üçün Excel-də #SPILL xətası nə deməkdirsə, baxın.

2-ölçülü massivi və ya diapazonu tək sıraya çevirmək üçün Excel-də TOROW funksiyasından belə istifadə edirsiniz. Oxuduğunuz üçün sizə təşəkkür edirəm və sizi gələn həftə bloqumuzda görməyə ümid edirəm!

Endirmək üçün məşq iş dəftəri

Excel TOROW funksiyası - düstur nümunələri (.xlsx faylı)