TOROW 기능을 사용하여 셀 범위를 단일 행으로 빠르게 변환할 수 있습니다.

Microsoft Excel 365에는 몇 가지 새로운 기능이 도입되었습니다. 배열로 다양한 조작을 수행합니다. TOROW를 사용하면 즉시 행 범위 변환을 수행할 수 있습니다. 다음은 이 새 함수가 수행할 수 있는 작업 목록입니다.

Excel TOROW 함수

Excel의 TOROW 함수는 셀의 배열 또는 범위를 다음으로 변환하는 데 사용됩니다. 한 행.

이 함수는 총 세 개의 인수를 사용하며 첫 번째 인수만 필요합니다.

TOROW(array, [ignore], [scan_by_column])

Where:

Array (필수) - 단일 행으로 변환할 배열 또는 범위입니다.

Ignore (선택) - 공백을 무시할지 여부를 결정합니다. 오류. 다음 값 중 하나를 사용할 수 있습니다.

• 0 또는 생략(기본값) - 모든 값 유지
• 1 - 공백 무시
• 2 - 오류 무시
• 3 - 공백 및 오류 무시

Scan_by_column (선택 사항) - 어레이 스캔 방법 정의:

• FALSE 또는 생략됨(기본값) - 배열을 행별로 가로로 스캔합니다.
• TRUE - 열로 배열을 세로로 스캔합니다.

팁:

• 배열을 변환하려면 TOCOL 함수를 활용하십시오.
• 행에서 배열로의 역 변환을 수행하려면 WRAPCOLS 함수를 사용하여 열로 래핑하거나 WRAPROWS 함수를 사용하여 래핑하십시오.배열을 행으로.
• 행을 열로 바꾸려면 TRANSPOSE 함수를 사용하세요.

TOROW 가용성

TOROW는 Excel에서만 지원되는 새로운 함수입니다. Microsoft 365(Windows 및 Mac용) 및 웹용 Excel.

Excel

의 기본 TOROW 수식 간단한 범위-행 변환을 수행하려면 TOROW 수식 사용 기본 형태로. 이를 위해서는 첫 번째 인수( array )만 정의하면 됩니다.

예를 들어 3개의 열과 3개의 행으로 구성된 2차원 배열을 단일 행으로 변환하려면 수식은 다음과 같습니다.

=TOROW(A3:C6)

단 하나의 셀(여기서는 A10)에 수식을 입력하면 자동으로 모든 결과를 포함하는 데 필요한 만큼 많은 셀에 분산됩니다. Excel 용어로 얇은 파란색 테두리로 둘러싸인 출력 범위를 유출 범위라고 합니다.

이 수식이 작동하는 방식:

먼저 제공된 셀 범위가 2차원 배열로 변환됩니다. 쉼표로 구분된 열과 세미콜론으로 구분된 행을 확인하십시오:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

그런 다음 TOROW 함수는 배열을 왼쪽에서 오른쪽으로 읽고 1차원 수평 배열로 변환합니다.

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

결과는 셀 A10으로 이동하여 오른쪽에 있는 이웃 셀로 유출됩니다.

공백 및 오류를 무시하고 범위를 행으로 변환

기본적으로 TOROW 함수는 빈 셀과오류. 출력에서 빈 셀 대신 0 값이 표시되어 매우 혼란스러울 수 있습니다.

공백 을 제외하려면 ignore 인수를 1로 설정합니다.

=TOROW(A3:C5, 1)

오류를 무시 하려면 ignore 인수를 2로 설정합니다.

=TOROW(A3:C5, 2)

건너뛰려면 공백 및 오류 둘 다 ignore 인수에 3을 사용합니다.

=TOROW(A3:C5, 3)

아래 이미지는 작동 중인 세 가지 시나리오를 모두 보여줍니다.

가로 또는 세로 배열 읽기

기본 동작에서 TOROW 함수는 배열을 왼쪽에서 오른쪽으로 가로로 처리합니다. 위에서 아래로 열별로 값을 스캔하려면 세 번째 인수( scan_by_column )를 TRUE 또는 1로 설정합니다.

예를 들어 소스 범위를 행별로 읽으려면 E3은:

=TOROW(A3:C5)

범위를 열로 스캔하기 위한 E8의 수식은 다음과 같습니다.

=TOROW(A3:C5, ,TRUE)

두 경우 모두 결과 배열은 다음과 같습니다. 크기는 같지만 값이 다른 순서로 정렬됩니다.

여러 범위를 하나의 행으로 병합

인접하지 않은 여러 범위를 단일 행으로 결합하려면 먼저 각각 HSTACK 또는 VSTACK의 도움을 받아 가로 또는 세로로 단일 배열로 스택합니다. , 그런 다음 TOROW 함수를 사용하여 결합된 배열을 행으로 변환합니다.

비즈니스 논리에 따라 다음 수식 중 하나가 작업을 수행합니다.

배열을 가로로 쌓고 다음으로 변환합니다. row

첫 번째A3:C4의 범위와 A8:C9의 두 번째 범위, 아래 수식은 두 범위를 가로로 단일 배열로 쌓은 다음 왼쪽에서 오른쪽으로 값을 읽는 행으로 변환합니다. 결과는 아래 이미지의 E3에 있습니다.

=TOROW(HSTACK(A3:C4, A8:C9))

배열을 가로로 쌓고 열로 변환합니다.

쌓인 배열을 위에서 아래로 세로로 읽으려면, 아래 이미지의 E5에 표시된 대로 TOROW의 세 번째 인수를 TRUE로 설정합니다.

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

배열을 세로로 쌓고 행별로 변환

후속 배열을 이전 배열의 맨 아래에 놓고 결합된 배열을 가로로 읽으면 E12의 공식은 다음과 같습니다.

=TOROW(VSTACK(A3:C4, A8:C9))

배열을 세로로 쌓고 열로 변환

각각의 후속 어레이를 이전 어레이의 맨 아래에 추가하고 결합된 어레이를 수직으로 스캔하려면 공식은 다음과 같습니다.

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

논리를 더 잘 이해하려면 결과 배열:

범위에서 행으로 고유한 값 추출

Microsoft Excel 2016부터 단일 열에서 고유한 값을 쉽게 가져올 수 있는 UNIQUE라는 멋진 함수가 있습니다. 또는 행. 그러나 다중 열 배열은 처리할 수 없습니다. 이 제한을 극복하려면 UNIQUE 및 TOROW 함수를 함께 사용하십시오.

예를 들어 A2:C7 범위에서 서로 다른(고유한) 값을 모두 추출하고 결과를 한 행에 배치하려면수식:

=UNIQUE(TOROW(A2:C7), TRUE)

TOROW는 1차원 수평 배열을 반환하므로 UNIQUE의 두 번째( by_col ) 인수를 TRUE로 설정하여 열을 각 배열과 비교합니다. other.

결과를 ​​알파벳순으로 정렬하려면 위 수식을 SORT 함수로 래핑합니다.

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

UNIQUE와 마찬가지로 by_col SORT의 인수도 TRUE로 설정됩니다.

Excel 365용 TOROW 대안 - 2010

TOROW 함수를 사용할 수 없는 Excel 버전에서는 다음에서 작동하는 몇 가지 다른 함수의 조합을 사용하여 범위를 단일 행으로 변환할 수 있습니다. 이전 버전. 이러한 솔루션은 더 복잡하지만 작동합니다.

범위를 수평으로 스캔하기 위한 일반 공식은 다음과 같습니다.

INDEX( range , QUOTIENT(COLUMN (A1)-1, COLUMNS( range ))+1, MOD(COLUMN(A1)-1, COLUMNS( range ))+1)

범위를 세로로 스캔하려면 일반 공식은 다음과 같습니다. :

INDEX( 범위 , MOD(COLUMN(A1)-1, COLUMNS( 범위 ))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS( range ))+1)

A3:C5의 샘플 데이터세트의 경우 수식은 다음과 같은 모양을 취합니다.

행별로 범위를 스캔하려면:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

이 수식은 세 번째 인수가 FALSE로 설정되거나 생략된 TOROW 함수의 대안입니다.

=TOROW(A3:C5)

범위를 스캔하려면 column:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

이 수식은 세 번째 인수가 다음으로 설정된 TOROW 함수와 동일합니다.TRUE:

=TOROW(A3:C5, ,TRUE)

동적 배열 TOROW 함수와 달리 이러한 기존 수식은 결과를 표시하려는 각 셀에 입력해야 합니다. 우리의 경우 첫 번째 수식(행별)은 E3으로 이동하고 M3을 통해 복사됩니다. 두 번째 수식(열 기준)은 E8에 도착하고 M8을 통해 드래그됩니다.

수식을 올바르게 복사하려면 절대 참조($A$3:$C$5)를 사용하여 범위를 잠급니다. 명명된 범위도 가능합니다.

수식을 필요한 것보다 더 많은 셀에 복사한 경우 #REF! "추가" 셀에 오류가 나타납니다. 이 문제를 해결하려면 수식을 다음과 같이 IFERROR 함수로 래핑하십시오.

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

수식 작동 방식

아래는 자세한 분석입니다. 값을 행별로 정렬하는 첫 번째 수식:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

수식의 중심에는 INDEX 함수를 사용하여 범위.

행 번호 는 다음 공식으로 계산됩니다.

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

아이디어는 1,1과 같은 반복되는 숫자 시퀀스를 생성하는 것입니다. ,1,2,2,2,3,3,3, … 여기서 각 숫자는 소스 범위에 있는 열 수만큼 반복됩니다.

QUOTIENT는 나누기의 정수 부분을 반환합니다.

분자 의 경우 COLUMN(A1)-1을 사용하여 일련 번호를 반환합니다. 수식이 입력된 첫 번째 셀의 0부터 n 까지의 숫자(범위에 있는 값의 총 개수빼기 1) 수식이 입력된 마지막 셀에서. 이 예에서는 E2에 0, M3에 8이 있습니다.

분모 의 경우 COLUMNS($A$3:$C$5))를 사용합니다. 이것은 범위의 열 수와 같은 상수를 반환합니다(여기서는 3개).

결과적으로 QUOTIENT 함수는 처음 3개 셀(E3:G3)에서 0을 반환합니다. 1을 더하면 행 번호는 1이 됩니다.

다음 3개 셀(H3:J3)에 대해 QUOTIENT는 1을 반환하고 +1은 행 번호 2를 반환합니다. 이와 같이 계속됩니다.

열 번호 를 계산하려면 MOD 함수를 사용하여 적절한 번호 시퀀스를 작성합니다.

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

범위에 3개의 열이 있으므로 시퀀스는 다음과 같아야 합니다. : 1,2,3,1,2,3,… A$3:$C$5))+

는

MOD(1-1, 3)+1)

가 되고 1을 반환합니다.

In F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

MOD(2-1, 3)+1)

하고 2를 반환합니다.

행과 열 번호가 설정되면 INDEX는 해당 행과 열의 교차점에서 값을 쉽게 가져옵니다.

E3에서 INDEX($A$3 :$C$5, 1, 1)은 첫 번째 행과 첫 번째 열의 값을 반환합니다. 참조 범위, 즉 셀 A3에서.

F3에서 INDEX($A$3:$C$5, 1, 2)는 첫 번째 행과 두 번째 열, 즉 셀 B3에서 값을 반환합니다.

등.

범위를 열별로 스캔하는 두 번째 수식은비슷한 방법. 차이점은 MOD를 사용하여 행 번호를 계산하고 QUOTIENT를 사용하여 열 번호를 계산한다는 것입니다.

TOROW 함수가 작동하지 않음

TOROW 함수 결과 오류가 발생하면 다음 이유 중 하나일 가능성이 높습니다.

#NAME? error

대부분의 Excel 함수에서 #NAME? 오류는 함수 이름의 철자가 틀렸다는 명확한 표시입니다. TOROW를 사용하면 Excel에서 함수를 사용할 수 없음을 의미할 수도 있습니다. Excel 버전이 365가 아닌 경우 TOROW 대안을 사용해 보십시오.

#NUM error

#NUM 오류는 반환된 배열이 행에 맞지 않음을 나타냅니다. 더 작은 범위 대신 전체 열 및/또는 행을 참조할 때 가장 자주 발생합니다.

#SPILL error

대부분의 경우 #SPILL 오류는 행이 수식을 입력했지만 빈 셀이 충분하지 않아 결과를 쏟을 수 없습니다. 인접한 셀이 시각적으로 비어 있는 경우 공백이나 기타 인쇄되지 않는 문자가 없는지 확인하십시오. 자세한 내용은 Excel에서 #SPILL 오류의 의미를 참조하세요.

이것이 Excel에서 TOROW 함수를 사용하여 2차원 배열 또는 범위를 단일 행으로 변환하는 방법입니다. 읽어 주셔서 감사합니다. 다음 주 블로그에서 뵙기를 바랍니다!

다운로드용 실습 워크북

Excel TOROW 함수 - 수식 예제(.xlsx 파일)