Brz način pretvaranja niza ćelija u jedan red uz pomoć TOROW funkcije.

Microsoft Excel 365 predstavio je nekoliko novih funkcija za obavljanje raznih manipulacija s nizovima. Uz TOROW možete izvršiti transformacije raspona u redove u tren oka. Evo popisa zadataka koje ova nova funkcija može izvršiti:

Excel TOROW funkcija

TOROW funkcija u Excelu koristi se za pretvaranje niza ili raspona ćelija u jedan redak.

Funkcija uzima ukupno tri argumenta, od kojih je samo prvi potreban.

TOROW(niz, [ignoriraj], [skeniraj_po_stupcu])

Gdje:

Niz (obavezno) - niz ili raspon za transformaciju u jedan red.

Zanemari (neobavezno) - određuje hoće li se zanemariti praznine ili/i pogreške. Može uzeti jednu od ovih vrijednosti:

• 0 ili izostavljeno (zadano) - zadržati sve vrijednosti
• 1 - zanemariti praznine
• 2 - zanemariti pogreške
• 3 - zanemari praznine i pogreške

Skeniraj_po_stupcu (neobavezno) - definira kako skenirati niz:

• NETOČNO ili izostavljeno (zadano) - skenirajte niz vodoravno po retku.
• TRUE - skenirajte niz okomito po stupcu.

Savjeti:

• Za transformaciju niza u jedan stupac, upotrijebite funkciju TOCOL.
• Da biste izvršili obrnutu transformaciju retka u niz, upotrijebite funkciju WRAPCOLS za prelamanje u stupce ili funkciju WRAPROWS za prelamanjeniz u retke.
• Za pretvaranje redaka u stupce upotrijebite funkciju TRANSPOSE.

Dostupnost TOROW

TOROW je nova funkcija koja je podržana samo u Excelu za Microsoft 365 (za Windows i Mac) i Excel za web.

Osnovna TOROW formula u programu Excel

Da biste izvršili jednostavnu transformaciju raspona u red, koristite TOROW formulu u svom osnovnom obliku. Za ovo trebate definirati samo prvi argument ( niz ).

Na primjer, da biste pretvorili dvodimenzionalni niz koji se sastoji od 3 stupca i 3 retka u jedan redak, formula je:

=TOROW(A3:C6)

Formulu unesete u samo jednu ćeliju (u našem slučaju A10), a ona se automatski prelijeva u onoliko ćelija koliko je potrebno da zadrži sve rezultate. U terminima programa Excel, izlazni raspon okružen tankim plavim rubom naziva se raspon izlijevanja.

Kako ova formula funkcionira:

Prvo se isporučeni raspon ćelija transformira u dvodimenzionalni niz. Obratite pozornost na stupce odvojene zarezima i retke odvojene točkom i zarezom:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

Zatim funkcija TOROW čita niz slijeva nadesno i pretvara ga u jednodimenzionalni horizontalni niz:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

Rezultat ide u ćeliju A10, iz koje se prelijeva u susjednu ćeliju s desne strane.

Transformiraj raspon u red zanemarujući praznine i pogreške

Prema zadanim postavkama, funkcija TOROW čuva sve vrijednosti iz izvornog niza, uključujući prazne ćelije ipogreške. U ispisu se umjesto praznih ćelija pojavljuju nulte vrijednosti, što može biti prilično zbunjujuće.

Za isključivanje praznina , postavite argument ignore na 1:

=TOROW(A3:C5, 1)

Za ignoriranje pogrešaka , postavite argument ignore na 2:

=TOROW(A3:C5, 2)

Za preskakanje oboje, praznine i pogreške , koristite 3 za argument ignore :

=TOROW(A3:C5, 3)

Slika ispod prikazuje sva tri scenarija na djelu:

Čitajte niz vodoravno ili okomito

Sa zadanim ponašanjem, funkcija TOROW obrađuje niz vodoravno slijeva nadesno. Za skeniranje vrijednosti po stupcu od vrha prema dnu, postavljate 3. argument ( scan_by_column ) na TRUE ili 1.

Na primjer, za čitanje izvornog raspona po redu, formula u E3 je:

=TOROW(A3:C5)

Za skeniranje raspona po stupcu, formula u E8 je:

=TOROW(A3:C5, ,TRUE)

U oba slučaja, rezultirajući nizovi su iste veličine, ali su vrijednosti raspoređene drugačijim redoslijedom.

Spajanje višestrukih raspona u jedan red

Da biste kombinirali nekoliko nesusjednih raspona u jedan redak, prvo ih složite vodoravno ili okomito u jedan niz uz pomoć HSTACK-a ili VSTACK-a, redom , a zatim upotrijebite funkciju TOROW za pretvaranje kombiniranog niza u red.

Ovisno o vašoj poslovnoj logici, jedna od sljedećih formula izvršit će zadatak.

Složite nizove vodoravno i pretvorite prema red

S prvimraspon u A3:C4 i drugi raspon u A8:C9, formula u nastavku složit će dva raspona vodoravno u jedan niz, a zatim ga transformirati u red koji čita vrijednosti slijeva nadesno. Rezultat je u E3 na donjoj slici.

=TOROW(HSTACK(A3:C4, A8:C9))

Složite nizove vodoravno i pretvorite po stupcu

Da biste pročitali naslagani niz okomito od vrha prema dolje, postavite 3. argument od TOROW na TRUE kao što je prikazano u E5 na slici ispod:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

Složite nizove okomito i pretvorite po retku

Za dodavanje svakog sljedeće polje na dno prethodnog polja i čitajte kombinirano polje vodoravno, formula u E12 je:

=TOROW(VSTACK(A3:C4, A8:C9))

Složite nizove okomito i pretvorite po stupcu

Za dodavanje svakog sljedećeg niza na dno prethodnog i okomito skeniranje kombiniranog niza, formula je:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

Da biste bolje razumjeli logiku, promatrajte različiti redoslijed vrijednosti u rezultirajuće nizove:

Izdvojite jedinstvene vrijednosti iz raspona u red

Počevši od Microsoft Excela 2016, imamo prekrasnu funkciju, nazvanu UNIQUE, koja može lako dobiti jedinstvene vrijednosti iz jednog stupca ili redom. Međutim, ne može se nositi s nizovima s više stupaca. Da biste nadvladali ovo ograničenje, koristite funkcije UNIQUE i TOROW zajedno.

Na primjer, da biste izdvojili sve različite (različite) vrijednosti iz raspona A2:C7 i smjestili rezultate u jedan red,formula je:

=UNIQUE(TOROW(A2:C7), TRUE)

Budući da TOROW vraća jednodimenzionalni horizontalni niz, postavljamo 2. ( by_col ) argument UNIQUE na TRUE kako bismo usporedili stupce sa svakim ostalo.

U slučaju da želite rezultate poredane abecednim redom, zamotajte gornju formulu u funkciju SORT:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

Kao i kod UNIQUE, by_col argument za SORT također je postavljen na TRUE.

TOROW alternativa za Excel 365 - 2010

U verzijama programa Excel gdje funkcija TOROW nije dostupna, možete transformirati raspon u jedan red pomoću kombinacije nekoliko različitih funkcija koje rade u starije verzije. Ova su rješenja složenija, ali funkcioniraju.

Za vodoravno skeniranje raspona, generička formula je:

INDEX( range , QUOTIENT(COLUMN (A1)-1, COLUMNS( raspon ))+1, MOD(COLUMN(A1)-1, COLUMNS( raspon ))+1)

Za okomito skeniranje raspona, generička formula je :

INDEX( raspon , MOD(COLUMN(A1)-1, COLUMNS( raspon ))+1, QUOTIENT(COLUMN (A1)-1, COLUMNS( raspon ))+1)

Za naš uzorak skupa podataka u A3:C5, formule imaju ovaj oblik:

Za skeniranje raspona po redu:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Ova je formula alternativa funkciji TOROW s trećim argumentom postavljenim na FALSE ili izostavljenim:

=TOROW(A3:C5)

Za skeniranje raspona pomoću stupac:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Ova formula je ekvivalentna funkciji TOROW s trećim argumentom postavljenim naTRUE:

=TOROW(A3:C5, ,TRUE)

Imajte na umu da za razliku od funkcije dinamičkog polja TOROW, ove tradicionalne formule treba unijeti u svaku ćeliju u kojoj želite da se pojave rezultati. U našem slučaju, prva formula (po redu) ide u E3 i kopira se kroz M3. Druga formula (po stupcu) dolazi u E8 i povlači se kroz M8.

Da bi se formule pravilno kopirale, zaključavamo raspon pomoću apsolutnih referenci ($A$3:$C$5). Imenovani raspon također će poslužiti.

Ako ste kopirali formule u više ćelija nego što je potrebno, #REF! pogreška će se pojaviti u "dodatnim" ćelijama. Da biste to popravili, zamotajte svoju formulu u funkciju IFERROR ovako:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

Kako ove formule rade

U nastavku je detaljna raščlamba prve formule koja raspoređuje vrijednosti po retku:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

U središtu formule koristimo se funkcijom INDEX za dobivanje vrijednosti ćelije na temelju njezinog relativnog položaja u raspon.

Broj reda izračunava se ovom formulom:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Ideja je proizvesti niz brojeva koji se ponavlja kao što je 1,1 ,1,2,2,2,3,3,3, … gdje se svaki broj ponavlja onoliko puta koliko ima stupaca u izvornom rasponu. Evo kako to radimo:

QUOTIENT vraća cjelobrojni dio dijeljenja.

Za brojnik koristimo COLUMN(A1)-1, koji vraća serijski broj od 0 u prvoj ćeliji u koju je formula unesena do n (ukupan broj vrijednosti u rasponuminus 1) u zadnjoj ćeliji u kojoj je formula unesena. U ovom primjeru imamo 0 u E2 i 8 u M3.

Za nazivnik koristimo COLUMNS($A$3:$C$5)). Ovo vraća konstantan broj jednak broju stupaca u vašem rasponu (3 u našem slučaju).

Kao rezultat, funkcija QUOTIENT vraća 0 u prve 3 ćelije (E3:G3), na koje smo dodajte 1, tako da je broj retka 1.

Za sljedeće 3 ćelije (H3:J3), QUOTIENT vraća 1, a +1 daje broj retka 2. I tako dalje.

Da biste izračunali broj stupca , izgradite odgovarajući niz brojeva koristeći MOD funkciju:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Budući da u našem rasponu postoje 3 stupca, niz mora izgledati ovako : 1,2,3,1,2,3,…

Funkcija MOD vraća ostatak nakon dijeljenja.

U E3, MOD(COLUMN(A1)-1, COLUMNS($) A$3:$C$5))+

postaje

MOD(1-1, 3)+1)

i vraća 1.

U F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

postaje

MOD(2-1, 3)+1)

i vraća 2.

Nakon što se utvrde brojevi retka i stupca, INDEX lako dohvaća vrijednost na sjecištu tog retka i stupca.

U E3, INDEX($A$3 :$C$5, 1, 1) vraća vrijednost iz 1. retka i 1. stupca referentnog raspona, tj. iz ćelije A3.

U F3, INDEX($A$3:$C$5, 1, 2) vraća vrijednost iz 1. retka i 2. stupca, tj. iz ćelije B3.

I tako dalje.

Druga formula koja skenira raspon po stupcu, radi usličan način. Razlika je u tome što koristimo MOD za izračunavanje broja retka i QUOTIENT za određivanje broja stupca.

Funkcija TOROW ne radi

Ako funkcija TOROW rezultira pogreškom, to je najvjerojatnije jedan od ovih razloga:

#IME? error

Kod većine Excel funkcija, #NAME? pogreška je jasan pokazatelj da je naziv funkcije pogrešno napisan. Uz TOROW to također može značiti da funkcija nije dostupna u vašem Excelu. Ako vaša verzija Excela nije 365, pokušajte upotrijebiti alternativu TOROW.

#NUM error

#NUM error označava da vraćeni niz ne može stati u red. Najčešće se to događa kada referencirate cijele stupce i/ili retke umjesto manjeg raspona.

#SPILL error

U većini slučajeva, #SPILL pogreška sugerira da je red gdje formulu koju ste unijeli nema dovoljno praznih ćelija u koje bi se prelili rezultati. Ako su susjedne ćelije vizualno prazne, provjerite da u njima nema razmaka ili drugih neispisnih znakova. Za više informacija pogledajte Što znači pogreška #SPILL u Excelu.

Tako koristite funkciju TOROW u Excelu za pretvaranje 2-dimenzionalnog polja ili raspona u jedan red. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Radna bilježnica za vježbe za preuzimanje

Excel TOROW funkcija - primjeri formula (.xlsx datoteka)