TOROW प्रकार्यको मद्दतले कक्षहरूको दायरालाई एउटै पङ्क्तिमा बदल्ने द्रुत तरिका।

Microsoft Excel 365 ले धेरै नयाँ प्रकार्यहरू प्रस्तुत गरेको छ। arrays संग विभिन्न हेरफेर प्रदर्शन गर्न। TOROW को साथ, तपाइँ कुनै समय मा दायरा देखि पङ्क्ति रूपान्तरण गर्न सक्नुहुन्छ। यो नयाँ प्रकार्यले पूरा गर्न सक्ने कार्यहरूको सूची यहाँ छ:

Excel TOROW प्रकार्य

Excel मा TOROW प्रकार्यलाई एरे वा कक्षहरूको दायरालाई रूपान्तरण गर्न प्रयोग गरिन्छ। एउटा पङ्क्ति।

प्रकार्यले कुल तीन तर्कहरू लिन्छ, जसमध्ये पहिलो मात्र आवश्यक छ।

TOROW(array, [ignore], [scan_by_column])

कहाँ:

एरे (आवश्यक) - एरे वा दायरा एउटै पङ्क्तिमा रूपान्तरण गर्न।

उपेक्षा गर्नुहोस् (वैकल्पिक) - खाली ठाउँहरू बेवास्ता गर्ने वा/र त्रुटिहरू। यी मध्ये एउटा मान लिन सक्छ:

• 0 वा हटाइएको (पूर्वनिर्धारित) - सबै मानहरू राख्नुहोस्
• 1 - खाली ठाउँहरू उपेक्षा गर्नुहोस्
• 2 - त्रुटिहरू उपेक्षा गर्नुहोस्
• 3 - खाली ठाउँ र त्रुटिहरूलाई बेवास्ता गर्नुहोस्

Scan_by_column (वैकल्पिक) - array कसरी स्क्यान गर्ने भनेर परिभाषित गर्दछ:

• FALSE वा मेटिएको (पूर्वनिर्धारित) - पङ्क्तिद्वारा तेर्सो रूपमा एरे स्क्यान गर्नुहोस्।
• TRUE - स्तम्भद्वारा ठाडो रूपमा एरे स्क्यान गर्नुहोस्।

सुझावहरू:

• एरेलाई रूपान्तरण गर्न एकल स्तम्भमा, TOCOL प्रकार्य प्रयोग गर्नुहोस्।
• रिभर्स रो-टु-एरे रूपान्तरणको लागि, स्तम्भहरूमा लपेट्न WRAPCOLS प्रकार्य वा र्याप गर्न WRAPROWS प्रकार्य प्रयोग गर्नुहोस्।पङ्क्तिहरूमा array।
• पङ्क्तिहरूलाई स्तम्भहरूमा बदल्न, TRANSPOSE प्रकार्य प्रयोग गर्नुहोस्।

TOROW उपलब्धता

TOROW एउटा नयाँ प्रकार्य हो, जुन एक्सेलमा मात्र समर्थित छ। Microsoft 365 (Windows र Mac को लागि) र वेब को लागि Excel।

Excel मा आधारभूत TOROW सूत्र

एक साधारण दायरा-देखि-पङ्क्ति रूपान्तरण गर्न, TOROW सूत्र प्रयोग गर्नुहोस्। यसको आधारभूत रूप मा। यसका लागि, तपाईंले पहिलो तर्क ( array ) लाई मात्र परिभाषित गर्न आवश्यक छ।

उदाहरणका लागि, 3 स्तम्भ र 3 पङ्क्तिहरू मिलेर बनेको दुई-आयामी एरेलाई एकल पङ्क्तिमा बदल्न, सूत्र हो:

=TOROW(A3:C6)

तपाईंले सूत्रलाई एउटा कक्षमा प्रविष्ट गर्नुहुन्छ (हाम्रो अवस्थामा A10), र यो स्वचालित रूपमा सबै नतिजाहरू समात्न आवश्यक पर्ने धेरै कक्षहरूमा फैलिन्छ। एक्सेल सर्तहरूमा, पातलो नीलो किनाराले घेरिएको आउटपुट दायरालाई स्पिल दायरा भनिन्छ।

यस सूत्रले कसरी काम गर्छ:

पहिले, कक्षहरूको एक आपूर्ति दायरालाई दुई-आयामी एरेमा रूपान्तरण गरिन्छ। कृपया अल्पविराम-डिलिमिटेड स्तम्भहरू र अर्धविराम-विभाजित पङ्क्तिहरू ध्यान दिनुहोस्:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

त्यसपछि, TOROW प्रकार्यले एरेलाई बायाँबाट दायाँ पढ्छ र यसलाई एक-आयामी तेर्सो एरेमा रूपान्तरण गर्दछ:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

नतिजा सेल A10 मा जान्छ, जहाँबाट यो दायाँ छिमेकी सेलमा फैलिन्छ।

रेन्जलाई खाली ठाउँ र त्रुटिहरूलाई बेवास्ता गर्दै पङ्क्तिमा रूपान्तरण गर्नुहोस्

पूर्वनिर्धारित रूपमा, TOROW प्रकार्यले स्रोत एरेबाट सबै मानहरू राख्छ, खाली कक्षहरू रत्रुटिहरू। आउटपुटमा, खाली कक्षहरूको स्थानमा शून्य मानहरू देखा पर्छन्, जुन धेरै भ्रमित हुन सक्छ।

खालीहरू बहिष्कार गर्न , उपेक्षा तर्कलाई १:<मा सेट गर्नुहोस्। 3>

=TOROW(A3:C5, 1)

त्रुटिहरूलाई बेवास्ता गर्न , उपेक्षा तर्कलाई 2 मा सेट गर्नुहोस्:

=TOROW(A3:C5, 2)

छोड्न दुबै, खाली र त्रुटिहरू , बेवास्ता गर्नुहोस् तर्कको लागि 3 प्रयोग गर्नुहोस्:

=TOROW(A3:C5, 3)

तलको छविले कार्यमा रहेका सबै तीन परिदृश्यहरू देखाउँदछ: <18

एरे तेर्सो वा ठाडो रूपमा पढ्नुहोस्

पूर्वनिर्धारित व्यवहारको साथ, TOROW प्रकार्यले एरेलाई तेर्सो रूपमा बाँयाबाट दायाँ प्रशोधन गर्दछ। स्तम्भद्वारा मानहरू माथिदेखि तलसम्म स्क्यान गर्न, तपाईंले तेस्रो तर्क ( scan_by_column ) लाई TRUE वा 1 मा सेट गर्नुभयो।

उदाहरणका लागि, पङ्क्तिद्वारा स्रोत दायरा पढ्न, सूत्रमा E3 हो:

=TOROW(A3:C5)

स्तम्भद्वारा दायरा स्क्यान गर्न, E8 मा सूत्र हो:

=TOROW(A3:C5, ,TRUE)

दुबै अवस्थामा, परिणामित एरेहरू हुन्। समान आकार, तर मानहरू फरक क्रममा व्यवस्थित छन्।

एउटै पङ्क्तिमा धेरै दायराहरू मर्ज गर्नुहोस्

एउटा पङ्क्तिमा धेरै गैर-सम्पन्न दायराहरू संयोजन गर्न, तपाईंले तिनीहरूलाई क्रमशः HSTACK वा VSTACK को मद्दतले एकल एरेमा तेर्सो वा ठाडो रूपमा स्ट्याक गर्नुहोस्। , र त्यसपछि संयुक्त एरेलाई पङ्क्तिमा रूपान्तरण गर्न TOROW प्रकार्य प्रयोग गर्नुहोस्।

तपाईँको व्यापार तर्कमा निर्भर गर्दै, निम्न सूत्रहरू मध्ये एउटाले कार्य प्रदर्शन गर्नेछ।

एरेहरू तेर्सो रूपमा स्ट्याक गर्नुहोस् र रूपान्तरण गर्नुहोस् पङ्क्ति

पहिलोसँगA3:C4 मा दायरा र A8:C9 मा दोस्रो दायरा, तलको सूत्रले दुई दायराहरू तेर्सो रूपमा एकल एरेमा स्ट्याक गर्नेछ, र त्यसपछि यसलाई बायाँबाट दायाँ मानहरू पढ्दै पङ्क्तिमा रूपान्तरण गर्नेछ। परिणाम तलको छविमा E3 मा छ।

=TOROW(HSTACK(A3:C4, A8:C9))

एरेहरू तेर्सो रूपमा स्ट्याक गर्नुहोस् र स्तम्भद्वारा रूपान्तरण गर्नुहोस्

स्ट्याक गरिएको एरेलाई माथिदेखि तलसम्म ठाडो रूपमा पढ्नको लागि, तलको छविमा E5 मा देखाइए अनुसार तपाईंले TOROW को तेस्रो तर्कलाई TRUE मा सेट गर्नुभयो:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

एरेहरू ठाडो रूपमा स्ट्याक गर्नुहोस् र पङ्क्तिद्वारा रूपान्तरण गर्नुहोस्

प्रत्येक जोड्न पछिल्लो एरेलाई अघिल्लो एरेको फेदमा जानुहोस् र संयुक्त एरेलाई तेर्सो रूपमा पढ्नुहोस्, E12 मा सूत्र हो:

=TOROW(VSTACK(A3:C4, A8:C9))

एरेहरूलाई ठाडो रूपमा स्ट्याक गर्नुहोस् र स्तम्भद्वारा रूपान्तरण गर्नुहोस्

अघिल्लो एकको तल प्रत्येक अर्को एरे थप्न र संयुक्त एरे ठाडो रूपमा स्क्यान गर्न, सूत्र हो:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

तर्कलाई राम्रोसँग बुझ्नको लागि, मानहरूको फरक क्रमलाई अवलोकन गर्नुहोस्। परिणाम स्वरूप arrays:

रेन्जबाट पङ्क्तिमा अद्वितीय मानहरू निकाल्नुहोस्

Microsoft Excel 2016 बाट सुरु गर्दै, हामीसँग UNIQUE नामको एउटा अद्भुत प्रकार्य छ, जसले सजिलै एकल स्तम्भबाट अद्वितीय मानहरू प्राप्त गर्न सक्छ। वा पङ्क्ति। यद्यपि, यसले बहु-स्तम्भ एरेहरू ह्यान्डल गर्न सक्दैन। यस सीमिततालाई पार गर्न, UNIQUE र TOROW प्रकार्यहरू सँगै प्रयोग गर्नुहोस्।

उदाहरणका लागि, दायरा A2:C7 बाट सबै फरक (अलग) मानहरू निकाल्न र परिणामहरूलाई एउटै पङ्क्तिमा राख्न,सूत्र हो:

=UNIQUE(TOROW(A2:C7), TRUE)

जसरी TOROW ले एक-आयामी तेर्सो एरे फर्काउँछ, हामीले UNIQUE को दोस्रो ( by_col ) तर्कलाई TRUE मा प्रत्येक स्तम्भहरू तुलना गर्न सेट गर्छौं। अन्य।

यदि तपाईं नतिजाहरू वर्णमालामा मिलाउन चाहनुहुन्छ भने, माथिको सूत्रलाई SORT प्रकार्यमा बेर्नुहोस्:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

UNIQUE को रूपमा, by_col SORT को तर्क पनि TRUE मा सेट गरिएको छ।

Excel 365 - 2010 को लागि TOROW वैकल्पिक

एक्सेल संस्करणहरूमा जहाँ TOROW प्रकार्य उपलब्ध छैन, तपाइँले काम गर्ने केही फरक प्रकार्यहरूको संयोजन प्रयोग गरेर दायरालाई एकल पङ्क्तिमा रूपान्तरण गर्न सक्नुहुन्छ। पुरानो संस्करणहरू। यी समाधानहरू धेरै जटिल छन्, तर तिनीहरूले काम गर्छन्।

क्षेत्रलाई तेर्सो रूपमा स्क्यान गर्न, सामान्य सूत्र हो:

INDEX( दायरा , QUOTIENT(COLUMN (A1)-1, COLUMNS( दायरा ))+1, MOD(COLUMN(A1)-1, COLUMNS( दायरा ))+1)

दायरा ठाडो रूपमा स्क्यान गर्न, जेनेरिक सूत्र हो :

INDEX( दायरा , MOD(COLUMN(A1)-1, COLUMNS( range ))+1, QuOTIENT(COLUMN (A1)-1, COLUMNS(<15)> दायरा ))+1)

A3:C5 मा हाम्रो नमूना डेटासेटको लागि, सूत्रहरूले यो आकार लिन्छ:

पङ्क्तिद्वारा दायरा स्क्यान गर्न:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

यो सूत्र TOROW प्रकार्यको विकल्प हो जसको तेस्रो तर्क FALSE मा सेट गरिएको छ वा हटाइएको छ:

=TOROW(A3:C5)

द्वारा दायरा स्क्यान गर्न स्तम्भ:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

यो सूत्र TOROW प्रकार्यसँग 3rd आर्गुमेन्ट सेट गरिएको छTRUE:

=TOROW(A3:C5, ,TRUE)

कृपया ध्यान दिनुहोस् कि डायनामिक एरे TOROW प्रकार्यको विपरीत, यी परम्परागत सूत्रहरू प्रत्येक कक्षमा प्रविष्ट गरिनुपर्छ जहाँ तपाईं परिणामहरू देखा पर्न चाहनुहुन्छ। हाम्रो अवस्थामा, पहिलो सूत्र (पङ्क्ति द्वारा) E3 मा जान्छ र M3 मार्फत प्रतिलिपि गरिएको छ। दोस्रो सूत्र (स्तम्भद्वारा) E8 मा अवतरण हुन्छ र M8 मार्फत तानिन्छ।

सूत्रहरू सही रूपमा प्रतिलिपि गर्नका लागि, हामी निरपेक्ष सन्दर्भहरू ($A$3:$C$5) प्रयोग गरेर दायरा लक गर्छौं। नाम गरिएको दायराले पनि गर्छ।

यदि तपाईंले सूत्रहरूलाई आवश्यकताभन्दा बढी कक्षहरूमा प्रतिलिपि गर्नुभएको छ भने, #REF! त्रुटि "अतिरिक्त" कक्षहरूमा देखा पर्नेछ। यसलाई ठीक गर्नको लागि, तपाईंको सूत्रलाई IFERROR प्रकार्यमा यसरी बेर्नुहोस्:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

यी सूत्रहरूले कसरी काम गर्छ

तल विस्तृत ब्रेक-डाउन छ। पङ्क्तिद्वारा मानहरू मिलाउने पहिलो सूत्रको:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

सूत्रको मुटुमा, हामी सेलको मान प्राप्त गर्नको लागि INDEX प्रकार्य प्रयोग गर्छौं। दायरा।

पङ्क्ति नम्बर यो सूत्रद्वारा गणना गरिन्छ:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

विचार दोहोरिने संख्या अनुक्रम जस्तै 1,1 उत्पादन गर्ने हो। ,1,2,2,2,3,3,3, … जहाँ प्रत्येक संख्या स्रोत दायरामा स्तम्भहरू भए जति पटक दोहोरिन्छ। र यहाँ हामी यो कसरी गर्छौं:

QUOTIENT ले डिभिजनको पूर्णांक भाग फर्काउँछ।

अंक को लागि, हामी COLUMN(A1)-1 प्रयोग गर्छौं, जसले सिरियल फर्काउँछ। पहिलो कक्षमा ० बाट नम्बर जहाँ सूत्र n मा प्रविष्ट गरिएको छ (दायरामा मानहरूको कुल संख्यामाइनस 1) अन्तिम कक्षमा जहाँ सूत्र प्रविष्ट गरियो। यस उदाहरणमा, हामीसँग E2 मा 0 र M3 मा 8 छ।

भाजक को लागि, हामी COLUMNS($A$3:$C$5)) प्रयोग गर्छौं। यसले तपाईंको दायरा (हाम्रो अवस्थामा ३) को स्तम्भहरूको सङ्ख्या बराबरको स्थिर सङ्ख्या फर्काउँछ।

परिणामस्वरूप, QUOTIENT प्रकार्यले पहिलो ३ कक्षहरू (E3:G3) मा ० फर्काउँछ, जसमा हामी 1 थप्नुहोस्, त्यसैले पङ्क्ति नम्बर 1 हो।

अर्को ३ कक्षहरूको लागि (H3:J3), QUOTIENT ले 1 फर्काउँछ, र +1 ले पङ्क्ति नम्बर 2 दिन्छ। र यस्तै।

स्तम्भ नम्बर गणना गर्न, तपाईंले MOD प्रकार्य प्रयोग गरेर उपयुक्त संख्या अनुक्रम निर्माण गर्नुहुन्छ:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

हाम्रो दायरामा ३ वटा स्तम्भहरू भएकाले, अनुक्रम यस्तो देखिनुपर्छ। : 1,2,3,1,2,3,…

MOD प्रकार्यले विभाजन पछि बाँकी फर्काउँछ।

E3 मा, MOD(COLUMN(A1)-1, COLUMNS($ A$3:$C$5))+

बन्छ

MOD(1-1, 3)+1)

र 1 फर्काउँछ।

मा F3, MOD(COLUMN(B1)-1, COLUMNS($A$3:$C$5))+

बन्छ

MOD(2-1, 3)+1)

र 2 फर्काउँछ।

पङ्क्ति र स्तम्भ संख्याहरू स्थापित भएपछि, INDEX ले त्यो पङ्क्ति र स्तम्भको प्रतिच्छेदनमा सजिलैसँग मान ल्याउँछ।

E3 मा, INDEX($A$3 :$C$5, 1, 1) पहिलो पङ्क्ति र पहिलो स्तम्भबाट मान फर्काउँछ सन्दर्भ दायराको, अर्थात् सेल A3 बाट।

F3 मा, INDEX($A$3:$C$5, 1, 2) ले पहिलो पङ्क्ति र दोस्रो स्तम्भबाट मान फर्काउँछ, अर्थात् सेल B3 बाट।

र यस्तै अगाडि।

दोस्रो सूत्र जसले दायरालाई स्तम्भद्वारा स्क्यान गर्छ, एक मा काम गर्दछसमान तरिका। भिन्नता यो हो कि हामी पङ्क्ति नम्बर गणना गर्न MOD प्रयोग गर्छौं र स्तम्भ संख्या पत्ता लगाउन QUOTIENT।

TOROW प्रकार्यले काम गरिरहेको छैन

यदि TOROW प्रकार्यले त्रुटिमा परिणाम दिन्छ भने, यो यी मध्ये एउटा कारण हुनसक्छ:

#NAME? त्रुटि

अधिकांश एक्सेल प्रकार्यहरूसँग, #NAME? त्रुटि भनेको प्रकार्यको नाम गलत हिज्जे भएको स्पष्ट संकेत हो। TOROW को साथ, यसको मतलब यो पनि हुन सक्छ कि प्रकार्य तपाईको एक्सेलमा उपलब्ध छैन। यदि तपाईंको एक्सेल संस्करण 365 बाहेक अन्यमा छ भने, TOROW वैकल्पिक प्रयोग गर्ने प्रयास गर्नुहोस्।

#NUM त्रुटि

#NUM त्रुटिले देखाउँछ कि फर्काइएको एरे पङ्क्तिमा फिट हुन सक्दैन। प्रायः यो तब हुन्छ जब तपाईले सानो दायराको सट्टा सम्पूर्ण स्तम्भहरू र/वा पङ्क्तिहरू सन्दर्भ गर्नुहुन्छ।

#SPILL त्रुटि

अधिकांश अवस्थामा, #SPILL त्रुटिले पङ्क्ति जहाँ तपाईंले सूत्र प्रविष्ट गर्नुभयो परिणामहरू फैलाउन पर्याप्त खाली कक्षहरू छैनन्। यदि छिमेकी कक्षहरू दृश्यात्मक रूपमा खाली छन् भने, निश्चित गर्नुहोस् कि त्यहाँ कुनै खाली ठाउँ वा अन्य गैर-मुद्रण वर्णहरू छैनन्। थप जानकारीको लागि, Excel मा #SPILL त्रुटिको अर्थ के हो हेर्नुहोस्।

यसरी तपाइँ २-आयामी एरे वा दायरालाई एकल पङ्क्तिमा रूपान्तरण गर्न Excel मा TOROW प्रकार्य प्रयोग गर्नुहुन्छ। पढ्नुभएकोमा म तपाईंलाई धन्यवाद दिन्छु र अर्को हप्ता हाम्रो ब्लगमा भेट्ने आशा गर्छु!

डाउनलोडको लागि अभ्यास कार्यपुस्तिका

एक्सेल TOROW प्रकार्य - सूत्र उदाहरणहरू (.xlsx फाइल)