TOROW функциясының көмегімен ұяшықтар ауқымын бір жолға айналдырудың жылдам жолы.

Microsoft Excel 365 бірнеше жаңа функцияларды енгізді. массивтермен әртүрлі манипуляцияларды орындау. TOROW көмегімен диапазоннан жолға түрлендірулерді еш уақытта орындауға болады. Міне, осы жаңа функция орындай алатын тапсырмалар тізімі:

Excel TOROW функциясы

Excel бағдарламасындағы TOROW функциясы массив немесе ұяшықтар ауқымын түрлендіру үшін пайдаланылады. бір жол.

Функция барлығы үш аргументті қабылдайды, оның ішінде тек біріншісі ғана қажет.

TOROW(массив, [елеспеу], [баған_бойынша_сканерлеу])

Мұндағы:

Массив (міндетті) - бір жолға түрлендіруге арналған массив немесе ауқым.

Елмеу (міндетті емес) - бос орындарды немесе/және елемеу керектігін анықтайды. қателер. Мына мәндердің бірін қабылдай алады:

• 0 немесе түсірілген (әдепкі) - барлық мәндерді сақтау
• 1 - бос орындарды елемеу
• 2 - қателерді елемеу
• 3 - бос орындар мен қателерді елемеу

Баған_бойынша сканерлеу (міндетті емес) - алапты сканерлеу жолын анықтайды:

• ЖАЛҒАН немесе түсірілген (әдепкі) - массивті көлденеңінен жолдар бойынша сканерлеңіз.
• TRUE - массивті тігінен баған бойынша сканерлеңіз.

Кеңестер:

• Массивті түрлендіру үшін бір бағанға қосу үшін TOCOL функциясын пайдаланыңыз.
• Кері жолды массивке түрлендіруді алдын ала дайындау үшін бағандарға орау үшін WRAPCOLS функциясын немесе орау үшін WRAPROWS функциясын пайдаланыңыз.массив жолдарға.
• Жолдарды бағандарға айналдыру үшін TRANSPOSE функциясын пайдаланыңыз.

TOROW қолжетімділігі

TOROW — тек Excel бағдарламасында қолдау көрсетілетін жаңа функция. Microsoft 365 (Windows және Mac үшін) және вебке арналған Excel.

Excel бағдарламасындағы негізгі TOROW формуласы

Қарапайым ауқымды жолға түрлендіру үшін TOROW формуласын пайдаланыңыз. оның негізгі түрінде. Ол үшін тек бірінші аргументті ( массив ) анықтау керек.

Мысалы, 3 баған мен 3 жолдан тұратын екі өлшемді массивді бір жолға айналдыру үшін, формула:

=TOROW(A3:C6)

Сіз формуланы тек бір ұяшыққа енгізесіз (біздің жағдайда A10) және ол барлық нәтижелерді сақтау үшін қажет болғанша көп ұяшыққа автоматты түрде төгіледі. Excel терминінде жіңішке көк жиекпен қоршалған шығыс ауқымы төгілу ауқымы деп аталады.

Бұл формула қалай жұмыс істейді:

Біріншіден, берілген ұяшықтар ауқымы екі өлшемді массивке түрлендіріледі. Үтірмен бөлінген бағандар мен нүктелі үтірмен бөлінген жолдарға назар аударыңыз:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

Содан кейін TOROW функциясы алапты солдан оңға қарай оқиды және оны бір өлшемді көлденең массивке түрлендіреді:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

Нәтиже A10 ұяшығына жіберіледі, одан ол оң жақтағы көрші ұяшыққа түседі.

Бос орындар мен қателерді елемейтін жолға диапазонды түрлендіру

Әдепкі бойынша, TOROW функциясы бастапқы массивтегі барлық мәндерді, соның ішінде бос ұяшықтарды және сақтайдықателер. Шығаруда бос ұяшықтардың орнында нөлдік мәндер пайда болады, бұл өте түсініксіз болуы мүмкін.

бос орындарды алып тастау үшін елеспеу аргументін 1 мәніне орнатыңыз:

=TOROW(A3:C5, 1)

қателерді елемеу үшін елеспеу аргументін 2 мәніне орнатыңыз:

=TOROW(A3:C5, 2)

Өткізіп жіберу үшін екеуі де, бос және қателер , елеспеу аргументі үшін 3 мәнін пайдаланыңыз:

=TOROW(A3:C5, 3)

Төмендегі суретте барлық үш сценарий әрекетте көрсетілген:

Массивті көлденең немесе тігінен оқу

Әдепкі әрекетте TOROW функциясы массивді көлденеңінен солдан оңға қарай өңдейді. Мәндерді жоғарыдан төменге қарай баған бойынша сканерлеу үшін 3-аргументті ( баған_бойынша сканерлеу ) TRUE немесе 1 мәніне орнатасыз.

Мысалы, бастапқы ауқымды жол бойынша оқу үшін, формула E3 - бұл:

=TOROW(A3:C5)

Ауқымды баған бойынша сканерлеу үшін E8-дегі формула:

=TOROW(A3:C5, ,TRUE)

Екі жағдайда да нәтиже массивтері өлшемі бірдей, бірақ мәндер басқа ретпен орналастырылған.

Бір қатарға бірнеше диапазондарды біріктіру

Бірнеше іргелес емес ауқымдарды бір жолға біріктіру үшін алдымен оларды HSTACK немесе VSTACK көмегімен сәйкесінше көлденең немесе тігінен бір массивке жинаңыз. , содан кейін біріктірілген массивді жолға түрлендіру үшін TOROW функциясын пайдаланыңыз.

Бизнес логикаңызға байланысты келесі формулалардың бірі тапсырманы орындайды.

Массивтерді көлденеңінен стек және түрлендіріңіз: қатар

Біріншімендиапазон A3:C4 және екінші ауқым A8:C9 ішінде болса, төмендегі формула екі ауқымды көлденеңінен бір массивке жинақтайды, содан кейін оны мәндерді солдан оңға қарай оқитын жолға түрлендіреді. Нәтиже төмендегі суреттегі E3 форматында.

=TOROW(HSTACK(A3:C4, A8:C9))

Массивтерді көлденеңінен стектеу және баған бойынша түрлендіру

Стектелген массивді тігінен жоғарыдан төмен оқу үшін, төмендегі суреттегі E5-те көрсетілгендей TOROW 3-ші аргументін TRUE мәніне орнатыңыз:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

Массивтерді тігінен орналастырыңыз және жол бойынша түрлендіріңіз

Әрқайсысын қосу үшін келесі массивді алдыңғы массивтің төменгі жағына қойыңыз және біріктірілген массивді көлденеңінен оқыңыз, E12 формуласы:

=TOROW(VSTACK(A3:C4, A8:C9))

Массивтерді тігінен орналастырыңыз және баған бойынша түрлендіріңіз

Әрбір келесі массивді алдыңғысының төменгі жағына қосу және біріктірілген массивді тігінен сканерлеу үшін мына формула табылады:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

Логиканы жақсырақ түсіну үшін, мәндердің әртүрлі ретін сақтаңыз. алынған массивтер:

Бірегей мәндерді диапазоннан жолға шығару

Microsoft Excel 2016 бағдарламасынан бастап бізде бір бағаннан бірегей мәндерді оңай алуға болатын UNIQUE деп аталатын тамаша функция бар. немесе қатар. Дегенмен, ол көп бағанды ​​массивтерді өңдей алмайды. Бұл шектеуді еңсеру үшін UNIQUE және TOROW функцияларын бірге пайдаланыңыз.

Мысалы, A2:C7 ауқымынан барлық әртүрлі (әртүрлі) мәндерді шығарып алу және нәтижелерді бір жолға орналастыру үшін,формула:

=UNIQUE(TOROW(A2:C7), TRUE)

TOROW бір өлшемді көлденең жиымды қайтаратындықтан, біз бағандарды әрқайсысымен салыстыру үшін UNIQUE 2-ші ( та_түс ) аргументін TRUE мәніне орнаттық. басқа.

Нәтижелердің әліпби ретімен реттелгенін қаласаңыз, жоғарыдағы формуланы СҰРЫПТАУ функциясына ораңыз:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

UNIQUE сияқты, by_col SORT аргументі де TRUE мәніне орнатылған.

Excel 365 - 2010 үшін TOROW балама

TOROW функциясы қолжетімсіз Excel нұсқаларында келесіде жұмыс істейтін бірнеше түрлі функциялардың тіркесімін пайдаланып ауқымды бір жолға түрлендіруге болады. ескі нұсқалар. Бұл шешімдер күрделірек, бірақ олар жұмыс істейді.

Ауқымды көлденең сканерлеу үшін жалпы формула:

INDEX( диапазон , QUOTIENT(COLUMN (A1)-1, БАҒАН( диапазон ))+1, MOD(COLUMN(A1)-1, COLUMNS( ауқым ))+1)

Ауқымды тігінен сканерлеу үшін жалпы формула: :

INDEX( диапазон , MOD(COLUMN(A1)-1, COLUMNS( ауқым ))+1, QUOTIENT(COLUMN (A1)-1, COLUMNS(<15)>ауқым ))+1)

A3:C5 форматындағы үлгі деректер жиыны үшін формулалар мына пішінді алады:

Ауқымды жол бойынша сканерлеу үшін:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Бұл формула TOROW функциясына балама болып табылады, 3-аргументі ЖАЛҒАН деп орнатылған немесе түсірілген:

=TOROW(A3:C5)

Ауқымды сканерлеу үшін: баған:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Бұл формула TOROW функциясына балама, 3-аргументіРАС:

=TOROW(A3:C5, ,TRUE)

Динамикалық массивтің TOROW функциясынан айырмашылығы, бұл дәстүрлі формулалар нәтижелер шығатын әрбір ұяшыққа енгізілуі керек екенін ескеріңіз. Біздің жағдайда бірінші формула (жол бойынша) E3-ке өтеді және M3 арқылы көшіріледі. Екінші формула (баған бойынша) E8 ішіне түседі және M8 арқылы апарылады.

Формулаларды дұрыс көшіру үшін абсолютті сілтемелерді ($A$3:$C$5) пайдаланып ауқымды құлыптаймыз. Атаулы ауқым да орындалады.

Егер формулаларды қажетінен көбірек ұяшықтарға көшірсеңіз, #REF! қате «қосымша» ұяшықтарда пайда болады. Бұны түзету үшін формулаңызды IFERROR функциясына келесідей ораңыз:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

Бұл формулалар қалай жұмыс істейді

Төменде егжей-тегжейлі бөлім берілген. мәндерді жол бойынша орналастыратын бірінші формуланың:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Формуланың негізінде ұяшықтың мәнін оның ұяшықтағы салыстырмалы орнына негізделген алу үшін INDEX функциясын қолданамыз. диапазон.

жол нөмірі мына формула бойынша есептеледі:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Осы идея 1,1 сияқты қайталанатын сандар тізбегін жасау болып табылады. ,1,2,2,2,3,3,3, … мұнда әрбір сан бастапқы ауқымдағы бағандар қанша рет қайталанады. Міне, біз мұны істейміз:

QUOTIENT бөлімнің бүтін бөлігін қайтарады.

алымдар үшін серияны қайтаратын COLUMN(A1)-1 қолданамыз. формула енгізілген бірінші ұяшықтағы 0-ден бастап n (ауқымдағы мәндердің жалпы саны) саныминус 1) формула енгізілген соңғы ұяшықта. Бұл мысалда бізде E2-де 0 және M3-те 8 бар.

деноминатор үшін біз БАҒАНдарды($A$3:$C$5)) пайдаланамыз. Бұл сіздің ауқымыңыздағы бағандар санына тең тұрақты санды қайтарады (біздің жағдайда 3).

Нәтижесінде QUOTIENT функциясы алғашқы 3 ұяшықта (E3:G3) 0 мәнін қайтарады, оған біз 1 қосыңыз, сондықтан жол нөмірі 1 болады.

Келесі 3 ұяшық үшін (H3:J3) QUOTIENT 1 мәнін қайтарады және +1 2 жол нөмірін береді.

баған нөмірін есептеу үшін MOD функциясы арқылы сәйкес сандар тізбегін құрастырасыз:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Біздің диапазонда 3 баған болғандықтан, реттілік келесідей болуы керек. : 1,2,3,1,2,3,…

MOD функциясы бөлгеннен кейінгі қалдықты қайтарады.

E3 ішінде MOD(COLUMN(A1)-1, COLUMNS($) A$3:$C$5))+

MOD(1-1, 3)+1)

болып, 1 мәнін қайтарады.

Ішінде F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

болды

MOD(2-1, 3)+1)

және 2 мәнін қайтарады.

Жол мен баған нөмірлері орнатылғаннан кейін INDEX сол жол мен бағанның қиылысындағы мәнді оңай алады.

E3 ішінде INDEX($A$3) :$C$5, 1, 1) 1-ші жол мен 1-бағандағы мәнді қайтарады сілтеме жасалған ауқымның, яғни A3 ұяшығынан.

F3 ішінде INDEX($A$3:$C$5, 1, 2) 1-ші жол мен 2-бағандағы мәнді қайтарады, яғни B3 ұяшығынан.

Және т.б.

Баған бойынша диапазонды сканерлейтін екінші формулаұқсас жол. Айырмашылығы мынада: жол нөмірін есептеу үшін MOD, ал баған нөмірін анықтау үшін QUOTIENT пайдаланамыз.

TOROW функциясы жұмыс істемейді

Егер TOROW функциясы қатеге әкелсе, ол ең алдымен мына себептердің бірі болуы мүмкін:

#NAME? қате

Excel функцияларының көпшілігінде #NAME? қате функция атауының қате жазылғанының айқын көрсеткіші болып табылады. TOROW көмегімен бұл функция Excel бағдарламасында қол жетімді емес дегенді де білдіруі мүмкін. Егер Excel нұсқасы 365-тен басқа болса, TOROW баламасын пайдаланып көріңіз.

#NUM қатесі

#NUM қатесі қайтарылған массив жолға сыймайтынын көрсетеді. Көбінесе бұл кішірек ауқымның орнына бүкіл бағандарға және/немесе жолдарға сілтеме жасағанда орын алады.

#SPILL қатесі

Көп жағдайда #SPILL қатесі жолдың формуланы енгіздіңіз, нәтижелерді төгу үшін бос ұяшықтар жеткіліксіз. Көрші ұяшықтар визуалды түрде бос болса, оларда бос орындар немесе басқа басып шығарылмайтын таңбалар жоқ екеніне көз жеткізіңіз. Қосымша ақпарат алу үшін Excel бағдарламасындағы #SPILL қатесі нені білдіреді бөлімін қараңыз.

Осылайша Excel бағдарламасындағы TOROW функциясын екі өлшемді массив немесе ауқымды бір жолға түрлендіру үшін пайдаланасыз. Оқығаныңыз үшін алғыс айтамын және келесі аптада блогымызда көреміз деп үміттенемін!

Жүктеп алуға арналған жұмыс кітабы

Excel TOROW функциясы - формула мысалдары (.xlsx файлы)