El tutorial explica la sintaxi i els usos bàsics de la funció TRIVIA i ofereix uns quants exemples no trivials que mostren com utilitzar una fórmula TRIVIA a Excel.

TRIU és un d'aquests. Les funcions d'Excel que poden no semblar útils per si soles, però combinades amb altres funcions ofereixen una sèrie d'avantatges impressionants. Al nivell més bàsic, utilitzeu la funció TRIAR per obtenir un valor d'una llista especificant la posició d'aquest valor. Més endavant, en aquest tutorial, trobareu diversos usos avançats que, sens dubte, val la pena explorar.

Funció d'Excel COOSE: sintaxi i usos bàsics

La funció COOSE d'Excel és dissenyat per retornar un valor de la llista basat en una posició especificada.

La funció està disponible a Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 i Excel 2007.

La sintaxi de la funció TRIAR és la següent:

On:

Núm_índex (obligatori): la posició del valor a retornar. Pot ser qualsevol nombre entre 1 i 254, una referència de cel·la o una altra fórmula.

Valor1, valor2, … : una llista de fins a 254 valors per triar. El valor1 és obligatori, els altres valors són opcionals. Aquests poden ser números, valors de text, referències de cel·les, fórmules o noms definits.

A continuació es mostra un exemple de fórmula COOSE en la forma més senzilla:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

La fórmula torna "Amy" perquè núm_índex és 3 i "Amy" és el tercer valor de la llista:

Funció EXCEL CHOOSE: 3 coses per recordar!

CHOOSE és una funció molt senzilla i difícilment trobareu cap dificultat per implementar-la als vostres fulls de treball. Si el resultat retornat per la vostra fórmula CHOOSE és inesperat o no és el resultat que cerqueu, pot ser que sigui pels motius següents:

1. El nombre de valors per triar està limitat a 254.
2. Si núm_índex és inferior a 1 o superior al nombre de valors de la llista, el #VALOR! es retorna l'error.
3. Si l'argument núm_índex és una fracció, es trunca a l'enter més baix.

Com s'utilitza la funció TRIA a Excel - fórmula exemples

Els exemples següents mostren com CHOOSE pot ampliar les capacitats d'altres funcions d'Excel i proporcionar solucions alternatives a algunes tasques habituals, fins i tot a aquelles que molts consideren inviables.

Excel CHOOSE en lloc de IF imbricats

Una de les tasques més freqüents a Excel és retornar diferents valors en funció d'una condició especificada. En la majoria dels casos, això es pot fer utilitzant una instrucció IF imbricada clàssica. Però la funció TRIAR pot ser una alternativa ràpida i fàcil d'entendre.

Exemple 1. Retorna diferents valors segons la condició

Suposant que tens una columna de puntuacions dels estudiants i vols etiquetar les puntuacions basades en elcondicions següents:

Una manera de fer-ho és anidar unes quantes fórmules SI una dins de l'altra:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Una altra manera és triar una etiqueta corresponent a la condició:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Com funciona aquesta fórmula:

A l'argument núm_índex , avalueu cada condició i torneu TRUE si la condició es compleix, FALSE en cas contrari. Per exemple, el valor de la cel·la B2 compleix les tres primeres condicions, de manera que obtenim aquest resultat intermedi:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Tenint en compte que a la majoria de fórmules d'Excel, TRUE equival a 1 i FALSE a 0, el nostre La fórmula experimenta aquesta transformació:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Després de realitzar l'operació d'addició, tenim:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Com a resultat, el tercer valor de la es retorna la llista, que és "Bo".

Consells:

• Per fer la fórmula més flexible, podeu utilitzar referències de cel·les en lloc d'etiquetes codificades, per exemple:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Si cap de les vostres condicions és VERTADERA, l'argument núm_índex s'establirà en 0 forçant la vostra fórmula a retornar el #VALOR! error. Per evitar-ho, simplement embolcalleu COOSE a la funció IFERROR de la següent manera:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Exemple 2. Feu diferents càlculs basats en la condició

De manera similar, vostèpodeu utilitzar la funció EXCEL CHOOSE per realitzar un càlcul en una sèrie de possibles càlculs/fórmules sense anidar múltiples declaracions IF una dins de l'altra.

Com a exemple, calculem la comissió de cada venedor en funció de les seves vendes:

Amb l'import de les vendes a B2, la fórmula pren la forma següent:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

En lloc de codificar els percentatges de la fórmula, podeu fer referència a la cel·la corresponent de la vostra taula de referència, si n'hi ha. Només recordeu arreglar les referències utilitzant el signe $.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel CHOSE formula per generar dades aleatòries

Com probablement sabeu, Microsoft Excel té una funció especial per generar nombres enters aleatoris entre els nombres inferior i superior que especifiqueu: funció RANDBETWEEN. Agrupeu-lo a l'argument núm_índex de CHOOSE i la vostra fórmula generarà gairebé totes les dades aleatòries que vulgueu.

Per exemple, aquesta fórmula pot produir una llista de resultats d'examen aleatoris:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

La lògica de la fórmula és òbvia: RANDBETWEEN genera nombres aleatoris de l'1 al 4 i CHOOSE retorna un valor corresponent de la llista predefinida de quatre valors.

Nota. RANDBETWEEN és una funció volàtil i es recalcula amb cadacanvi que feu al full de treball. Com a resultat, la vostra llista de valors aleatoris també canviarà. Per evitar que això passi, podeu substituir les fórmules pels seus valors utilitzant la funció Enganxa especial .

TRIA la fórmula per fer una cerca visual a l'esquerra

Si alguna vegada heu fet una cerca vertical a Excel, ja sabeu que la funció BUSCAR V només pot cercar a la columna més a l'esquerra. En situacions en què necessiteu retornar un valor a l'esquerra de la columna de cerca, podeu utilitzar la combinació INDEX / MATCH o enganyar BUSCARV niudant-hi la funció TRIA. A continuació s'explica com:

Suposem que teniu una llista de puntuacions a la columna A, els noms dels estudiants a la columna B i voleu recuperar la puntuació d'un estudiant concret. Com que la columna de retorn es troba a l'esquerra de la columna de cerca, una fórmula normal de Vlookup retorna l'error #N/A:

Per solucionar-ho, obteniu la funció CHOOSE per intercanviar les posicions de les columnes, dient a Excel que la columna 1 és B i la columna 2 és A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Perquè proporcionem una matriu de {1,2} al núm_índex argument, la funció COOSE accepta intervals en els arguments valor (normalment, no ho fa).

Ara, inseriu la fórmula anterior a l'argument table_array de CERCA V:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

I voilà: es fa una cerca a l'esquerra sense cap problema!

TRIA la fórmula per tornar al següent treball dia

Si no esteu segur de sihauries d'anar demà a la feina o pots quedar-te a casa i gaudir del teu merescut cap de setmana, la funció EXCEL TRIA pot saber quan és el següent dia laboral.

Suposant que els teus dies laborables són de dilluns a divendres, la fórmula va de la següent manera:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Difícil a primera vista, en una ullada més de prop, la lògica de la fórmula és fàcil de seguir:

WEEKDAY (TODAY()) retorna un número de sèrie corresponent a la data d'avui, que va de l'1 (diumenge) al 7 (dissabte). Aquest número va a l'argument núm_índex de la nostra fórmula CHOOSE.

Valor1 - valor7 (1,1,1,1,1, 3,2) determineu quants dies cal afegir a la data actual. Si avui és diumenge - dijous (núm_índex 1 - 5), afegiu 1 per tornar l'endemà. Si avui és divendres (núm_índex 6), afegiu 3 per tornar dilluns vinent. Si avui és dissabte (núm_índex 7), afegiu 2 per tornar dilluns que ve. Sí, és així de senzill :)

TRIA la fórmula per tornar un nom de dia/mes personalitzat a partir de la data

En situacions en què voleu obtenir un nom de dia en el format estàndard, com ara el nom complet ( Dilluns, dimarts, etc.) o nom curt (dl., dimarts, etc.), podeu utilitzar la funció TEXT tal com s'explica en aquest exemple: Obteniu el dia de la setmana a partir de la data a Excel.

Si voleu retorneu el nom d'un dia de la setmana o d'un mes en un format personalitzat, utilitzeu la funció TRIA de la manera següent.

Per obtenir un dia de la setmana:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Per aconseguir unmes:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

On A2 és la cel·la que conté la data original.

Espero que aquest tutorial us hagi donat algunes idees sobre com podeu utilitzar la funció TRIAR a Excel per millorar els vostres models de dades. Us agraeixo la lectura i esperem veure-us al nostre blog la setmana vinent!

Descarregueu el quadern de pràctiques

Excel CHOOSE function examples